|
 |
Don Barron wrote:
>
> Does anyone have any suggestions as to how one might simulate the vignetting
> in early camera lenses. So for example how to control the brightness of the
> image in terms of its angular distance from the look_at according to cos(
> theta)
Not angular brightness, exactly, but if I understand the artistic
effect you're shooting for, try this instead:
Sample may need adaptation for your particular scene, but it will
do to decide if it's what you need. Animation of scale could
be made into a wipe effect, the color of the border is variable
at need, and different patterns will allow for different border
shapes...
-----------------------------------------------------------------
#include "transforms.inc" //needed for Reorient_Trans
/*camera location and look_at are declared because the effect
depends on them later... */
#declare CamPos=<0,10,-20>;
#declare CamTarget=<0,2,0>;
#declare CamAxisDiff=CamTarget-CamPos;
camera {
location CamPos
look_at CamTarget
}
plane { //this is the filter...
y, -0.9*vlength(CamPos)
pigment {
wood
color_map {
[ 0 rgbt<0,0,0,1> ]
[ .25 rgbt<0,0,0,1> ]
[ 1 rgbt<0,0,0,0> ]
}
rotate<90,0,0>
scale 2.25
}
no_shadow
Reorient_Trans(y, CamAxisDiff)
translate CamTarget
}
//a generic scene to vignette...
light_source { <100,100,-100> rgb <1,1,1> }
plane { y, 0 pigment { checker color rgb .5 color rgb .75 } }
sphere { CamTarget, 2 pigment { rgb<0,0,1> } finish { phong .75 } }
--
@C[$F];
The Silver Tome :: http://www.silvertome.com
"You may sing to my cat if you like..."
Post a reply to this message
|
|
