Le 18-04-04 à 08:04, Sven Littkowski a écrit :
> I wonder, if the BRICKS pattern can't be used for this, but instead
> specifying pigments (colors), now specifying textures instead.
> 
> This would be worth a suggestion to Clipka, as that feature would make
> it easy to finally have easily creatable planks in the scenes.
> 
> Doing some experimenting on my own, I am wondering if there is a way to
> "remote-control" textures in a similar way as MACRO does with objects.
> If there is a way to change parameters of a texture, it could allow to
> change the lumber-type of an upcoming planks texture without having to
> re-declare all the entire thing again as a new texture.
> 
> ---
> Diese E-Mail wurde von AVG auf Viren geprüft.
> http://www.avg.com
> 

It's easy to use full textures with bricks :
texture{bricks Texture1 Texture2}

Please note that one is always for the bricks and the other always for 
the grout. The grout part can be made very narrow.
The bricks parts are continuous, you'll need to use warp{repeat ...} if 
you want some variations for your planks.
Things get complicated because, row to row, the boundaries alternate. 
Your repeat need to accomodate for that.

Post a reply to this message

Am 04.04.2018 um 14:04 schrieb Sven Littkowski:
> I wonder, if the BRICKS pattern can't be used for this, but instead
> specifying pigments (colors), now specifying textures instead.
> 
> This would be worth a suggestion to Clipka, as that feature would make
> it easy to finally have easily creatable planks in the scenes.

As Alain points out, this feature already exists. Virtually all patterns
that can be used for pigments can just as well be used for entire
textures (and vice versa).

> Doing some experimenting on my own, I am wondering if there is a way to
> "remote-control" textures in a similar way as MACRO does with objects.
> If there is a way to change parameters of a texture, it could allow to
> change the lumber-type of an upcoming planks texture without having to
> re-declare all the entire thing again as a new texture.

Macros do not "do something with objects" - they just provide a means to
insert (almost) arbitrary scene definition statements in a way that can
be parameterized. Such statements just may happen to be object
definitions, that's all. In the very same way, they may happen to
contain texture definitions instead.

e.g.

    #macro MySphere(C,R)
      sphere { C, R }
    #end

    #macro MyTexture(D,S)
      texture { finish { diffuse D specular S } }
    #end

    object {
      MySphere(<0,1,0>, 1.0)
      MyTexture(0.7, 1.0)
    }

is perfectly valid scene code (unless I injected some stupid blunder).

Post a reply to this message

http://news.povray.org/povray.text.scene-files/message/%3Cweb.5ac57be22ec21c585cafe28e0%40news.povray.org%3E/#%3Cweb.5a
c57be22ec21c585cafe28e0%40news.povray.org%3E

Post a reply to this message

Yes, I made already some first thoughts about how to interrupt a
continuous grain. My idea is 8what I am using already right now for my
ship) to equip the wood texture with a random-based TRANSLATE that comes
into effect with each call of the texture.

I also experimented with BRICKS for TEXTURE, but it seems I did things
wrong and always got error messages. :-D

Thanks for sharing that simple code. What a shame for me... :-D

---
Diese E-Mail wurde von AVG auf Viren geprüft.
http://www.avg.com

Post a reply to this message

Hmmmm... When I tried the macro with texture, I got error messages
saying "object expected but texture found". Will try again.

Thanks for the clarifications, Clipka.

On 04.04.2018 13:59, clipka wrote:
> #macro MyTexture(D,S)
>       texture { finish { diffuse D specular S } }
>     #end

---
Diese E-Mail wurde von AVG auf Viren geprüft.
http://www.avg.com

Post a reply to this message

Yippie-ya-yeah!!!   :-D




On 04.04.2018 20:30, Bald Eagle wrote:
> http://news.povray.org/povray.text.scene-files/message/%3Cweb.5ac57be22ec
21c585cafe28e0%40news.povray.org%3E/#%3Cweb.5a
> c57be22ec21c585cafe28e0%40news.povray.org%3E

---
Diese E-Mail wurde von AVG auf Viren geprüft.
http://www.avg.com

Post a reply to this message

Le 18-04-04 à 23:46, Sven Littkowski a écrit :
> Yes, I made already some first thoughts about how to interrupt a
> continuous grain. My idea is 8what I am using already right now for my
> ship) to equip the wood texture with a random-based TRANSLATE that comes
> into effect with each call of the texture.
> 
> I also experimented with BRICKS for TEXTURE, but it seems I did things
> wrong and always got error messages. :-D
> 
> Thanks for sharing that simple code. What a shame for me... :-D
> 
> ---
> Diese E-Mail wurde von AVG auf Viren geprüft.
> http://www.avg.com
> 

