/*

 aberrate36.pov
 2009 Samuel Benge
 3.6 version
 
 Applies a chromatic aberration and film grain
 effect to the image of your choice. The film
 grain is optional and may look better if
 antialising is turned on.
 
*/

global_settings{
 //assumed_gamma 1.0
}

#default{finish{ambient 1}}

camera{
 orthographic
 right x*2 up y*2
 location -z*8 look_at 0
}

// #####################################
// here is where you change the settings

// amount of film grain
// 0.0 - 1.0
#declare Noise = 0.0;

// amount of chromatic aberration
// 1.0 - ?
#declare Aberration = 1.7;

// quality of aberration effect
// 1 - ?
#declare Aberration_Samples = 40;

// your image here
#declare image=
pigment{
 image_map{
  png"growth2.png"
  // interpolate 2
 }
}
// #####################################

// image plane, no need to change it
plane{z,0
 pigment{
  image
  warp{repeat x flip x}
  warp{repeat y flip y}
  translate -.5
  scale<2,2,1>
 }
}

// effect sphere, no need to change it
sphere{<0,0,10>,12
 pigment{
  #if(Noise>0)
   crackle solid
   scale .001
   color_map{
    [0 rgb 0 transmit 1-Noise]
    [1/6 rgb y transmit 1-Noise]
    [2/6 rgb 0 transmit 1-Noise]
    [3/6 rgb x transmit 1-Noise]
    [4/6 rgb 0 transmit 1-Noise]
    [5/6 rgb z transmit 1-Noise]
   }
   #else
   rgbt 1
  #end
 }
 interior{
  ior 1.0
  dispersion Aberration
  dispersion_samples Aberration_Samples
 }
}