I have the following in POV (trying to make transparent glass/crystal ball)
and the results is not what I expect/want.  What can I improve below or what
am I doing wrong?

include "finish.inc"
include "textures.inc"
include "colors.inc"
include "glass.inc"
include "stones.inc"

camera {
        location <0,0,-3>
        look_at <0,0,1>
}

light_source { <0,2,-2> color White}

  plane { <0, 1, 0>, -1
    pigment {
      color Red
    }
  }

  cylinder {
    <0, 0, -10>,     // Center of one end
    <0, 10, -10>,     // Center of other end
   2.0         // Radius
   open           // Remove end caps
    texture { T_Stone25 scale 4 }
  }

object {
sphere {
  <0, 1, 2>, 2

photons{
  target
  reflection on
  refraction on
}

  pigment {
  //color  rgb <1,1,1> transmit 1
        Col_Glass_Clear
      }
  finish{ reflection{0,1 fresnel on}}
    interior {ior 1.5}
}
}

Post a reply to this message

On Wed, 12 Nov 2003 06:16:45 -0500, "George Yanez" <gya### [at] ncrrcom> wrote:

>I have the following in POV (trying to make transparent glass/crystal ball)
>and the results is not what I expect/want.  What can I improve below or what
>am I doing wrong?

Your are doing nothing wrong. It's just that you expect a different result. Try
changing the plane to a checker 
  plane { <0, 1, 0>, -1
    pigment {
      checker
      color rgb 1
      color blue 1
      scale 0.5
    }
    finish{
      diffuse 0.8
      ambient 0.1
    }
}

and move the camera back to get a better view. Also note what Warp wrote.

Regards
        Stephen

Post a reply to this message

I also want to make the ball see-through...transparent...I was told to use
rgbft/transmit function...in my example I commented it out.  Is the
use/placement of it in my code provided correct or not?

Post a reply to this message

On Wed, 12 Nov 2003 07:22:16 EST, "gyanez" <gya### [at] ncrrcom> wrote:

>I also want to make the ball see-through...transparent...I was told to use
>rgbft/transmit function...in my example I commented it out.  Is the
>use/placement of it in my code provided correct or not?

Yes that is correct. You can also use 
color  rgbt <1,1,1,1> and color  rgbft <1,1,1,0,1> 

Note that filter and transmit should add up to one (1) unless you want strange
results.
To see what is happening put something behind the ball and raise the light
source. For instance.
#include "finish.inc"
#include "textures.inc"
#include "colors.inc"
#include "glass.inc"
#include "stones.inc"

camera {   // Front
        location <0,2,-10>
        look_at <0,0,1>
} 


/*
camera {   // Side
        location <10,2,-10>
        look_at <0,0,1>
}
*/

light_source { <0,5,-2> color White}

  plane { <0, 1, 0>, -1

    pigment {
      checker
      color rgb 1
      color blue 1
      scale 0.5
    }
    finish{
      diffuse 0.8
      ambient 0.1
    }

  }

  

object {
sphere {
  <0, 1, 2>, 2
//no_image         // Un comment to view without the sphere
photons{
  target
  reflection on
  refraction on
}

  pigment {
  color  rgbft <1,0,0,1,0> 
//        Col_Glass_Clear
      }
  finish{ reflection{0,1 fresnel on}}
    interior {ior 1.5}
}
}

  cone { <0, 7, 0>, 0.0, <0, 0, 0>, 1.0 
  
  translate <1,-1,10>
  
texture {
  pigment { colour rgb<1,1,1>         
  }
  finish {           // (---surface finish---)
    ambient 0.2
    specular 0.6     // shiny
  }
}
  
  } 

Regards
        Stephen

Post a reply to this message

George Yanez <gya### [at] ncrrcom> wrote:
> I have the following in POV (trying to make transparent glass/crystal ball)
> and the results is not what I expect/want.

  Mainly because you don't have details in the environment for the sphere
to reflect/refract.
  Try this:

-----------8<-----------8<-----------8<-----------8<-----------8<-----------
global_settings { photons { count 10000 } }

camera { location <2,5,-10>*.7 look_at 0 angle 35 }
light_source { <15,20,-4>, 1 fade_distance 20 fade_power 2 }
light_source { <-20,10,-5>, <.5,.25,.1> fade_distance 20 fade_power 2 }

// Glass sphere
sphere { 0,1
// You can also try this instead of the above for a hollow sphere:
//difference { sphere { 0,1 } sphere { 0, .9 }
  pigment { rgbf 1 }
  finish
  { specular 2 roughness .005
    reflection { .2, .4 }
  }
  interior { ior 1.5 }
  photons { target reflection on refraction on }
}

// Floor. (Don't mind the complexity, it's just for getting details)
plane
{ y,-1
  pigment { checker rgb 1, rgb .5 }
  #declare TileNormal =
    normal
    { gradient x 1 slope_map
      { [0 <0,1>][.05 <1,0>][.95 <1,0>][1 <0,-1>] }
    }
  normal
  { average normal_map
    { [1 TileNormal]
      [1 TileNormal rotate y*90]
    }
  }
  finish { specular .5 }
}
-----------8<-----------8<-----------8<-----------8<-----------8<-----------

