POV-Ray : Newsgroups : povray.newusers : Background and area light Server Time
28 Mar 2024 04:55:34 EDT (-0400)
  Background and area light (Message 1 to 4 of 4)  
From: PerroNoob
Subject: Background and area light
Date: 29 Dec 2016 17:45:00
Message: <web.58659163c29d0dd2f8c3c8dd0@news.povray.org>
I'm trying to render a long rectangle (with some extra stuff) using an area
light. The problem is that I always see a dark background, even if I extend the
area light further along the z direction. If I change the perspective, I also
see that extending the area light region does not have much effect, there is
always a darker side on the rectangle, which I don't know why. I've also tried
increasing the height (y direction) of the area light with a better result,
however the shadows are smaller in that case.

What I want is to make most of the floor and background as white as possible but
without making the rectangle to look too bright (that's why I use a gray
background).

The code is here (I'm using the rc3metal files; btw, is there a way to make the
Bronze rectangles even more realistic? do I need a turbulence or something like
that?) :


# -----------------------------------------------------------------------------

#include "colors.inc"
#include "textures.inc"
#include "metals.inc"
#include "rad_def.inc"
#include "rc3metal.inc"
// RC3Metal_Set_highlight (0.3)
#declare BLURRED_REFLECTION = 1;

global_settings
{ assumed_gamma 1
  max_trace_level 30
    radiosity
    { count 200
      error_bound 0.1
      normal on //for spun brass
      pretrace_end 0.005
      recursion_limit 6
      brightness 0.5
    }
}

background { color rgb <0.6, 0.6, 0.6> }

camera{
    location <100, 50, -30>
    look_at <15, -40, 110>
    up        1 * y
    right     2 * x
}

#for (z_disp, 22, 260, 44)
    box {
        <0, 0, z_disp>, <40, 10, z_disp + 22>
        RC3Metal_Texture (RC3M_C_CHROME, 0.3, 0.3)
        // normal {granite 0.1
  // scale <0.1, 20, 1>
  // no_bump_scale}
    }
#end

#for (z_disp, 0, 260, 44)
    box {
        <0, 0, z_disp>, <40, 10, z_disp + 22>
        RC3Metal_Blur_t
        ( RC3Metal_Texture (RC3M_C_ZINC, 0.5, 0.7),
        0.25, 0.001, 1
        )
    }
#end

#for (z_disp, 18, 260, 44)
    box {
        <0, 10, z_disp>, <40, 12, z_disp + 30>
        RC3Metal_Texture (RC3M_C_BRONZE_NEW, 0.2, 0.2)
        // normal {granite 0.1
  // scale <0.1, 20, 1>
  // no_bump_scale}
    }
#end

plane {
    // We can use 'y' instead '<0, 1, 0>'
    <0, 1, 0>, 0
    texture {
        // pigment { checker color White color Black }
        pigment{ color White }
        finish{ambient 0 diffuse 0.8}
        // normal {granite 0.5 scale 0.001}
    }
}

light_source { <-30, 150, 10>
               color White
               area_light 80*x, 300*z, 10, 10
               jitter
               }

# -----------------------------------------------------------------------------


Post a reply to this message

From: omniverse
Subject: Re: Background and area light
Date: 30 Dec 2016 01:55:01
Message: <web.586604733800872e9c5d6c810@news.povray.org>
"PerroNoob" <ara### [at] gmailcom> wrote:
> I'm trying to render a long rectangle (with some extra stuff) using an area
> light. The problem is that I always see a dark background, even if I extend the
> area light further along the z direction. If I change the perspective, I also
> see that extending the area light region does not have much effect, there is
> always a darker side on the rectangle, which I don't know why. I've also tried
> increasing the height (y direction) of the area light with a better result,
> however the shadows are smaller in that case.
>
> What I want is to make most of the floor and background as white as possible but
> without making the rectangle to look too bright (that's why I use a gray
> background).
>
> The code is here (I'm using the rc3metal files; btw, is there a way to make the
> Bronze rectangles even more realistic? do I need a turbulence or something like
> that?) :

There isn't anything for the metal to reflect so that's why it appears
featureless, it's only reflecting the background gray. A normal, such as
granite, would make it less flat but possibly grainy or wavy depending on scale
of that.

I rendered your scene using a large sphere, instead of background color, putting
an image_map of a room picture in it. That gave it something to reflect. Depends
on what your wanting it to be like. I also tried just a pigment pattern and that
might not be able to produce a discernable reflection object. In other words,
could lack a perceived reflection from external source unless you can also see
that elsewhere (from behind, above, wherever).
A "room" reflected in the metal probably doesn't need to be seen to know it's
from the surroundings.

The ground plane might be able to use something like:

    finish{ambient 0 diffuse 0.1 specular 0.9 roughness 9}

Maybe extreme but this would even out the brightness and still leave a shadow,
versus using emission 0.5 for example which would affect that shadow.

Bob


Post a reply to this message

