|
 |
quoderatd wrote:
> How would I generate a scene with an eclipse?
>
> I am aware of medias but can it represent a corona well?
Emissive media should be fine. The trick will be to find a
density function which matches the structure of the corona.
Here is a little something to get you started. It uses two
densities, one for spherical structure and one for radial
structure (the latter is actually cheating because it is
actually modelling a cylindrical radial structure and
not a spherical corona).
#include "colors.inc"
#include "functions.inc"
global_settings
{
assumed_gamma 1.0
}
camera
{
location <0.0, 0.0, -5.0>
look_at <0.0, 0.0, 0.0>
angle 90
}
sphere {0,1 pigment {color Black}} // "Moon"
sphere // "Corona"
{
0,1 hollow
pigment {color rgbt 1}
interior
{
media
{
emission 0.15
density
{
//function {f_spherical(x,y,z)}
function {max(0,f_spherical(x,y,z) - 0.15*f_agate(2*x,2*y,2*z))}
color_map
{
[0 color Black]
[0.20 color rgb <0.2,0.5,1>]
[0.33 color White]
}
}
density
{
#local my_f_radial = function {pattern {radial frequency 30}}
function {my_f_radial(x,y,z)}
rotate 90*x
color_map
{
[0 color rgb 0.8]
[0.5 color White]
[1 color rgb 0.8]
}
}
}
}
scale 3
translate 3*z
}
Post a reply to this message
|
|