-- 
#macro M(A,N,D,L)plane{-z,-9pigment{mandel L*9translate N color_map{[0rgb x]
[1rgb 9]}scale<D,D*3D>*1e3}rotate y*A*8}#end M(-3<1.206434.28623>70,7)M(
-1<.7438.1795>1,20)M(1<.77595.13699>30,20)M(3<.75923.07145>80,99)// - Warp -

Post a reply to this message

On 12 Nov 2003 09:06:31 -0500, Warp <war### [at] tagpovrayorg> wrote:

> George Yanez <gya### [at] ncrrcom> wrote:
>> I have the following in POV (trying to make transparent glass/crystal 
>> ball)
>> and the results is not what I expect/want.
>
>   Mainly because you don't have details in the environment for the sphere
> to reflect/refract.
>   Try this:
>
> -----------8<-----------8<-----------8<-----------8<-----------8<-----------
> global_settings { photons { count 10000 } }
>
> camera { location <2,5,-10>*.7 look_at 0 angle 35 }
> light_source { <15,20,-4>, 1 fade_distance 20 fade_power 2 }
> light_source { <-20,10,-5>, <.5,.25,.1> fade_distance 20 fade_power 2 }
>
> // Glass sphere
> sphere { 0,1
> // You can also try this instead of the above for a hollow sphere:
> //difference { sphere { 0,1 } sphere { 0, .9 }
>   pigment { rgbf 1 }
>   finish
>   { specular 2 roughness .005
>     reflection { .2, .4 }
>   }
>   interior { ior 1.5 }
>   photons { target reflection on refraction on }
> }
>
> // Floor. (Don't mind the complexity, it's just for getting details)
> plane
> { y,-1
>   pigment { checker rgb 1, rgb .5 }
>   #declare TileNormal =
>     normal
>     { gradient x 1 slope_map
>       { [0 <0,1>][.05 <1,0>][.95 <1,0>][1 <0,-1>] }
>     }
>   normal
>   { average normal_map
>     { [1 TileNormal]
>       [1 TileNormal rotate y*90]
>     }
>   }
>   finish { specular .5 }
> }
> -----------8<-----------8<-----------8<-----------8<-----------8<-----------
>

It always amazes me how just a few lines of code can produce something 
that looks so gorgeous, "Don't mind the complexity" that's like a 
matador's cape to me:) Slope-map's? Haven't really looked at normals yet, 
those look -interesting- ah well, there goes the evening:)

--
Phil

-- 
Using M2, Opera's revolutionary e-mail client: http://www.opera.com/m2/

Post a reply to this message

"Phil Cook" <phi### [at] nospamdeckingdealscouk> wrote in message
news:opryja1daup4ukzs@news.povray.org...


Gah - now I've got to render the damn thing...

Post a reply to this message

"Warp" <war### [at] tagpovrayorg> wrote in message news:3fb23e67@news.povray.org...

Just out of curiousity, why:

reflection { .2, .4 }

rather than

reflection{fresnel}

?

(or, more accurately, why doesn't fresnel produce such nice results as .2, .4 ?)

Post a reply to this message

In article <3fb26d11$1@news.povray.org>,
 "Tom Melly" <tom### [at] tomandlucouk> wrote:

> (or, more accurately, why doesn't fresnel produce such nice results as .2, .4 
> ?)

Because you're using it wrong. First, fresnel reflection varies from 0 
to 1 by default, so "reflection {fresnel}" isn't even remotely 
equivalent to "reflection {0.2, 0.4}". And second...glass reflection 
isn't really very variable. Get a piece of glass and look at it from 
various angles...the reflection stays pretty much the same (there is a 
sharp increase where total internal reflection starts, but that is a 
separate effect that POV also simulates). Water and many ceramic glazes 
and plastics do have highly variable reflection.

-- 
Christopher James Huff <cja### [at] earthlinknet>
http://home.earthlink.net/~cjameshuff/
POV-Ray TAG: chr### [at] tagpovrayorg
http://tag.povray.org/

Post a reply to this message

Christopher James Huff <cja### [at] earthlinknet> wrote:
> glass reflection isn't really very variable.

  That depends a lot in the type of glass and its coating layer.
  There are certain types of glass surface finishes which exhibit a very
pronounced variable reflection. When you look at the glass right from
the front, it reflects some, but you can mostly see through it. However,
when you look at it at a sharp angle, it's almost like a mirror.

  Next time you walk on a street, try looking at the store windows from
different angles... :)

-- 
plane{-x+y,-1pigment{bozo color_map{[0rgb x][1rgb x+y]}turbulence 1}}
sphere{0,2pigment{rgbt 1}interior{media{emission 1density{spherical
density_map{[0rgb 0][.5rgb<1,.5>][1rgb 1]}turbulence.9}}}scale
<1,1,3>hollow}text{ttf"timrom""Warp".1,0translate<-1,-.1,2>}//  - Warp -

Post a reply to this message