I'm trying to make a bright yellow glowing spot.
I've tried a sphere to and emitting yellow media, and a point light in
a sphere.

Thanks in advance for any advice.
I got it work with a halo, but alas I can't get it to work with media

Heather
hjpinnix@mindspring

Post a reply to this message

On Sat, 1 Jul 2000 16:17:16 -0400, "Heather Pinnix"
<hjp### [at] mindspringcom> wrote:

>I'm trying to make a bright yellow glowing spot.
>I've tried a sphere to and emitting yellow media, and a point light in
>a sphere.

Emitting media should work. Was your container object hollow? Try
something like

sphere
{ 0, 1
  pigment { rgbf 1 }
  interior 
  { media { emission Yellow absorption Blue density { spherical } }
}

You can also try to do it with a lens flare using Chris or Nathan's
include files.


Peter Popov ICQ : 15002700
Personal e-mail : pet### [at] usanet
TAG      e-mail : pet### [at] tagpovrayorg

Post a reply to this message

In article <395e5143$1@news.povray.org>, "Heather Pinnix" 
<hjp### [at] mindspringcom> wrote:

> I'm trying to make a bright yellow glowing spot.
> I've tried a sphere to and emitting yellow media, and a point light in
> a sphere.
> 
> Thanks in advance for any advice.
> I got it work with a halo, but alas I can't get it to work with media

I do it in one of two ways, depending on what I need. Media is slower, 
but much more versatile, and if you use MegaPOV and sampling method 3, 
the speed isn't usually a problem. The light-sphere-highlight method is 
normally much faster, and gives light to surrounding objects, but can't 
do some of the things media can do, and could really slow things down if 
you have a lot of "spots".
You might also want to look at one of the lens flare includes:
NKFlare: http://nathan.kopp.com/nkflare.htm
Chris Colfax's Lens Effects: http://www.geocities.com/ccolefax/


camera {
    location <0, 3.5,-10>
    angle 45
    look_at <0, 0, 0>
}
box {<-100, 0,-100>, < 100, 0, 100>
    texture {pigment {checker color Black, color White}}
}

//the media method
//make sure you use the "hollow" keyword. And don't
//forget that media is scale-dependant, a greater thickness
//of media will be brighter.
sphere {< 0, 0, 0>, 1
    texture {pigment {color White filter 1}}
    hollow
    interior {
        media {
            emission color rgb < 1, 1, 0.2>
            samples 15
            density {spherical
                color_map {
                    [0 color Black]
                    [1 color White]
                }
            }
        }
    }
    translate < 2, 1.2, 0>
}

//light-sphere-highlight method
//The glow is actually the highlight from the light source
//on the sphere.
union {
    sphere {< 0, 0, 0>, 1
        texture {
            pigment {color White filter 1}
            finish {
                specular 1
            }
        }
    }
    light_source {<0,0,0> color rgb < 1, 1, 0.2>}
    translate <-2, 1.2, 0>
}

-- 
Christopher James Huff - Personal e-mail: chr### [at] maccom
TAG(Technical Assistance Group) e-mail: chr### [at] tagpovrayorg
Personal Web page: http://homepage.mac.com/chrishuff/
TAG Web page: http://tag.povray.org/

Post a reply to this message

Taking all the fun out of do-it-yourself, there's this:

#declare GS=
sphere {0,1 hollow
        pigment {rgbf 1}
 interior {
  media {intervals 12 samples 3,3
        emission <.67,.75,.33> absorption <.33,.25,.67>
         scattering {4,<.67,.75,.33>} // type 1 is softer, 2-4 tighter and
intense
          density {spherical
                   density_map {
                    [0 rgb 0]
                    [.33 rgb .75] // vary index to change sharpness/softness
                    [1 rgb 1]
                    }ramp_wave}}
 }
}

#declare GlowSpot=
light_source {0,<.67,.75,.33>
  looks_like {GS}
        fade_distance 1 fade_power 2
}

GlowSpot

camera {location -5*z
        look_at 0
}

plane {y,-1.01 pigment {rgb 1}}

Post a reply to this message

Yet another way to do this:

#declare light_object =
   sphere { 0,1
            pigment {  rgbf <1,1,1,1> }
            finish { specular 5 metallic} }

 light_source { 0*x color rgb <1,0.75,0> looks_like { light_object } }

From my Cyclopedia entry on the "looks_like" statement.

Josh English

Heather Pinnix wrote:

> I'm trying to make a bright yellow glowing spot.
> I've tried a sphere to and emitting yellow media, and a point light in
> a sphere.
>
> Thanks in advance for any advice.
> I got it work with a halo, but alas I can't get it to work with media
>
> Heather
> hjpinnix@mindspring

--
Josh English
eng### [at] spiritonecom
"May your hopes, dreams, and plans not be destroyed by a few zeros."

Post a reply to this message

In article <3961187A.C5ADC831@spiritone.com>, Josh English 
<eng### [at] spiritonecom> wrote:

> Yet another way to do this:

And another:(untested, but it should work)
#macro LightningBug(CameraPos, BugPos, Radius, Col)
    disk {BugPos, CameraPos-BugPos, Radius
        texture {
            pigment {spherical
                color_map {
                    [0 color rgbf < 1, 1, 1, 1>]
                    [1 color Col]
                }
                translate BugPos
            }
            finish {ambient 1}
        }
    }
#end

-- 
Christopher James Huff - Personal e-mail: chr### [at] maccom
TAG(Technical Assistance Group) e-mail: chr### [at] tagpovrayorg
Personal Web page: http://homepage.mac.com/chrishuff/
TAG Web page: http://tag.povray.org/

Post a reply to this message

Try using this.
interior
{
media { emission <0.75,1,0> absorption <0.25,0,1>
density { spherical } } }

It looks more green.
Brendan Ryan

Peter Popov wrote:

> On Sat, 1 Jul 2000 16:17:16 -0400, "Heather Pinnix"
> <hjp### [at] mindspringcom> wrote:
>
> >I'm trying to make a bright yellow glowing spot.
> >I've tried a sphere to and emitting yellow media, and a point light in
> >a sphere.
>
> Emitting media should work. Was your container object hollow? Try
> something like
>
> sphere
> { 0, 1
>   pigment { rgbf 1 }
>   interior
>   { media { emission Yellow absorption Blue density { spherical } }
> }
>
> You can also try to do it with a lens flare using Chris or Nathan's
> include files.
>
> Peter Popov ICQ : 15002700
> Personal e-mail : pet### [at] usanet
> TAG      e-mail : pet### [at] tagpovrayorg

Post a reply to this message