From: clipka
Subject: Re: Background and area light
Date: 30 Dec 2016 07:11:30
Message: <58664ef2$1@news.povray.org>
Am 29.12.2016 um 23:42 schrieb PerroNoob:
> I'm trying to render a long rectangle (with some extra stuff) using an area
> light. The problem is that I always see a dark background, even if I extend the
> area light further along the z direction. If I change the perspective, I also
> see that extending the area light region does not have much effect, there is
> always a darker side on the rectangle, which I don't know why. I've also tried
> increasing the height (y direction) of the area light with a better result,
> however the shadows are smaller in that case.
> 
> What I want is to make most of the floor and background as white as possible but
> without making the rectangle to look too bright (that's why I use a gray
> background).

I'm not sure I correctly understand what you're trying to describe, but
I have a hunch that "area_illumination on" might be what you want.

Without that, area lights only affect the boundary of shadows, while
still acting like point lights with regards to how bright unshadowed
surfaces appear. So if your area light is 1000 x 1 meters, and only a
meter away from a surface, you only get a perfectly symmetric bright
spot near the light source's nominal center, rather than the expected
bright stripe along the whole length of the area light, because this
dimming is not due to shadows but due to the angle at which the light
hits the surface.

"area_illumination" was specifically introduced to fix this.


Post a reply to this message

From: Alain
Subject: Re: Background and area light
Date: 30 Dec 2016 14:42:56
Message: <5866b8c0@news.povray.org>

> I'm trying to render a long rectangle (with some extra stuff) using an area
> light. The problem is that I always see a dark background, even if I extend the
> area light further along the z direction. If I change the perspective, I also
> see that extending the area light region does not have much effect, there is
> always a darker side on the rectangle, which I don't know why. I've also tried
> increasing the height (y direction) of the area light with a better result,
> however the shadows are smaller in that case.
>
> What I want is to make most of the floor and background as white as possible but
> without making the rectangle to look too bright (that's why I use a gray
> background).
>
> The code is here (I'm using the rc3metal files; btw, is there a way to make the
> Bronze rectangles even more realistic? do I need a turbulence or something like
> that?) :
>
>
> # -----------------------------------------------------------------------------
>
> #include "colors.inc"
> #include "textures.inc"
Not used
> #include "metals.inc"
Not used
> #include "rad_def.inc"
Not used
> #include "rc3metal.inc"
> // RC3Metal_Set_highlight (0.3)
> #declare BLURRED_REFLECTION = 1;
>
> global_settings
> { assumed_gamma 1
>   max_trace_level 30
This may need to be increased.
>     radiosity
>     { count 200
Try something like count 200 25000
It can really improve your results.
>       error_bound 0.1
>       normal on
You can probably do without this
>       pretrace_end 0.005
>       recursion_limit 6
Maybe a little large, 3 or 4 should be enough.
>       brightness 0.5
If it's to dim, try removing this.
>     }
> }
>
> background { color rgb <0.6, 0.6, 0.6> }
>
> camera{
>     location <100, 50, -30>
>     look_at <15, -40, 110>
>     up        1 * y
>     right     2 * x
> }
>
> #for (z_disp, 22, 260, 44)
>     box {
>         <0, 0, z_disp>, <40, 10, z_disp + 22>
>         RC3Metal_Texture (RC3M_C_CHROME, 0.3, 0.3)
>         // normal {granite 0.1
>   // scale <0.1, 20, 1>
>   // no_bump_scale}
>     }
> #end
>
> #for (z_disp, 0, 260, 44)
>     box {
>         <0, 0, z_disp>, <40, 10, z_disp + 22>
>         RC3Metal_Blur_t
>         ( RC3Metal_Texture (RC3M_C_ZINC, 0.5, 0.7),
>         0.25, 0.001, 1
>         )
>     }
> #end
>
> #for (z_disp, 18, 260, 44)
>     box {
>         <0, 10, z_disp>, <40, 12, z_disp + 30>
>         RC3Metal_Texture (RC3M_C_BRONZE_NEW, 0.2, 0.2)
>         // normal {granite 0.1
>   // scale <0.1, 20, 1>
>   // no_bump_scale}
>     }
> #end
>
> plane {
>     // We can use 'y' instead '<0, 1, 0>'
>     <0, 1, 0>, 0
>     texture {
>         // pigment { checker color White color Black }
>         pigment{ color White }
Try using some pattern instead, like granite or bumps. To get lighter 
general tints, use a colour_map:
colour_map{[0 rgb 0.6][1 rgb 1]}
To get some special effects:
colour_map{[0 rgb 0.6][0.98 rgb 0.97][1 rgb 10]}
>         finish{ambient 0 diffuse 0.8}
>         // normal {granite 0.5 scale 0.001}
>     }
> }
>
> light_source { <-30, 150, 10>
>                color White
>                area_light 80*x, 300*z, 17, 33
>                jitter
	area_illumination // spread the illumination
	adaptive 0 // offer dramatic speed improvment
>                }
>
> # -----------------------------------------------------------------------------
>
>
>


still act as a point light whenever shadows are not concerned.

To look realistic, metallic textures need something to reflect other 
than a plain background.
Use a sky_sphere with some clouds or a high dynamic range light probe. 
You may also use a plane as a kind of sky or a very large sphere. It can 
also be some objects that don't need to be complex. Some boxes and 
spheres with non-uniform and non-metallic textures can do the trick.


your metal texture rely essentially on actual reflection rather than 
radiosity.



Alain


Post a reply to this message

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.