// Persistence of Vision Ray Tracer Scene Description File
// Vers: 3.5
// Desc: Water 'Bucket' (Example)
// Date: 09/05/03
// Auth: Just a random raytracer
//

#version 3.5;

#include "colors.inc"
#include "skies.inc"

global_settings {
  assumed_gamma 1.0
  max_trace_level 15
}

// ----------------------------------------

camera {
  location  <0.0, 7.5, -10.0>
  direction 1.5*z
  right     x*image_width/image_height
  look_at   <0.0, 5.0,  0.0>
}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}

light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <1, 1, 1>  // light's color
  translate <-30, 90, 30>
}

// ----------------------------------------

plane {
  y,-0.1
  pigment { color rgb 0.2 }
}

box {
  -1,1-y
  scale 50
  texture
  {
    pigment {
      hexagon
      color rgb 0.5
      color green 0.4 blue 0.7
      color red 0.4 green 0.7
      scale 2
    }
    finish{
      diffuse 0.8
      ambient 0.1
    }
  }
}

sky_sphere { S_Cloud2 }

intersection {
	cylinder { 4.1*y, -0.5*y, 4.2 }
	cylinder { 4.5*y, 0.01*y, 4 inverse }
	pigment { 
		bozo
		color_map {
			[ 0 color rgb 0.7 ]
			[ 1 color rgb 0.9 ]
		}
		scale 0.1
		turbulence 0.9
	}
}

#declare r_0 = normal { bozo 0.2 scale 1.2 }
#declare r_1 = normal { bozo 0.7 scale 0.5 }
#declare r_2 = normal { bozo 0.8 scale 0.11 }
#declare r_3 = normal { bozo 0.6 scale 0.027 }
#declare r_4 = normal { bozo 0.1 scale 0.0039 }

cylinder {
	4*y, 0.011*y, 3.9999
	texture {
		pigment {
			color rgbf <0.8,0.8,1.0,0.97>
		}
		finish {
			diffuse 0.0
			ambient 0.0
			specular 0.3
			roughness 0.001
			reflection {
				0.1, 0.8
				fresnel on
			}
			conserve_energy
		}
		normal {
			average 
			normal_map {
				[ 1 r_3 ]
				[ 1 r_2 ]
				[ 1 r_1 ]
				[ 1 r_0 ]
			}
			scale 4
		}
	}
	interior { 
		ior 1.33 
		fade_distance 7
		fade_power 1
		fade_color <0.3, 0.25, 0.2>
	}
}