POV-Ray : Newsgroups : povray.general : Background image Server Time: 22 Oct 2017 21:06:27 GMT
  Background image (Message 1 to 3 of 3)  
From: kurtz le pirate
Subject: Background image
Date: 31 Dec 2016 09:08:49
Message: <586775a1@news.povray.org>
Hello,

On this page 
<https://medium.com/@gklka/every-default-wallpaper-of-os-x-7d6fee2e63e3#.mdysmxa3u> 
you can see somme background images from 10.0 to 10.4;

Do you think it is possible to make this kind of image with POV-Ray ?
If yes, how ? Can be with fractals?


Thank you for your ideas...

-- 
Kurtz le pirate
Compagnie de la Banquise


Post a reply to this message

From: omniverse
Subject: Re: Background image
Date: 31 Dec 2016 12:40:01
Message: <web.5867a5c59f0afbad9c5d6c810@news.povray.org>
kurtz le pirate <kur### [at] gmailcom> wrote:
>
> On this page
> <https://medium.com/@gklka/every-default-wallpaper-of-os-x-7d6fee2e63e3#.mdysmxa3u>
> you can see some background images from 10.0 to 10.4;
>
> Do you think it is possible to make this kind of image with POV-Ray ?
> If yes, how ? Can be with fractals?

Thought of torus shapes looking at those, so went with that. You could try
plenty more by changing/adding other objects, and of course changing parameters
and everything. In other words, maybe not need fractals.
However, this does have me wondering if there's other possible ways to go about
it anyway. Some of those look like curving sheets and I was thinking that might
need color specular highlights instead of media alone.
And I didn't succeed in getting emitting media to fill the torus the exact way I
wanted. That's when I found a povray group message about toroidal warp (for
edge-on galaxy, couple years ago*), but that again failed for me. Couldn't get
tight lines filling the torus, close but never enough.

/* smoky cobweb wallpaper */

#version 3.7;

global_settings{assumed_gamma 1}

camera
{
 location <0,3,-12> look_at 0
 up y
 right image_width/image_height*x
 angle 67
}

#declare Speed=yes;  // no for slow final render

#declare Color=<0.2,0.4,0.8>;

#declare Lightness=0.5; // >0 to ?

#declare ScaleFactor=1; // >0 to ?

#declare RotateFactor=1; // >0 to 1

#declare TranslateFactor=3; // >0 to ?


box{-33,33 pigment {rgbt 1} inverse} // finite enclosure

background {rgb Color*Lightness}

#include "functions.inc"

#declare xS=seed(35);
#declare yS=seed(41);
#declare zS=seed(92);

#for(It,0,7,1)
#declare Xr=rand(xS);
#declare Yr=rand(yS);
#declare Zr=rand(zS);

torus
{
 2+Yr*5, 0.1+3.9*Zr
 hollow on
 pigment
 {
  rgbt 1
 }
 interior
 {
  media
  {
   samples
#if(Speed>0) 20 #else 60 #end // increase if needed
   emission (Color/4)*Lightness
   //absorption 0.5
   density
   {
   function { f_torus(0,y,0, 2+Yr*5, 0.5+3.5*Zr) }
    density_map
    {
     [0 rgb 1] [0.1 rgb 0] [1 rgb 0]
    }
    warp { // same major radius... or what?
    toroidal orientation y major_radius 2+Yr*5
    }
   }
  }
 }
 scale 0.5+Xr*ScaleFactor // could try this after translate
 rotate <Xr,Yr,Zr>*360*RotateFactor
 translate <Xr,Yr,Zr>-<Xr,Yr,Zr>*TranslateFactor
}

#end
/*-------------end scene------------*/


* link to that message for the curious:

http://news.povray.org/povray.binaries.images/thread/%3C54855e67%40news.povray.org%3E/


Post a reply to this message

From: kurtz le pirate
Subject: Re: Background image
Date: 1 Jan 2017 09:44:50
Message: <5868cf92$1@news.povray.org>
Le 31/12/2016 à 13:35, omniverse a écrit :
> kurtz le pirate <kur### [at] gmailcom> wrote:
>>
>> On this page
>> <https://medium.com/@gklka/every-default-wallpaper-of-os-x-7d6fee2e63e3#.mdysmxa3u>
>> you can see some background images from 10.0 to 10.4;
>>
>> Do you think it is possible to make this kind of image with POV-Ray ?
>> If yes, how ? Can be with fractals?
>
> Thought of torus shapes looking at those, so went with that. You could try
> plenty more by changing/adding other objects, and of course changing parameters
> and everything. In other words, maybe not need fractals.
> However, this does have me wondering if there's other possible ways to go about
> it anyway. Some of those look like curving sheets and I was thinking that might
> need color specular highlights instead of media alone.
> And I didn't succeed in getting emitting media to fill the torus the exact way I
> wanted. That's when I found a povray group message about toroidal warp (for
> edge-on galaxy, couple years ago*), but that again failed for me. Couldn't get
> tight lines filling the torus, close but never enough.
>
> ...
>

A very good start... :)
Thanks


-- 
Kurtz le pirate
Compagnie de la Banquise


Post a reply to this message

Copyright 2003-2008 Persistence of Vision Raytracer Pty. Ltd.