#default {finish {ambient 0}}

//	#declare photon_count = 0;
//	#declare photon_count = 100000;
	#declare photon_count = 10000000;
//	#declare photon_count = 100000000;
//	#declare focal_blur = 0;
//	#declare focal_blur = 1;
	#declare focal_blur = 2;
//	#declare area_lights = 0;
//	#declare area_lights = 15;
	#declare area_lights = 25;
//	#declare words = 0;
	#declare words = 1;

	#declare view = 0;
//	#declare view = 1;
//	#declare view = 2;


global_settings {
	#if (photon_count > 0)
		photons {
			count photon_count
		}
	#end
}

camera {
	#switch(view)
	#case(0)
		location <0,6,0>
		look_at z*4
	#break
	#case(1)
		location <0,6,0>
		look_at <1.5,0,4>
		angle 30
	#break
	#case(2)
		location <0,6,0>
		look_at <1,0,4.4>
		angle 10
	#end

	#if (focal_blur > 0)
		focal_point <1,2,4.4>
		aperture 0.8
		#switch(focal_blur)
		#case(1)
			blur_samples 100
		#break
		#case(2)
			blur_samples 200
		#break
		#end
	#end
}

light_source {
	<25,25,25>
	color rgb <4,2,2>/2
	spotlight
	point_at z*4
	radius 0
	falloff 3
	#if (area_lights > 0)
		area_light
		x*2,y*2,area_lights,area_lights
		circular orient
		adaptive 1
	#end
	photons {
		reflection on
		refraction on
	}
}

light_source {
	<0,5,25>
	color rgb <1,1,2>/32
	#if (area_lights > 0)
		area_light
		x*2,y*2,area_lights,area_lights
		circular orient
		adaptive 1
	#end
	photons {
		reflection on
		refraction on
	}
}

#declare page = bicubic_patch {
	type 1
	u_steps 2
	v_steps 6
	<0,0,0>, <3,2,0>, <6,0.5,0>, <9,0,0>,
	<0,0,4>, <3,2,4>, <6,0.5,4>, <9,0,4>,
	<0,0,8>, <3,2,8>, <6,0.5,8>, <9,0,8>,
	<0,0,12>,<3,2,12>,<6,0.5,12>,<9,0,12>
}


#macro line( txt )
	text {ttf "times.ttf" txt 2,0 scale 1/40 translate <0.025,line_pos,0>}
	#declare line_pos = line_pos - 0.03;
#end

#declare lwords = union {
	cylinder {<0.5,0.05,0>,<0.5,0.95,0>,0.0025}
	sphere {<0.5,0.05,0>,0.0025}
	sphere {<0.5,0.95,0>,0.0025}
	#declare line_pos = 0.86;
	line( "  Gentiles, whether we be bond or free; and")
	line( "  have been all made to drink into one Spirit.")
	line( "    14 For the body is not one member, but")
	line( "  many.")
	line( "    15 If the foot shall say, Because I am not")
	line( "  the hand, I am not of the body; is it")
	line( "  therefore not of the body?")
	line( "    16 And if the ear shall say, Because I am")
	line( "  not the eye, I am not of the body; is it")
	line( "  therefore not of the body?")
	line( "    17 If the whole body were an eye, where")
	line( "  were the hearing? If the whole were hearing,")
	line( "  where were the smelling?")
	line( "    18 But now hath God set the members every")
	line( "  one of them in the body, as it hath pleased")
	line( "  him.")
	line( "    19 And if they were all one member, where")
	line( "  were the body?")
	line( "    20 But now are they many members, yet but")
	line( "  one body.")
	line( "    21 And the eye cannot say unto the hand,")
	line( "  I have no need of thee: nor again the ahead")
	line( "  to the feet, I have no need of you.")
	line( "    22 Nay, much more those members of the")
	line( "  body, which seem to be more feeble, are")
	line( "  necessary:")
	line( "    23 And those members of the body, which")
	union { // next column
	#declare line_pos = 0.86;
	line( "  we think to be less honourable, upon these")
	line( "  we bestow more abundant honour; and our")
	line( "  uncomely parts have more abundant")
	line( "  comeliness.")
	line( "    24 For our comely parts have no need:")
	line( "  but God hath tempered the body together,")
	line( "  having given more abundant honour to that")
	line( "  part which lacked:")
	line( "    25 That there should be no schism in the")
	line( "  body; but that the members should have the")
	line( "  same care one for another.")
	line( "    26 And whether one member suffer, all the")
	line( "  members suffer with it; or one member be")
	line( "  honoured, all the members rejoice with it.")
	line( "    27 Now ye are the body of Christ, and")
	line( "  members in particular.")
	line( "    28 And God hath set some in the church,")
	line( "  first apostles, secondarily prophets, thirdly")
	line( "  teachers, after that miracles, then gifts of")
	line( "  healings, helps, governments, diversities of")
	line( "  tongues.")
	line( "    29 Are all apostles? are all prophets? are")
	line( "  all teachers? are all workers of miracles?")
	line( "    30 Have all the gifts of healing? do all")
	line( "  speak with tongues? do all interpret?")
	line( "    31 But covet earnestly the best gifts: and")
	line( "  yet shew I unto you a more excellent way.")

	translate x*0.5
	}
}

