Decrease the camera angle, and then maybe move it back.

Post a reply to this message

Am 11.10.2017 um 21:21 schrieb Sven Littkowski:
> On 11.10.2017 15:07, Bald Eagle wrote:
>>  only ever
> 
> 
> Bald Eagle: FULL HIT!
> 
> You managed to open my eyes. Yes, it was "MyNumber", and when i placed
> it inside the macro, it worked! I think, that is what Clipka had in
> mind, too, but I did not understand him (my fault again)

My eye and programming kung-fu may be sharp, but apparently my tutoring
kung-fu didn't quite cut it this time ;)

Post a reply to this message

Le 17-10-11 à 15:41, Sven Littkowski a écrit :
> Okay, I am getting there. Almost where I want to reach. Now another
> problem where I need the advise of you experienced users: perspective!
> 
> Currently, the lower ends of the oars spread more towards the left and
> right side (because they are closer to the camera). I don't want to
> switch of that entirely, but i want to reduce the perspective drag
> towards the sides a bit. I know, this must be accomplished inside the
> CAMERA settings. but how exactly?
> 
> I started to experiment already, but have not yet found the path to
> paradise.
> 
> 
> ---
> Diese E-Mail wurde von AVG auf Viren geprüft.
> http://www.avg.com
> 

Double the distance between the camera and the oars, and reduce the 
angle by half OR double the direction vector length.

Post a reply to this message

On 11.10.2017 18:19, clipka wrote:

> My eye and programming kung-fu may be sharp, but apparently my tutoring
> kung-fu didn't quite cut it this time ;)
> 
Maybe it were my eyes or my mind that were not in best condition. :-)

---
Diese E-Mail wurde von AVG auf Viren geprüft.
http://www.avg.com

Post a reply to this message

Everything is perfect now ... just one more question.   :-D

Is there any trick in POV-Ray, that allows me to make an item invisible
but still to get its shadow onto a wall behind it?

---
Diese E-Mail wurde von AVG auf Viren geprüft.
http://www.avg.com

Post a reply to this message

Sven Littkowski <I### [at] SvenLittkowskiname> wrote:
> Everything is perfect now ... just one more question.   :-D
>
> Is there any trick in POV-Ray, that allows me to make an item invisible
> but still to get its shadow onto a wall behind it?

no_image in the primitive, CSG or object statement, will do that and texture not
needed.

Post a reply to this message

On 11.10.2017 23:17, omniverse wrote:
> no_image in the primitive, CSG or object statement, will do that and texture not
> needed.

BIG THANKS!
"That's one small step for a POVian, one giant leap for reconstructors."

Everything is working 100% now.


---SCENE--------------------------------------------------------------------------

#local Temp_version = version;
#version 3.7;

#declare MyRadiosity = off;   // on

global_settings
{
 #if(MyRadiosity)
  radiosity
  {
   media on
   pretrace_start 0.08
   pretrace_end   0.001
   count 400
   error_bound 0.75
   recursion_limit 1
   normal on
  }
 #end
 subsurface        {}
 adc_bailout       0.0039
 ambient_light     rgb < 0.000, 0.000, 0.000 >
 assumed_gamma     1.000
 irid_wavelength   rgb < 0.250, 0.180, 0.140 >
 max_trace_level   5
 number_of_waves   10
 noise_generator   3
 charset           ascii
}





#declare TotalLength           = 10.0;   // length of oars of the lowest
line
#declare AmountOarsInLine      = 25;
#declare AmountLines           = 1;
#declare MyBladeWidth          = 0.150;  // the width of the oar's blade
#declare LineLeftShift         = 0.25;   // shift towards the left side
for additional lines
#declare LineHeightShift       = 0.25;   // distance to line below
#declare MyVariance            = 1.5;    // human irregularity
#declare MyHeightMore          = 0.50;   // upper lines need longer oars
#declare MyAngleMore           = 01.5;   // upper lines go a bit steeper
into water
#declare GeneralAngle          = 82.5;   // the angle of each oar from
hull towards water - lower angles = more vertical / higher angles = more
horizontal
#declare BladeAngle            = -65.0;  // the angle of the blade when
touching water
#declare ForwardAngle          =  7.3;   // to equalize the ends of each
line to the eye - lower angle = more backwards / higher angle = more
forwards / 7.5 = balanced
#declare MySceneTransitionLeft = -1.0;   // moves the entire object into
view center
#declare MyCameraAngle         = 17.0;
#declare MyShadows             = yes;     // render of "OARS ONLY" (no)
or of "SHADOWS ONLY" (yes)

