Hi folks:

I just finished rendering this little file as a Quicktime Movie, [Start
- 1, End - 50, Frames - 50] and everything worked ok except for the
skysphere, which jumps around like TV static.  Is there an easy way to
minimize this effect?

Thanks,
--Brandan

--------------Begin Scene File----------------

// Persistence of Vision Ray Tracer Scene Description File
// File: .pov
// Vers: 3.1
// Desc: Earth/Moon Flyby
// Date: 10/28/00
// Auth: Brandan Whearty

// ==== Standard POV-Ray Includes ====
#include "colors.inc" // Standard Color definitions
#include "textures.inc" // Standard Texture definitions
#include "metals.inc" // Standard Metal definintions

camera
{ location  <(-1.5+(clock*3)) ,-.03 ,-.08>
  look_at   <0.0 , 0.0 , 0.0>}

// SUN
light_source
{ 0*x
  color rgb<1,1,1>  // light's color
  translate <100, 1,-500>
}

//  STARFIELD
sky_sphere
{
   pigment {
        granite
        color_map {
            [0.72 rgb 0.00 ]
            [0.72 rgb 0.20 ]
            [0.75 rgb 0.00 ]
            [0.78 rgb 0.60 ]
            [0.81 rgb 0.00 ]
            [0.85 rgb 0.05 ]
            [0.91 rgb 1.00 ]
            [0.91 rgb 0.00 ]
        }
    scale .0015
    }
}

// MOON
sphere {<0,0,0> 3
  scale .5
  translate <10,0,0>
  no_shadow
  texture{
    pigment {
      agate
      color_map {
        [0.0 color Grey]
        [0.2 color <1,1,1>]
        [0.4 color LightGrey]
        [0.6 color Grey]
        [0.8 color<.3,.3,.3>]
        [0.9 color Grey]
      }
       scale .3
       turbulence 0
      }
      finish {ambient 0 diffuse 2}
}}

// EARTH LIKE PLANET
sphere {<0,0,0> 3
  translate <-10,0,0>
  texture{
    pigment {
      granite
      color_map {
        [0.0 color Brown]
        [0.2 color DarkGreen]
        [0.3 color DarkBrown]
        [0.4 color DarkGreen]
        [0.45 color Blue]
        [0.6 color Blue]
        [0.7 color Blue]
      }
      scale 6
      turbulence 0
      }
      finish {ambient .1 diffuse 2}
}}

// EARTH LIKE PLANET CLOUD COVER
sphere {<0,0,0> 3.1
  translate <-10,0,0>
  texture{
    pigment {
      agate
      color_map {
        [0.0 color rgbf <1,1,1,1>]
        [0.2 color rgbf <1,1,1,0>]
        [0.5 color <1,1,1,1>]
        [0.6 color <1,1,1,0>]
        [0.8 color <1,1,1,1>]
        [0.9 color <1,1,1,0>]
        [0.92 color <1,1,1,1>]
      }
      scale 10
      turbulence 2
      }
      finish {ambient .2 diffuse 2}
}}

// SPACE SHIP
#macro Hull()
   union{
   union {
     cylinder{ <-3,0,0> <2,0,0> 1}
     sphere {<-3,0,0> 1}
     pigment {P_Chrome5}
     finish {F_MetalA}
     scale <1,.5,1>
   }
   sphere{ <-3,.5,0> .5
     scale <1,1,1>
     pigment {color Blue}
     finish {reflection .5}
   }
   }
#end // Hull

#macro Engine(EngineOffSet)
  union{
  difference {
    union {
      cylinder{<0,0,0> <3,0,0> 1}
      sphere{<0,0,0> 1}
      box{<1,-0,-.1> <3,1.5,.1>}
      box{<1,1.5,.1> <0,0,-.1>
       rotate 45*z
       translate <1.3,-.2,0>
        }
      translate<0,0,EngineOffSet>
      pigment {P_Chrome5}
      finish{F_MetalA}
    }
    sphere{<3,0,0> .7
      translate <0,0,EngineOffSet>
      pigment {color rgb <1,.25,0>}
      finish {ambient 1}
    }
   plane {y,1.5
     inverse}
   plane {y,-1.5}
  }
  }
#end // Engine

object {
  union {
    Hull()
    Engine(1.5)
 Engine(-1.5)
  }
  scale<2,1,1>
  scale<.005,.005,.005>
}

Post a reply to this message

Brandan Whearty <ema### [at] domaincom> wrote:
> I just finished rendering this little file as a Quicktime Movie, [Start
> - 1, End - 50, Frames - 50] and everything worked ok except for the
> skysphere, which jumps around like TV static.  Is there an easy way to
> minimize this effect?

The problem is with the starfield texture.  Using a granite pattern scaled
that small means that you don't actually see the coherent pattern itself.
Instead, each ray fired at the sky-sphere picks up points in the pattern so
far apart (relative to the size of the pattern's details) that they might as
well be random noise.  This, of course, is perfect for still starfield
scenes.  In animations with a moving camera, however, each camera viewpoint
results in a different set of 'random' points, making the starfield flicker
from frame to frame.

The solution is to use a pigment (such as crackle, or a pre-rendered
image-map) that looks like a starfield at a larger scale, so the samples
aren't taken randomly, e.g.:

sky_sphere {
   pigment {crackle color_map {[.5 rgb 0] [1 rgb 2]} scale .01}
   }

Or, you can create the stars using objects - my Galaxy Include file includes
various functions for this and other space backgrounds:

   http://www.geocities.com/ccolefax

Post a reply to this message

<snip>

>
> sky_sphere {
>    pigment {crackle color_map {[.5 rgb 0] [1 rgb 2]} scale .01}
>    }
>
> Or, you can create the stars using objects - my Galaxy Include file includes
> various functions for this and other space backgrounds:
>
>    http://www.geocities.com/ccolefax

Thanks.  It worked like a charm.
-- Brandan

Post a reply to this message