#declare rwords = union {
	cylinder {<0.5,0.05,0>,<0.5,0.95,0>,0.0025}
	sphere {<0.5,0.05,0>,0.0025}
	sphere {<0.5,0.95,0>,0.0025}
	#declare line_pos = 0.86;
	line( "                          Chapter 13") 
	line( "    1 Though I speak with the tongues of men")
	line( "  and of angels, and have not charity, I am")
	line( "  become as sounding brass, or a tinkling")
	line( "  cymbal.")
	line( "    2 And though I have the gift of prophecy,")
	line( "  and understand all mysteries, and all")
	line( "  knowledge; and though I have all faith, so")
	line( "  that I could remove mountains, and have")
	line( "  not charity, I am nothing.")
	line( "    3 And though I bestow all my goods to")
	line( "  fee the poor, and though I give my body to")
	line( "  be burned, and have not charity, it profiteth")
	line( "  me nothing.")
	line( "    4 Charity suffereth long, and is kind;")
	line( "  charity envieth not; charity vaunteth not")
	line( "  itself, is not puffed up,")
	line( "    5 Doth not behave itself unseemly,")
	line( "  seeketh not her own, is not easily provoked,")
	line( "  thinketh no evil;")
	line( "    6 Rejoiceth not in iniquity, but rejoiceth")
	line( "  in the truth;")
	line( "    7 Beareth all things, believeth all things,")
	line( "  hopeth all things, endureth all things.")
	line( "    8 Charity never faileth: but whether")
	line( "  there be prophecies, they shall fail; whether")
	line( "  there be tongues, they shall cease; whether")
	union {// Next column
	#declare line_pos = 0.86;
	line( "  there be knowledge, it shall vanish away.")
	line( "    9 For we know in part, and we prophesy")
	line( "  in part.")
	line( "    10 But when that which is perfect is")
	line( "  come then that which is in part shall be")
	line( "  done away.")
	line( "    11 When I was a child, I spake as a")
	line( "  child, I understood as a child, I thought as")
	line( "  a child: but when I became a man, I put")
	line( "  away childish things.")
	line( "    12 For now we see through a glass,")
	line( "  darkly: but then face to face: now I know")
	line( "  in part; but then shall I know even as also")
	line( "  I am known.")
	line( "    13 And now abideth faith, hope, charity,")
	line( "  these three; but the greatest of these is")
	line( "  charity.")
	line( "                          Chapter 14")
	line( "    1 Follow after charity, and desire")
	line( "  spiritual gifts, but rather that ye may")
	line( "  prophesy.")
	line( "    2 For he that speaketh in an unknown tongue")
	line( "  speaketh not unto men, but unto God: for no")
	line( "  man understandeth him; howbeit in the spirit")
	line( "  he speaketh mysteries.")
	line( "    3 But he that prophesieth speaketh unto")
	line( "  men to edification, and exhortation, and")
	translate x*0.5
	}
}

#declare rpage = pigment {
	average
	pigment_map {
		[5 object {rwords color rgb 1 color rgb 0}]
		[1 object {lwords color rgb 1 color rgb 0} scale <-1,1,1> translate x]
	}
}

#declare lpage = pigment {
	average
	pigment_map {
		[1 object {rwords color rgb 1 color rgb 0}]
		[5 object {lwords color rgb 1 color rgb 0} scale <-1,1,1> translate x]
	}
//	object {
//		lwords
//		color rgb 1
//		color rgb 0
//	}
//	scale <-1,1,1>
//	translate x
}

union {
	#if (words > 0)
		object { page texture {uv_mapping pigment {rpage}} }
		object { page texture {uv_mapping pigment {lpage}} scale <-1,1,1> }
	#else
		object { page }
		object { page scale <-1,1,1>}
		pigment {color rgb 1}
	#end
}

#declare gold = texture {
	pigment { color rgb <1,.8,.2> }
	finish {
	 	brilliance 5
		specular 2
		roughness 0.01
		reflection {0,0.75 metallic}
		metallic
	}
	normal {
		bumps 1/10
		scale 1/300
	}
}

// Men's ring
difference {
	torus {5/8,1/8}
	sphere {0,19/32}
	texture { gold }
	rotate z*25
	translate <0.75,0.5,3.5>
	photons {
		target on
		reflection on
		refraction on
	}
}

#declare pa = <0.00,0,15/32>;
#declare pb = <0.14,0,21/32>;
#declare pc = <0.14,0,24/32>;
#declare pd = <0.12,0,25/32>;

// Women's ring
union {
	difference {
		torus {1/2,1/12}
		sphere {0,31/64}
		texture { gold }
	}
	union {
		#declare prot = 45;
		#while (prot < 360)
			#declare pra = vrotate(pa,z*prot)*<2,1,1>;
			#declare prb = vrotate(pb,z*prot)*<2,1,1>;
			#declare prc = vrotate(pc,z*prot)*<2,1,1>;
			#declare prd = vrotate(pd,z*prot)*<2,1,1>;
			cylinder {pra, prb, 1/64}
			cylinder {prb, prc, 1/64}
			cylinder {prc, prd, 1/64}
			sphere {prb, 1/64}
			sphere {prc, 1/64}
			sphere {prd, 1/64}
		#declare prot = prot + 90;
		#end
		texture { gold }
	}
	intersection {
		box {-1,1}
		#declare rotx = 0;
		#while (rotx <= 120)
			#declare roty = 00;
			#while (roty <= 360)
			plane {y, 0.5 rotate x*rotx rotate y*roty}
			#declare roty = roty + 20;
			#end
		#declare rotx = rotx + 20;
		#end
		plane {-y,0.5}
		scale <2,1,1>/4
		rotate -x*90
		translate z*23/32
		
		texture {
			pigment {color transmit 1}
			finish {specular 1}
		}
		interior {
			ior 2.5
			dispersion 1.05
		}
	}
	
	scale 0.9
	rotate -y*60
	rotate -z*5
	translate <1.5,0.9,3.5>
	photons {
		target on
		reflection on
		refraction on
	}
}