#version unofficial 3.8; // yuqk
#if (file_exists("version.inc"))
    #include "version.inc"
#end
#if (!defined(Fork_yuqk))
    #error "This POV-Ray SDL code requires the yuqk fork."
#end
global_settings { assumed_gamma 1 shadow_tolerance 1e-5 }
#declare Grey50 = srgb <0.5,0.5,0.5>;
background { Grey50*0.2 }
#declare Camera00 = camera {
    perspective
    location <3,+3,-3.001>*0.7
    sky y
    angle 35
    right x*(image_width/image_height)
    look_at <0,0,0>
}
#declare VarOrthoMult =
    1.2/max(image_width/image_height,image_height/image_width);
#declare Camera01z = camera {
    orthographic
    location <0,0.5,-2> // 0,0,-2
    direction z
    right VarOrthoMult*x*max(1,image_width/image_height)
    up VarOrthoMult*y*max(1,image_height/image_width)
}
#declare Camera01y = camera {
    orthographic
    location <0,2,0>
    direction -y
    right VarOrthoMult*x*max(1,image_width/image_height)
    up VarOrthoMult*z*max(1,image_height/image_width)
}
#declare Camera01x = camera {
    orthographic
    location <2,0,0>
    direction -x
    right VarOrthoMult*z*max(1,image_width/image_height)
    up VarOrthoMult*y*max(1,image_height/image_width)
}
#declare White = srgb <1,1,1>;
#declare Light00 = light_source { <50,150,-250>, White }
#declare Red = srgb <1,0,0>;
#declare CylinderX = cylinder { -1*x, 1*x, 0.01 pigment { Red } }
#declare Green = srgb <0,1,0>;
#declare CylinderY = cylinder { -1*y, 1*y, 0.01 pigment { Green } }
#declare Blue = srgb <0,0,1>;
#declare CylinderZ = cylinder { -1*z, 1*z, 0.01 pigment { Blue } }

//--- scene ---
    light_source { Light00 }
    camera { Camera00 }
//  camera { Camera01x }
//  camera { Camera01y }
  //camera { Camera01z }
    object { CylinderX }
  //object { CylinderY }
    object { CylinderZ }

#declare Ary = array {
    <+1.50,+1.00> // Cstart
    <+0.05,+0.00>
    <+0.00,+0.45>
    <+0.40,+0.47>
    <+0.40,+0.53>
    <+0.00,+0.55>
    <+0.05,+0.90>
    <+1.50,+0.00> // Cend
}

#local N = dimension_size(Ary, 1);

#declare Sor00 = sor {
    N
    #for (PP, 0, N-1)
    Ary[PP]
    #end
}

#declare Cherokee = srgb <0.98824,0.8549,0.59608>;
#declare Cherry = srgb <0.87059,0.19216,0.38824>;
#declare CherryBlossomPink = srgb <1,0.71765,0.77255>;
#declare ChathamsBlue = srgb <0.0902,0.33333,0.47451>;
#declare Cherrywood = srgb <0.41176,0.11765,0.09412>;

#declare CylY  = cylinder { -1*y, 1*y, 0.03 pigment { Green*0.6 } }
#declare CylYY = cylinder { -1*y, 1*y, 0.30 }
#if (1)
difference {
    union {
        sor { Sor00 caps on
            pigment{Green} }
        sor { Sor00 caps off intervals "10000"
            pigment{Cherokee} }
        sor { Sor00 caps off intervals "01000"
            pigment{Cherry} }
        sor { Sor00 caps off intervals "00100"
            pigment{CherryBlossomPink} }
        sor { Sor00 caps off intervals "00010"
            pigment{ChathamsBlue} }
        sor { Sor00 caps off intervals "00001"
            pigment{Cherrywood} }
    }
    object { CylYY translate <+0.2,0,-0.2> }
    cutaway_textures
}
#elseif (0)
    union {
        intersection {
            object { CylY }
            sor    { Sor00 intervals "11011" }
        }
        intersection {
            object { CylY pigment { srgb <0.5,0.0,0.2> } }
            sor    { Sor00 intervals "00100" }
        }
        rotate +22*(x+z)
    }
#else
    object { Sor00 }
#end