camera {
	location <0,0,-10>
	look_at 0
}
light_source {
	<-5,5,-7>
	rgb 1.5
	fade_distance 5
	fade_power 2
}
light_source {
	<-500,500,-500>
	rgb <.5,.4,.3>
	shadowless
}
light_source {
	<500,-500,150>
	rgb <.7,.8,.9>
}
plane {-z,0
	texture {
		#declare Bricksize=<8, 3, 4.5>;
		#declare Mortar=.5;
		brick
		texture {
			pigment {
				granite
				color_map {
					[0 rgb .5]
					[1 rgb .25]
				}
				scale .1
			}
			normal {
				average
				#declare Aantal=10;
				#declare Blur=.0625;
				#declare Seed=seed(3541);
				normal_map {
					#while (Aantal>0)
						[brick 20 brick_size Bricksize mortar Mortar translate Blur*(<rand(Seed),rand(Seed),rand(Seed)>-<rand(Seed),rand(Seed),rand(Seed)>)]
						#declare Aantal=Aantal-1;
					#end
					[granite -20 scale .5]
				}
			}
			finish {ambient 0 diffuse .75 specular 0}
		}
		texture {
			pigment {
				cells
				pigment_map {
					[0 
						granite
						color_map {
							[0 rgb <1,.5,.25>]
							[1 rgb <.5,.25,.125>*1.5]
						}
						scale <10,.2,.2>
						warp {turbulence 1}
					]
					[1 
						granite
						color_map {
							[0 rgb <1,.5,.25>/4]
							[1 rgb <.5,.25,.125>/3]
						}
						scale <5,.5,.5>
						warp {turbulence 1}
					]
				}
				warp {repeat y offset 1189*x*.5}
				scale Bricksize
			}
			normal {
				average
				#declare Aantal=50;
				#declare Blur=.5;
				#declare Seed=seed(3541);
				normal_map {
					#while (Aantal>0)
						[brick 150 brick_size Bricksize mortar Mortar translate Blur*(<rand(Seed),rand(Seed),rand(Seed)>-<rand(Seed),rand(Seed),rand(Seed)>)]
						#declare Aantal=Aantal-1;
					#end
					[granite -50 scale 1]
				}
			}
			finish {ambient 0 diffuse 1 specular .75 roughness .02}
      }
		brick_size Bricksize
		mortar Mortar 
		scale .25
	}
}