I'm trying to create a glowing light which floats inside a partially
frosted glass dome, using emission media with spherical density to
create the glow.

Without the glass dome, it works fine; the background shows through the
edges of the glow.  If I add the glass dome, then there's a very obvious
dark ring around the glow showing the edge of the containing sphere,
almost as though absorption has been added to the media.

The dome is hollow.  The containing sphere is hollow, with a completely
clear pigment.  I've tried all four combinations of rgbt and rgbf on the
dome and containing sphere.

I've included a simple example below, showing the effect both with and
without the dome (the glow for the one without the dome has had its
pigment and light strengths reduced so that it doesn't wash out).

Is it something I'm doing wrong, or is this an inherent limitation of
media?


#declare GlassDome = intersection {
  sphere { 0, 1 }
  sphere { 0, 0.9 inverse }
  plane { z, 0 }
  hollow
  bounded_by { sphere { 0, 1 }}
  pigment { colour rgbt <0.95,0.975,1,0.5> }
  finish { ambient 0.3 diffuse 0.4 specular 1.0 roughness 0.0025 }
  interior { ior 1.5 }
}

#declare TinfoilCylinder = difference {
  cylinder { 0, z*0.5, 0.95 }
  cylinder { z*-0.1, z*0.45, 0.9 }
  bounded_by { cylinder { 0, z*0.5, 0.95 }}
  pigment { colour rgb <1,0.9,0.8> }
  finish { reflection 0.5 specular 1 roughness 0.001 brilliance 2 }
  normal { wrinkles 0.25 scale 0.1 }
}

#declare Glow_no_glass = union {
  sphere { 0, 1 pigment { colour rgbt 1 } hollow
    interior { media { emission <2.5,2.5,0> density { spherical }}}
    scale 0.3 translate z*-0.25
  }
  light_source { z*-0.25 colour rgb <1,0.5,0> fade_distance 1
    fade_power 2
  }
}

#declare Glow_glass = union {
  sphere { 0, 1 pigment { colour rgbt 1 } hollow
    interior { media { emission <7.5,7.5,0> density { spherical }}}
    scale 0.3 translate z*-0.25
  }
  light_source { z*-0.25 colour rgb <3,1.5,0> fade_distance 1
    fade_power 2
  }
}


object { TinfoilCylinder translate x*-1.125 }
object { Glow_no_glass   translate x*-1.125 }

object { TinfoilCylinder translate x* 1.125 }
object { Glow_glass      translate x* 1.125 }
object { GlassDome       translate x* 1.125 }

camera { location <0,0,-8> look_at <0,0,0> angle 37.5 rotate x*-45}
light_source { <-1000,-1000,-1000> colour rgb <1,1,1> }

Post a reply to this message

On Wed, 22 Sep 1999 15:39:41 GMT, Jeff Lee wrote:
>Is it something I'm doing wrong, or is this an inherent limitation of
>media?

One word (token, really):  max_trace_level.

Post a reply to this message

par### [at] fwicom (Ron Parker) wrote:
> On Wed, 22 Sep 1999 15:39:41 GMT, Jeff Lee wrote:
>
>> Is it something I'm doing wrong, or is this an inherent limitation of
>> media?
>
> One word (token, really):  max_trace_level.

One word: Thanks.


-- 
Jeff Lee         shi### [at] gatenet         http://www.gate.net/~shipbrk/

Post a reply to this message