#declare R1 = seed(1);
#declare R2 = seed(2);
#declare R3 = seed(3);






#if(MyShadows=no)
 camera
 {
  location < 7.0,  0.0, -200.0 >
  look_at  < 7.0,  0.0,   0.0 >
  angle MyCameraAngle
  right x*image_width/image_height
 }
#elseif(MyShadows=yes)
 camera
 {
  location < 7.0, -65.0, -200.0 >
  look_at  < 7.0, -15.0,   0.0 >
  angle MyCameraAngle
  right x*image_width/image_height
 }
#end



light_source
{
 < -50000.0, 25000.0, -100000.0 >
 rgb < 1.0, 1.0, 1.0 > *1.5
 area_light x*2500,z*2500,5,5 circular orient
 area_illumination
}

#if(MyShadows=no)
 light_source
 {
  <  50000.0, 25000.0, -100000.0 > //light position
  color rgb < 1.0, 1.0, 1.0 > * 0.5
  parallel
  point_at < 0.0, 0.0, 0.0 >
 }
#end

//
--------------------------------------------------------------------------------------------------

#include "textures.inc"

#declare UpperOar = texture
{
 DMFDarkOak
 pigment { color rgb < 0.3686275,  0.4509804,  0.2509804 > }
 normal { wood 0.5 scale 0.3 turbulence 0.1 }
 finish { phong 1 }
 rotate< 90.0, 0.0, 0.0 >
 scale 0.25
}

#declare LowerOar = texture
{
 DMFDarkOak
 pigment { color rgb < 0.1372549,  0.1372549,  0.1372549 > }
 normal { wood 0.5 scale 0.3 turbulence 0.1 }
 finish { phong 1 }
 rotate< 90.0, 0.0, 0.0 >
 scale 0.25
}





//
--------------------------------------------------------------------------------------------------

#macro MyOar(MyHeightMoreThis)
 union
 {
  union
  {
   cone
   {
    < 0.0, -10.0, 0.0 > 0.025 < 0.0, -9.75, 0.0 > MyBladeWidth   //
Bottom Blade
    scale < 1.0, 1.0, 0.1 >
   }
   cone
   {
    < 0.0, -9.75, 0.0 > MyBladeWidth < 0.0, -6.5, 0.0 > 0.075    // Top
Blade
    scale < 1.0, 1.0, 0.1 >
   }
   cone
   {
    < 0.0, -9.5, 0.0 > 0.020 < 0.0, -6.5, 0.0 > 0.075            //
Shaft Blending into Blade
   }
   cylinder
   {
    < 0.0, -6.5, 0.0 > < 0.0, -6.0, 0.0 > 0.075                  //
Lower Shaft
   }
   texture { LowerOar }
  }
  union
  {
   cylinder
   {
    < 0.0, -6.0, 0.0 > < 0.0, 0.0, 0.0 > 0.075                   //
Upper Shaft
   }
   #if(MyHeightMoreThis>0)
    cylinder
    {
     < 0.0, MyHeightMoreThis, 0.0 > < 0.0, 0.0, 0.0 > 0.075      //
Longer Shaft for Upper Oar Lines
    }
    translate < 0.0, -MyHeightMoreThis, 0.0 >
   #end
   texture { UpperOar }
  }
  #if(MyShadows=no)
   no_shadow
  #end
 }
#end






#macro MyOarLine(AmountOarsInLine,MyHeightMoreThis,MyAngleMore)
 union
 {
  #declare MyNumber = 0;
  #while(MyNumber<AmountOarsInLine)

   #declare MyAngleWater     = (rand(R1)*MyVariance)+GeneralAngle;
   #declare MyAngleHands     = (rand(R2)*MyVariance)+BladeAngle;
   #declare MyAngleDirection = (rand(R3)*MyVariance)+ForwardAngle;
   object
   {
    MyOar(MyHeightMoreThis)
    rotate < 0.0, MyAngleHands, 0.0 >
    rotate < MyAngleWater-MyAngleMore, 0.0, 0.0 >
    rotate < 0.0, 0.0, MyAngleDirection >
    translate < (MyNumber*0.925), 0.0, 0.0 >
   }
   #declare MyNumber = MyNumber+1;
  #end
 }
#end



