I'm impressed with the landscape.pov scene file that comes with POV 
3.5b17. How can I create a cubic panorama with that file? I essentially 
need six 512X512 images that tile seamlessly. Four sides that resemble 
the current landscape scene, one ground plane that is grass or dirt only 
without trees, and one sky plane. The four sides would need to be 
further away from the central viewpoint than they currently are. The 
trees are too close. Sort of like being in the center of a huge valley 
surrounded by hills and trees on all sides.

Any ideas on how to achieve that based on the current file?

Bob

Post a reply to this message

> I'm impressed with the landscape.pov scene file that comes with POV
> 3.5b17. How can I create a cubic panorama with that file? I essentially
> need six 512X512 images that tile seamlessly. Four sides that resemble
> the current landscape scene, one ground plane that is grass or dirt only
> without trees, and one sky plane. The four sides would need to be
> further away from the central viewpoint than they currently are. The
> trees are too close. Sort of like being in the center of a huge valley
> surrounded by hills and trees on all sides.
> 
> Any ideas on how to achieve that based on the current file?

I haven't looked at that scene yet, but you should be able to achieve what
you want using this camera:

#macro CubicQTVRCam(loc)
    camera {
        location 0
        #switch (clock)
            #range(0, 3) //front - right - back - left
                up 2*image_height/(image_height-1)*y
                right 2*image_width/(image_width-1)*x
                direction z
            #break
            #case(4) //ceiling
                up -2*image_height/(image_height-1)*z
                right 2*image_width/(image_width-1)*x
                direction y
            #break
            #case(5) //floor
                up 2*image_height/(image_height-1)*z
                right 2*image_width/(image_width-1)*x
                direction -y
            #break
        #end
        #if (clock < 4)
            rotate clock*90*y
        #end
        translate loc
    }
#end

Rendering an animation of square images with clock running from 0 to 5 using
this camera should produce 6 images that are properly oriented for direct
feeding to MakeCubic.

This is from an include file that I've started to write some time ago that
provides ready-to-use QTVR cams, also a cylindric one, and can make
suggestions about whether to use a cylindrical or cubic camera, and what
image dimensions to use for cylindric cameras. Maybe I'll release it to the
public some day when I get around to finishing it and writing some
documentation.

If you are wondering about the 2*image_height/(image_height-1) stuff, this
is to compensate for the half pixel that QTVR cuts off the image borders (in
order to interpolate more easily at the edges of the cube). This, and the
"camera off by half a pixel" flaw of previous versions, makes it require POV
3.5.

 -Christian

Post a reply to this message