I've got some confusion about the use of the key word "collect off" in
Photon scene containing glass objects.

The Photon tip in the Help on POV-Ray says "Use collect off in glass
objects. "
However, the "Photon Scene template" does not have the "collect off" key
words in the example.
I have hard time understanding the meaning of the tip for the glass objects.
Any reason for the tip? Is this related to rendering speed or quality?

Would anyone  help me understand the meaning of the Photon tip for the
glass?

Another question:
Does this keyword "collect off" have same effect as the "target 0" ?

Thanks a lot.

Jong

== copy of the POV help file on Photon ==
The keyword "collect off" causes the object to ignore photons. Photons are
neither deposited nor gathered on that object.
Note: Photons will not be shot at an object unless you specify the "target"
keyword. Simply turning refraction on will not suffice.
======================================

Post a reply to this message

"Jong" <jjk### [at] mmewhaackr> wrote in message news:3d3f7940@news.povray.org...
> I've got some confusion about the use of the key word "collect off" in
> Photon scene containing glass objects.
>

<snip>

Hmm, the sample scene does seem odd in that "collect off" is not applied to the
glass object.

In general, glass objects will be photon-targets, in that they will affect
photons, but will have "collect off" so that photons don't show up (or try to
show up) on them. This is because

a) glass doesn't really show photons
b) you can get some odd photon artifacts on glass.

You could view "target" as meaning "influence photons" and "collect on" as
meaning "show photons". IMHO the keyword "target" is slightly misleading.

Post a reply to this message

"Tom Melly" <tom### [at] tomandlucouk> wrote in message
news:3d3fb7bd@news.povray.org...

<snip>

BTW I tried adding "collect off" to the glass objects in the sample scene, but
it initially resulted in appalling artifacts, although rendered very quickly.

Changing the spacing to 0.01 (was 0.02) slowed things down a bit, but the
artifacts went away and it was still a lot faster than the original version.

The differences between the default scene and the "collect off, spacing 0.02"
version were minimal (some highlights on the glass were lost, predictably
enough)

Here are the times (approx.)

The Original version 11m 38s (collect on for glass objects, spacing 0.02)
Bad-Artifact version 0m 26s (collect off for glass objects, spacing 0.02)
Non-Artifact version 1m 40s (collect off for glass objects, spacing 0.01)

I'm mystified as to why turning collect off on the glass objects suddenly
results in such bad artifacts....

Post a reply to this message

Dear Tom,

I really appreciate your kind reply.

"Tom Melly" <tom### [at] tomandlucouk> wrote in message
news:3d3fb7bd@news.povray.org...
> In general, glass objects will be photon-targets, in that they will affect
> photons, but will have "collect off" so that photons don't show up (or try
to
> show up) on them. This is because
> a) glass doesn't really show photons
> b) you can get some odd photon artifacts on glass.

May I regard the "don't show up on" as "don't show up on the surface of" the
glass object? (Since I'm not very good at English, the meaning of some word
is sometimes not very clear to me.)

Thanks,

Jong

Post a reply to this message

"Jong" <jjk### [at] mmewhaackr> wrote in message news:3d3fda7a$1@news.povray.org...
>
> May I regard the "don't show up on" as "don't show up on the surface of" the
> glass object?

Yes.

On the whole, objects either show photons (they collect photons that have passed
through, and been influenced by, a target) or affect photons (they are a target
for the photons emitted by a light).

The reason for this is fairly obvious - objects that affect photons must either
be transparent or reflective, therefore any photons falling on to them will
either pass through or be reflected by them.

Post a reply to this message

"Tom Melly" <tom### [at] tomandlucouk> wrote in message
news:3d3fbdf0@news.povray.org...
>
> The Original version 11m 38s (collect on for glass objects, spacing 0.02)
> Bad-Artifact version 0m 26s (collect off for glass objects, spacing 0.02)
> Non-Artifact version 1m 40s (collect off for glass objects, spacing 0.01)

Wish I had some insight into this to add but I use photons only a fraction
for renderings so it isn't something I'm not extremely familiar with. At
least not for all sorts of situations that can be encountered.

Just wanted to say that I'm making a oil lamp using photons now and noticed
a couple peculiarities. There are crystals hanging from the glass shade,
which I added to the main "chimney" and base. While checking on things, I
removed everything except those crystal pieces and tried collect off to see
how they'd appear alone. The photons stopped showing on the wall and the
render was much slower. I changed back to collect on and it sped up (perhaps
twice as fast) and the photons reappeared on the wall behind them. I wasn't
expecting that to happen.

I was under the impression that collect off only removed photons from the
object itself. Maybe there was some other explanation for what happened, or
even how it works. I was thinking collect off had become a boolean for
turning photons on/off instead of using target to do so.

So anyway that is unlike what your test found. I'm using a spacing of 0.04
but it had been set to 0.06, and 0.1 is still good enough for test renders.
I just realized something else, this depends on dispersion being used too.
Without it I am not seeing the photons occur whether or not collect is on or
off. However, the speed change is still evident. If you are curious, please
try the following scene, it renders in just over 2 minutes on this 800MHz P3
CPU for a 160x120 res. image.

global_settings {
        max_trace_level 9
        photons {
                spacing 0.1
                }
}

camera {
  location  <0, 3, -12>
  look_at   <0, 2,  0>
  right     x*image_width/image_height
}

light_source {
        <15,10,-15>,1
}

box {
        <-36,-12,-36>,<36,24,12>
        pigment {
                rgb 1
        }
}

#declare Crystal_M=
material {
        texture {
                pigment {
                        rgbf 0.999
                }
                finish {
                        ambient 0 diffuse 0.09 specular 0.9 roughness 0.002
                        reflection {0.1,0.5 fresnel}
                }
        }
                interior {
                        ior 1.5 fade_distance 3 fade_power 1111 fade_color
<0.2,0.5,0.7>
                        dispersion 1.05 dispersion_samples 9
 // remove dispersion and photons will also be removed?
                }
}

#local I=9;

#declare Crystal=
intersection {
#while (I>0)
        plane {
                x,1 rotate 15*z rotate 40*I*y
        }
        plane {
                x,1 rotate -30*z rotate 40*I*y
        }
#local I=I-1;
#end
 scale 0.15
}

#local I=6;

#while (I>0)
object {
        Crystal
        material {Crystal_M}
        translate 2.75*x rotate 30*I*y
        translate y
photons {
        target
        reflection on
        refraction on
        collect off // on is faster shows photons, off slower no photons
        }
}
#local I=I-1;
#end

Post a reply to this message

Dear Tom,

 I tried using the keyword, collect off, as you suggested , and the
photon-map tracing got much faster.

Thank you again,

Jong
"Tom Melly" <tom### [at] tomandlucouk> wrote in message
news:3d3ff2b8$1@news.povray.org...
> "Jong" <jjk### [at] mmewhaackr> wrote in message
news:3d3fda7a$1@news.povray.org...
> >
> > May I regard the "don't show up on" as "don't show up on the surface of"
the
> > glass object?
>
> Yes.
>
> On the whole, objects either show photons (they collect photons that have
passed
> through, and been influenced by, a target) or affect photons (they are a
target
> for the photons emitted by a light).
>
> The reason for this is fairly obvious - objects that affect photons must
either
> be transparent or reflective, therefore any photons falling on to them
will
> either pass through or be reflected by them.
>
>

Post a reply to this message