Hmm.  Why is there not any light coming from the cutout?

here's my code:

#include "colors.inc"
#include "woods.inc"

#declare Wall_Texture=
texture{
 pigment{ color White-(White-Khaki)*0.495 }
 normal{ wrinkles 0.2 }
}

#declare light_wood=
pigment{ P_WoodGrain7A color_map {M_Wood7A} }
#declare dark_wood=
pigment{ P_WoodGrain14A color_map {M_Wood14A} }

#declare board_length= 1.5;
#declare board_width= 0.25;

#declare Floor_Texture=
texture{
 pigment{
  gradient y triangle_wave
  pigment_map{
   [ 0.0 light_wood]
   [ 1.0 dark_wood ]
  }
  warp{ repeat board_length*z offset 0.50*y }
  warp{ repeat board_width*x offset board_length*5/2*z }
 }
 normal{
  boxed
  slope_map{
   [0.5 <1.0, 0>]
   [1.0 <0, 0>]
  }
  bump_size 0.1
  scale <board_width,1,board_length>
  warp{ repeat board_length*z }
  warp{ repeat board_width*x offset board_length/2*z }
 }
}

light_source{
 <9,9,9>
 color White
 area_light
 <2,0,0> <0,0,2>
 8,8
 adaptive 0
 jitter
}

camera{
 location <0,5,11>
 look_at <0,5,-10>
}

// Right Wall
box{
 <10,0,-12>,<11,10,12>
 texture{
  Wall_Texture
 }
}

// Left Wall
difference{
 box{
  <-11,0,-12>,<-10,10,12>
  texture{
   Wall_Texture
  }
 }
 box{
  <-8,0,-4>,<-8,8,4>
  texture{
   pigment{
    color White
   }
  }
 }
}

// Back Wall
box{
 <-10,0,-12>,<10,10,-13>
 texture{
  Wall_Texture
 }
}

// The Floor
box{
 <-10,-1,-12>,<10,0,12>
 texture{
  Floor_Texture
 }
}

// The Ceiling
box{
 <-10,10,-12>,<10,11,12>
 texture{
  Wall_Texture
 }
}

// A Round Table
union{
 cylinder { <0,0,0><0,0.1,0> 1.5 }
 cylinder { <0,0,0><0,1.4,0> 0.3 translate 0.1*y }
 cylinder { <0,0,0><0,0.1,0> 3 translate 1.5*y }
 texture { T_Wood1 }
 translate -7.25*z
}

Wade

Post a reply to this message

Wade wrote:
> 
> Hmm.  Why is there not any light coming from the cutout?
> 
> // Left Wall
> difference{
>  box{
>   <-11,0,-12>,<-10,10,12>
     ^^^         ^^^
>   texture{
>    Wall_Texture
>   }
>  }
>  box{
>   <-8,0,-4>,<-8,8,4>
     ^^        ^^
Problem #1:  Your door is infinitely thin in the x axis.
Problem #2:  It's not touching the wall.

Change the <-8,0,-4>,<-8,8,4> to <-12,0,-4> <-9,0,4> and that should fix
it.

[1] I wrote left in the comments because I'm used to having the camera
point in the +z direction.  Your door would actually appear on the right
wall.

-- 
Francois Labreque | Unfortunately, there's no such thing as a snooze
    flabreque     | button on a cat who wants breakfast.
        @         |      - Unattributed quote from rec.humor.funny
   videotron.ca

Post a reply to this message

Here's what I came up with after this "open door with light" idea came up.
http://www.mosquitonet.com/~blessing/door.jpg


Gary
just another new pov user,that likes to share.

Francois Labreque <fla### [at] videotronca> wrote in message
news:3BA0416E.2344A085@videotron.ca...
>
>
> Wade wrote:
> >
> > Hmm.  Why is there not any light coming from the cutout?
> >
> > // Left Wall
> > difference{
> >  box{
> >   <-11,0,-12>,<-10,10,12>
>      ^^^         ^^^
> >   texture{
> >    Wall_Texture
> >   }
> >  }
> >  box{
> >   <-8,0,-4>,<-8,8,4>
>      ^^        ^^
> Problem #1:  Your door is infinitely thin in the x axis.
> Problem #2:  It's not touching the wall.
>
> Change the <-8,0,-4>,<-8,8,4> to <-12,0,-4> <-9,0,4> and that should fix
> it.
>
> [1] I wrote left in the comments because I'm used to having the camera
> point in the +z direction.  Your door would actually appear on the right
> wall.
>
> --
> Francois Labreque | Unfortunately, there's no such thing as a snooze
>     flabreque     | button on a cat who wants breakfast.
>         @         |      - Unattributed quote from rec.humor.funny
>    videotron.ca

Post a reply to this message