#include "colors.inc"	// Standard Color definitions
#include "textures.inc"	// Standard Texture definitions
#include "metals.inc"  
#include "tuyau1.pov"

light_source{<50,5,-75>  color White  }
light_source{<-12,5,-3>  color White} 
  
camera
{
  location  <0,5,-50 >
  direction 1.5*z
  right     1.5*x
  look_at   <0, 0,0>
}     

#declare Tex_mec=texture { T_Brass_5C finish { crand 0.1}}  

#declare Barre3=difference {
  union { box { -1,1 scale <1,3,0.1>}
          cylinder {<0,3,-0.1>,<0,3,0.1>,1}
          cylinder {<0,-3,-0.1>,<0,-3,0.1>,1}}
  cylinder {<0,3,-0.2>,<0,3,0.2>,0.5}
  cylinder {<0,0,-0.2>,<0,0,0.2>,0.5}        
  cylinder {<0,-3,-0.2>,<0,-3,0.2>,0.5}
  cylinder {<0,-3,-0.2>,<0,-3,-0.7>,0.7}                 
  texture {Tex_mec normal { bumps 0.3 scale 0.1}}
  }  
  
#declare Barre2=difference {
  union { box { -1,1 scale <1,1.5,0.1>}
          cylinder {<0,1.5,-0.1>,<0,1.5,0.1>,1}
          cylinder {<0,-1.5,-0.1>,<0,-1.5,0.1>,1}}
    cylinder {<0,1.5,-0.2>,<0,1.5,0.2>,0.5}
    cylinder {<0,-1.5,-0.2>,<0,-1.5,0.2>,0.5}
    cylinder {<0,-1.5,-0.15>,<0,-1.5,-0.2>,0.7}            
  texture {Tex_mec normal { bumps 0.3 scale 0.1}}
  }  
  
#declare vis= difference
{ cylinder { 0,z,0.6 scale <1,1,0.25>}
  box {<-0.15,0.7,0.05>,<0.15,-0.7,0.3>}
  box {<-0.15,0.45,0.1>,<0.15,-0.45,0.3> rotate z*-8}
  box {<-0.15,0.45,0.15>,<0.15,-0.45,0.3> rotate z*-16} 
  
  texture {T_Brass_5C} 
  rotate <0,180,30>}  
  
#declare E_mec= union {  
object { Barre3}
object { Barre3 rotate z*90 translate <3,3,0.15>}  
object { vis translate <0,3,-0.1>}
object { Barre3 rotate z*90 translate <3,-3,0.15>}  
object { vis translate <0,-3,-0.1>} 
object { Barre2 rotate z*90 translate <1.5,0,-0.15>}
object { vis translate <0,0,-0.25>} }

#declare C_mec= union {  
object { Barre3}
object { Barre3 rotate z*90 translate <3,3,0.15>}  
object { vis translate <0,3,-0.1>}
object { Barre3 rotate z*90 translate <3,-3,0.15>}  
object { vis translate <0,-3,-0.1>} 
}
#declare H_mec= union {  
object { Barre3}
object { Barre3 rotate z*90 translate <3,0,0.15>}  
object { vis translate <0,0,-0.1>}
object { Barre3 translate <6,0,0>}  
object { vis translate <6,0,-0.1>} }     

#declare A_mec= union {  
object { Barre3}
object { Barre3 rotate z*90 translate <3,0,0.15>}  
object { vis translate <0,0,-0.1>}
object { Barre3 translate <6,0,0>}  
object { vis translate <6,0,-0.1>} 
object { Barre3 rotate z*90 translate <3,3,0>}  
object { vis translate <0,3,-0.1>}
object { vis translate <6,3,-0.1>}
}                          

#declare P_mec= union {  
  object { Barre3} 
  object { Barre2 rotate z*90 translate <1.5,3,0.15>}  
  object { vis translate <0,3,-0.1>}
  object { Barre2 rotate z*90 translate <1.5,0,0.15>}  
  object { vis translate <0,0,-0.1>}
  object { Barre2 translate <3,1.5,0>}  
  object { vis translate <3,3,-0.1>}
  object { vis translate <3,0,-0.1>}
  }                                 
  

#declare clef= union {
 difference {  cylinder { -0.1*z,0.1*z,1}
               box { <-2,0.4,-0.2>,<0.3,-0.4,0.2>}
               }
 box {<0.8,0.4,0>,<1,-0.4,1>}
 cylinder {<0.9,-0.4,0.9>,<0.9,0.4,0.9>,0.1}
 box {<0.9,0.4,0.9>,<2,-0.4,1.1>}
 difference {
   cylinder { <3,0,0.9>,<3,0,1.1>,1}
   box { -0.4,0.4 rotate z*45 translate <3,0,1>}
   } 
   box { <0.9,0.4,0.9>,<2,-0.4,1.1> translate x*3}
   difference {  cylinder { -0.1*z,0.1*z,1}
               box { <-2,0.4,-0.2>,<0.3,-0.4,0.2>}
               rotate z*180
               translate x*6+z
               }

 texture {Silver_Texture }
 }                
 
 #declare tournevis= union {
  object{tuyau}
  cylinder {<0,2,0>,<0,-1,0>,0.21}
  intersection {box {<-2,-5,-0.4>,<2,2,0.4> rotate x*4} 
                box {<-2,-5,-0.4>,<2,2,0.4> rotate -x*4} 
                box {<-2,-5,-0.4>,<2,2,0.4> rotate z*14}
                box {<-2,-5,-0.4>,<2,2,0.4> rotate -z*14}
                box {<-2,-3,-0.4>,<2,-1,0.4> rotate x*4}
                scale <0.3,1,0.1>
               } 
      texture { Silver_Texture}         
   }            

object { E_mec translate x*-18}  
object { C_mec translate x*-09}
object { H_mec translate x*+00}
object { A_mec translate x*+09}
object { P_mec translate x*+18}



object { Barre2 rotate z*-60 translate <-14,6,0>}

object { clef rotate 25 translate <4,-8,-7>}
object { tournevis scale 1.5 rotate <5,45,90> translate <-4,-4,-8>}
sphere {                  // --- Sky ---
  <0, 0, 0>, 1
  texture {
   pigment {
     gradient y
     color_map {
       [0.0 color rgb < 1.0, 1.0, 1.0 >]
       [0.3 color rgb < 0.5, 0.6, 1.0 >]
     }
   }
   finish { diffuse 0 ambient 1 }
  }
  scale 10000
  hollow on
  no_shadow
}   

object { vis scale 25 translate <0,2,19>}
sphere {-900*z,700 pigment{ MediumSeaGreen}} 
 
 plane { y, -10
  pigment {
    hexagon  color rgbf <0.1, 0.3, 0.8,0.8>
             color rgbf <0.2, 0.5, 0.8,0.8>
             color rgbf <0.2, 0.4, 0.9,0.8> 
    turbulence 0.55         
    scale 10
  }
}