// Persistence of Vision Ray Tracer Scene Description File
// File: ground04.pov
// Vers: 3.5
// Desc: Use of the trace function in a macro to generate 
//       a mesh2  from an isosurface
// Date: 11/12/02
// Auth: Greg M. Johnson
//

#version 3.5;       
#include "transforms.inc"

//global_settings {  assumed_gamma 1.0}

// ----USER DEFINED VARIABLES---------------------------             


#macro mercator(numphi,numtheta,Originny,hills,merctext)

//#declare numphi=30;  //this is the number of places in phi: like the latitude lines on a globe. 
//#declare numtheta=30; // this is the number of places in theat: like the longitude lines on a globe.
//#declare Originny=0*y; // this is the origin of your globe   <0,0,0>

                                                        
// ----------------------------------------                                                                     

#declare Norm=<0,0,0>;                                                        
//light_source{<-40,100,-80> color rgb 1} 
//background{blue 1}
//fog {distance 200 color rgb <0.2,0.3,1>}

         
mesh2 {
  vertex_vectors {
       6*numtheta*numphi,

        #declare nphi=0;
        #while(nphi<numphi)
        #declare ntheta=0;
        #while(ntheta<numtheta)
                   
                #declare p0= Originny;
                
                #declare v0= y;
                
                #local tr1=transform{rotate z*180*pow((nphi+0)/numphi,1) rotate y*360*(ntheta+0)/numtheta};
                #local tr2=transform{rotate z*180*pow((nphi+0)/numphi,1) rotate y*360*(ntheta+1)/numtheta};
                #local tr3=transform{rotate z*180*pow((nphi+1)/numphi,1) rotate y*360*(ntheta+0)/numtheta};
                #local tr4=transform{rotate z*180*pow((nphi+1)/numphi,1) rotate y*360*(ntheta+1)/numtheta};
                
                #declare vul=vtransform(v0,tr1);
                #declare vur=vtransform(v0,tr2);                       
                #declare vll=vtransform(v0,tr3);
                #declare vlr=vtransform(v0,tr4);

                #declare p1=trace(hills, Originny,vul,Norm);
                #declare p2=trace(hills, Originny,vur,Norm); 
                
                #declare p3=trace(hills, Originny,vll,Norm);
                #declare p4=trace(hills, Originny,vlr,Norm);

                p1,p2,p4,
                p1,p3,p4        
                              
               #if(ntheta<numtheta-1&nphi<numphi-1)
                       ,
               #end
        #declare ntheta=ntheta+1;
        #end
        #declare nphi=nphi+1;
        #end
        
  }
  
  face_indices {
     2*numphi*numtheta,

               #declare n=0;
               #while (n<6*numphi*numtheta-0)      
     
                  <n,n+1,n+2>,
                       
               #declare n=n+3;
               #end

               #if(n<6*numphi*numtheta-1)
                    ,
               #end                          
               }
  
  texture {merctext}
  
  //translate 3*y 
  
}
    
    


#end