union
{
 #declare ThisLine = 0;
 #while(ThisLine<AmountLines)
  object
  {
   MyOarLine(AmountOarsInLine,MyHeightMore*ThisLine,MyAngleMore*ThisLine)
   translate <
-((AmountOarsInLine*0.925)/2)+0.925+(LineLeftShift*ThisLine),
LineHeightShift*ThisLine, 0.0 >
   #if(MyShadows=yes)
    no_image
   #end
  }
  #declare ThisLine=ThisLine+1;
 #end

 #if(MyShadows=yes)
  box
  {
   < -30.0, -15.0, 0.0 > < 30.0, 15.0, 0.1 >
   pigment { color rgb < 1.0, 1.0, 1.0 > }
  }
  #end
 translate < MySceneTransitionLeft, 0.0, 0.0 >
}


---
Diese E-Mail wurde von AVG auf Viren geprüft.
http://www.avg.com

Post a reply to this message

Le 17-10-11 à 22:47, Sven Littkowski a écrit :
> Everything is perfect now ... just one more question.   :-D
> 
> Is there any trick in POV-Ray, that allows me to make an item invisible
> but still to get its shadow onto a wall behind it?
> 
> ---
> Diese E-Mail wurde von AVG auf Viren geprüft.
> http://www.avg.com
> 

Yes. Add the no_image attribute to your object.

There is also no_reflection (won't be seen in reflections), no_shadow 
(won't cast any shadow) and no_radiosity (ignore this object when 
computing radiosity).

Post a reply to this message

On 12.10.2017 12:28, Alain wrote:
> Yes. Add the no_image attribute to your object.
> 
> There is also no_reflection (won't be seen in reflections), no_shadow
> (won't cast any shadow) and no_radiosity (ignore this object when
> computing radiosity).

Thanks again. The code is perfect now, it dos exactly what I need it to
do. :-)

---
Diese E-Mail wurde von AVG auf Viren geprüft.
http://www.avg.com

Post a reply to this message

Sven Littkowski <I### [at] SvenLittkowskiname> wrote:

> Everything is working 100% now.
>
>
> > ---SCENE-------------------------------------------------------
snip]
> #include "textures.inc"
>
> #declare UpperOar = texture
> {
>  DMFDarkOak
>  pigment { color rgb < 0.3686275,  0.4509804,  0.2509804 > }
>  normal { wood 0.5 scale 0.3 turbulence 0.1 }
>  finish { phong 1 }
>  rotate< 90.0, 0.0, 0.0 >
>  scale 0.25
> }

It looks like you are substituting your own pigment for the pigment 'DMFDarkOak'
(which is actually just a pigment, not a complete texture.) In other words, your
own pigment is 'over-riding' DMFDarkOak; your scene isn't using it at all. The
same is happening in your 'LowerOar' texture.

When using multiple pigments in a texture, the 'final' pigment is the one that's
used; any previous ones are NOT used, or are ignored. So a texture should have
only ONE pigment-- unless you want to use a pigment_map and maybe the 'average'
keyword, to actually blend several pigments togather. Like this, for example...

#declare UpperOar =
texture{
   pigment{
       average
       pigment_map{
              [1 DMFDarkOak]
              [1 color rgb < 0.3686275,  0.4509804,  0.2509804 >]
                  }
          } // end of overall pigment statement
   normal { wood 0.5 scale 0.3 turbulence 0.1 }
   finish { phong 1 }
   rotate< 90.0, 0.0, 0.0 >
   scale 0.25
}

This blends DMFDarkOak and your own color equally (because of the 1 and 1
'weights' of the two, in the pigment_map.) You could instead use 3 and 1 for the
respective weights (for example), which would blend '3 parts DMFDarkOak' to '1
part of your color'

There's also another problem in your scene, here:

#declare DMFDarkOak =
pigment {
    wood
    turbulence 0.04            // For best results,  keep this low!
    octaves 3
    scale <0.2, 0.2, 1>        // Scaled for a unit object
    color_map {
        [0.1 rgb <0.60, 0.30, 0.18>]
        [0.9 rgb <0.30, 0.15, 0.09>]
    }
}

Now you have re-#declared DMFDarkOak to be a different pigment entirely, for use
in your 'LowerOar' texture. But again, you are substituting your own pigment
in 'LowerOar' for this 'new' DMFDarkOak.

My suggestion would be to re-write 'UpperOar' and 'LowerOar, to use *either*
DMFDarkOak *or* your own pigment/color, but not both of those. Or use the
pigment_map trick, for a blend.

Post a reply to this message