//The idea is to use the last rendered image as input for the current image

#version unofficial MegaPOV 0.6;//For frame_number, final_frame, clock_on
#include "colors.inc"

//IMPORTANT IMPORTANT IMPORTANT IMPORTANT IMPORTANT IMPORTANT IMPORTANT IMPORTANT 
global_settings { 
	/*Make sure write to file is on
	  & that we know the file name 
	  cause currently you can't access
	  it from the scene without patching POV*/
	/*ini_option "+F +FN +Ochaos.png +KFF1000"*/
	assumed_gamma 2.2
}

//Find out how many characters the output file contains
#declare I = final_frame;
#declare L = 1;
#while(I>1)
#declare I = I/10;
#declare L = L+1;
#end
//L now contains the number of characters the Frame number should take up
#if(clock_on)
	//For when this is rendered as an animation
	#declare file = concat("chaos",str(frame_number-1,-L,0),".png")
	//Little bit of debugging when anim is on
	#debug concat("\n",file,"\n")
#else
	//For when you call POV many times to render the image
	#declare file = "chaos.png"
#end

//Simple camera
camera {
   location  <0, 120, 0>
   look_at   <0, 0,  0>
}

/*Initially this file was one of the
  "Ready-made scenes" from the POV-Win
  insert menu & the following lights are
  relics from the file this was based on*/
light_source {
	<0, 50, -1> color LightGray
	spotlight
	point_at <0, 0, 8>
	tightness 50
	radius 50
	falloff 100
}

light_source {
	<-13, -0.5, -2>
	color Red
	spotlight
	point_at <-0, -0, -00>
	tightness 10
	radius 100
	falloff 250
}

light_source {
	<10, -0.5, -2>
	color Green
	spotlight
	point_at <0, -0, -0>
	tightness 10
	radius 100
	falloff 250
}

light_source {
	<13, -0.5, -2> color Blue
	spotlight
	point_at <0, 0, 0>
	tightness 10
	radius 100
	falloff 250
}

//Light that I added
light_source {<100,120,-130> colour White}

//The smaller less visible sphere adding to the image
sphere { 0, 25
	pigment {
		image_map{ png file interpolate 2 map_type 1 transmit all 0.8 }
		scale 100 rotate x*90 rotate z*40
	}
	normal {
		bump_map { png file bump_size 5 interpolate 2 once }
		scale 60
		translate <-25, -25, 8970>
	}
	finish {ambient 0.2 diffuse 0.7 specular 0.6}
}

//The elongated 3D Red elipse that affects the image the most
sphere { <0.1, 10, 0>, 20
	pigment { Red transmit 0.8}
	normal {
		bump_map { png file bump_size 5 interpolate 2 once }
		scale 60
		rotate <-25, -25, 50>
		translate <-25, -25, 0>
	}
	finish {ambient 0.2 diffuse 0.7 specular 0.6}
	scale <2,1,1> //Elongate it
}

//The plane that does most of the IFS work
plane { y, -25
	finish {ambient 0.6 }
	pigment {
		//The actual image
		image_map{ png file interpolate 2 map_type 0}
		//Arbitrary transformations
		scale 100 rotate x*90 rotate y*45 /*rotate z*40*/
	}
}

//See simple really but a lot more could be done with it