Here some code that I used in one of my rojects :
texture{
	pigment{
		wood
		warp{turbulence 0.03725
		omega 0.65725
		lambda 2.425}
		color_map{
		[0.250 color rgb <1.00000, 0.53373, 0.11665>]
		[0.350 color rgb <0.66275, 0.28607, 0.00000>]
		[0.525 color rgb <1.00000, 0.53363, 0.11715>]
		[0.600 color rgb <0.66475, 0.28647, 0.00000>]
		[0.750 color rgb <1.00000, 0.53353, 0.11565>]
		[0.850 color rgb <0.66275, 0.28667, 0.00000>]
		[1.000 color rgb <1.00000, 0.53143, 0.11795>]
		}
	scale <0.205, 0.225, 1.2>
	warp{repeat x*WarpScale offset y*2.427 flip y}
		}
	}
texture{
	pigment{
		wood
		scale 1.01275
		turbulence 0.0435
		omega 0.65
		lambda 3.15
		color_map{
		[0.200 color rgbt <0.56695, 0.17347, 0.00000, 0.8250>]
		[0.350 color rgbt <0.96471, 0.54510, 0.22753, 0.7710>]
		[0.400 color rgbt <0.56341, 0.17547, 0.00000, 0.9150>]
		[0.615 color rgbt <0.96472, 0.54510, 0.22553, 0.7590>]
		[0.700 color rgbt <0.56671, 0.17687, 0.00000, 0.7920>]
		[0.850 color rgbt <0.96485, 0.54510, 0.22453, 0.8975>]
		[1.000 color rgbt <0.56478, 0.17247, 0.00000, 0.9750>]
		}
		scale <0.225, 0.2725, 1.0>
	translate <-0.35, 0.095, 1.25>
	warp{repeat x*WarpScale offset -y*0.321 flip z}
	}
	finish{specular 0.3 roughness 0.12
		reflection{0.001,0.1 fresnel}}
	}
texture{
	pigment{
		gradient x color_map{[0.04 Black][0.04 rgbt 1]}
		//turbulence 0.025 octaves 4 lambda 0.8 omega 0.25
		scale WarpScale}}

The last layer is just to add some gaps between the planks and may be 
omited if you like.

Post a reply to this message

Hmmm, I just tried it, and get an error message. Are you sure that code
is correct? See here how I wrote it:

texture
{
 brick
 DMFWood6
 Brushed_Aluminum
 brick_size < 0.150, 0.075, 0.100 >
 mortar 0.025
}

The error message I am getting, is
"Parse Error: No matching } in texture, texture found instead".






On 04.04.2018 13:34, Alain wrote:
> It's easy to use full textures with bricks :
> texture{bricks Texture1 Texture2}

---
Diese E-Mail wurde von AVG auf Viren geprüft.
http://www.avg.com

Post a reply to this message

Am 08.04.2018 um 17:31 schrieb Sven Littkowski:
> Hmmm, I just tried it, and get an error message. Are you sure that code
> is correct? See here how I wrote it:
> 
> texture
> {
>  brick
>  DMFWood6
>  Brushed_Aluminum
>  brick_size < 0.150, 0.075, 0.100 >
>  mortar 0.025
> }
> 
> The error message I am getting, is
> "Parse Error: No matching } in texture, texture found instead".

Pretty much everywhere you're using variables containing scene elements
(objects, pigments and what-have-you) you need to wrap them in a
statement specifying what you think they contain.

For instance, in a union, you cannot just write:

    union {
      MyPart1
      MyPart2
    }

Instead, you have to write:

    union {
      object { MyPart1 }
      object { MyPart2 }
    }

Exactly the same is true for textures, so for your construct to work,
you'll have to use:

    texture {
      brick
      texture { DMFWood6 }
      texture { Brushed_Aluminum }
      ...
    }

Post a reply to this message

Hi,

yes, obviously. And I should know that. The situation is, that I
actually believed I tried exactly what you said, but got error messages
in the past. Now, however, it works. I think, because I was rendering
literally until I fell asleep 8after my working hours, deep in the
night), I must have dome something wrong and was just too tired to find
out what. That is, why i considered your method as "not functioning".

Of course it functions, the fault is just on my side - I was simply
over-tired. You know, when incredibly tired we all make the most basic
and most stupid mistakes.

I want to say THANK YOU, and my appreciation. :-)

---
Diese E-Mail wurde von AVG auf Viren geprüft.
http://www.avg.com

Post a reply to this message