POV-Ray : Newsgroups : povray.general : Texture for translucent polypropylene? Server Time: 16 Dec 2018 22:53:53 GMT
  Texture for translucent polypropylene? (Message 1 to 5 of 5)  
From: bzigon
Subject: Texture for translucent polypropylene?
Date: 19 Jul 2018 21:30:01
Message: <web.5b510294debbec76c17b3fd10@news.povray.org>
Hello
I am trying to model objects made from polypropylene. The material
is translucent (as opposed to transparent).

Here is a link that shows what the material looks like.

https://www.webstaurantstore.com/cambro-30ppch190-1-3-size-translucent-polypropylene-handled-lid/21430PPCH.html

The povray material type I am using always looks clear. I can't figure out how
to model the look of the material.

Here is what I have. Can anyone help?

#declare TranslucentPlastic =
 material
 {
  texture
  {
    pigment{rgbf 1}
    finish
    {
      diffuse 0.3
      ambient 0.7
      reflection{fresnel on}
      phong 10.0
      phong_size 60.0
    }
  }
  interior
  {
    ior 1.5
  }
}

--Bob


Post a reply to this message

From: Bald Eagle
Subject: Re: Texture for translucent polypropylene?
Date: 20 Jul 2018 00:15:00
Message: <web.5b512882c1822b9c458c7afe0@news.povray.org>
"bzigon" <bob### [at] gmailcom> wrote:
> Hello
> I am trying to model objects made from polypropylene. The material
> is translucent (as opposed to transparent).
>
> Here is a link that shows what the material looks like.
>
>
https://www.webstaurantstore.com/cambro-30ppch190-1-3-size-translucent-polypropylene-handled-lid/21430PPCH.html
>
> The povray material type I am using always looks clear. I can't figure out how
> to model the look of the material.

Use transmit, not filter, and set it less than 1, else it will be completely
transparent.   There are some good docs and websites with examples.

http://xahlee.info/3d/povray-glassy.html

http://news.povray.org/povray.binaries.images/thread/%3Cweb.57a7e643418f435e7df57c0%40news.povray.org%3E/

I also thought your reflection values were a bit drastic, but I always just
tinker until I get something that works.   I'm certainly no expert.

Try:

#version 3.8;
global_settings {assumed_gamma 1.0}

#include "colors.inc"
//#include "shapes.inc"
//#include "shapes2.inc"
#include "shapes3.inc"

camera {
   location <0, 2, -5>    // position & direction of view
  look_at  <0, 0, 0>
  right x*image_width/image_height           // horizontal size of view
  up y // vertical size of view
}

plane {y, -1 pigment {checker}}

light_source {<5, 5, -30> color White}

#declare PP =
 material
 {
  texture
  {
    pigment{rgbt <1, 1, 1, 0.9>}
    finish
    {
      diffuse 0.3
      ambient 0.7
      reflection {0.05 fresnel on}
      phong 0.25
      phong_size 20.0
    }
  }
  interior
  {
    ior 1.5
  }
}

//----------------------------------------------------------------------------

//----------------------------------------------------------------------------
object { Half_Hollowed_Rounded_Cylinder1( //
                                3.2,//  Len_total, // total_Lenght from end to
end
                                0.9,// outer radius
                                0.2,// border radius
                                1, //  border scale y ( >0 ), 0 = no rounded
borders!
                                1  //  Merge_On , // 0 = union, 1 = merge !
                              ) //--------------------------------------------
         material {PP} // end texture
         scale <1,1,1>
         translate <0, 0, 0>
         rotate <0,0,0>
       }  // end of object ---------------------------------------------------
//----------------------------------------------------------------------------


Post a reply to this message

From: Stephen
Subject: Re: Texture for translucent polypropylene?
Date: 20 Jul 2018 07:27:46
Message: <5b518ef2$1@news.povray.org>
On 20/07/2018 01:10, Bald Eagle wrote:
> Use transmit, not filter, and set it less than 1, else it will be completely
> transparent.   There are some good docs and websites with examples.
> 
> http://xahlee.info/3d/povray-glassy.html
> 
>
http://news.povray.org/povray.binaries.images/thread/%3Cweb.57a7e643418f435e7df57c0%40news.povray.org%3E/
> 
> I also thought your reflection values were a bit drastic, but I always just
> tinker until I get something that works.   I'm certainly no expert.
> 
Also the ambient is too high.
Subsurface scattering might do it. But you might get the effect with 
micro-normals.

> Try:


#declare PP0 =
material{
   texture {
     pigment {
       colour rgbft <1.000,1.000,1.000,0.000,0.250>
/* increase t for more transparency */
     }

     normal {
       crackle, 0.010
       form < -1.000, 1.000, 0.000 >
       metric 2.000
       offset 0.000
       scale     <0.010,0.010,0.010>  /* Scale micro-normals. */
     }

     finish {
       ambient     rgb <0.100,0.100,0.100>*2.500
       brilliance  1.000
       diffuse     0.300
       phong       0.000
       phong_size  1.000
       specular    0.078
       roughness   1.000
       reflection {
         rgb <0.015,0.015,0.015>, rgb <0.025,0.025,0.025>
         fresnel   1
         falloff   0.000
         exponent  1.000
         metallic  0.000
       }
     }

   }

   interior{
     ior                 1.500
     caustics            0.000
     dispersion          1.000
     dispersion_samples  7.000
     fade_power          0.000
     fade_distance       0.000
     fade_color          rgb <0.000,0.000,0.000>
   }

}



-- 

Regards
     Stephen


Post a reply to this message

From: Alain
Subject: Re: Texture for translucent polypropylene?
Date: 26 Jul 2018 18:14:33
Message: <5b5a0f89$1@news.povray.org>
Le 18-07-19 à 17:28, bzigon a écrit :
> Hello
> I am trying to model objects made from polypropylene. The material
> is translucent (as opposed to transparent).
> 
> Here is a link that shows what the material looks like.
> 
>
https://www.webstaurantstore.com/cambro-30ppch190-1-3-size-translucent-polypropylene-handled-lid/21430PPCH.html
> 
> The povray material type I am using always looks clear. I can't figure out how
> to model the look of the material.
> 
> Here is what I have. Can anyone help?
> 
> #declare TranslucentPlastic =
>   material
>   {
>    texture
>    {
>      pigment{rgbf 1}
>      finish
>      {
>        diffuse 0.3
>        ambient 0.7
>        reflection{fresnel on}
>        phong 10.0
>        phong_size 60.0
>      }
>    }
>    interior
>    {
>      ior 1.5
>    }
> }
> 
> --Bob
> 
> 

The best way is to use subsurface light transport. Version 3.8 alpha or 
Uber-POV.

To use it, you need to activate it in the global_settings block :

global_settings {
   subsurface { [samples DiffuseScatteringINT, SingleScatteringINT] 
[radiosity BOOL] }
}

samples default to 50, 50
Use smaller to get fraster, but grainy, render.
radiosity defaults to OFF

Next, you need to add it to the finish block of the object :

subsurface { translucency COLOR }

COLOR can be a colour vector or a float.
The values are NOT limited to the  range.
If translucency is large relative to the object, then the object can 
look transparent.

The effect depends on the ior of the object and it's scale.
The scale can be set globally :
global_settings{mm_per_unit INT}

Where INT represent how many milimeters are in one POV unit.

When using translucency, you should avoid colour components of zero. 
Instead, use some very small values. Use rgb 0.001 instead of rgb 0 for 
your black.
DON'T use diffuse 0. It can cause a crash.

Use merge instead of union.
Meshes must be well beheaved and closed.
In a CSG, use a single object whide interior.


Alain


Post a reply to this message

From: Alain
Subject: Re: Texture for translucent polypropylene?
Date: 26 Jul 2018 18:22:51
Message: <5b5a117b$1@news.povray.org>
Le 18-07-26 à 14:16, Alain a écrit :

> The best way is to use subsurface light transport. Version 3.8 alpha or 
> Uber-POV.
> 
> To use it, you need to activate it in the global_settings block :
> 
> global_settings {
>    subsurface { [samples DiffuseScatteringINT, SingleScatteringINT] 
> [radiosity BOOL] }
> }
> 
> samples default to 50, 50
> Use smaller to get fraster, but grainy, render.
> radiosity defaults to OFF
> 
> Next, you need to add it to the finish block of the object :
> 
> subsurface { translucency COLOR }
> 
> COLOR can be a colour vector or a float.
> The values are NOT limited to the  range.
> If translucency is large relative to the object, then the object can 
> look transparent.
> 
> The effect depends on the ior of the object and it's scale.
> The scale can be set globally :
> global_settings{mm_per_unit INT}
> 
> Where INT represent how many milimeters are in one POV unit.
> 
> When using translucency, you should avoid colour components of zero. 
> Instead, use some very small values. Use rgb 0.001 instead of rgb 0 for 
> your black.
> DON'T use diffuse 0. It can cause a crash.
> 
> Use merge instead of union.
> Meshes must be well beheaved and closed.
> In a CSG, use a single object whide interior.
> 
> 
> Alain

After looking at the picture, I suggest a transluncency value that is 
just a bit larger than the thickness of your object as a starting point.


Post a reply to this message

Copyright 2003-2008 Persistence of Vision Raytracer Pty. Ltd.