Transparent objects appear to interact in strange ways. For example, if you
take 2 transparent objects and make object 1 matt and object 2 reflective,
then not only can you see the reflection of object 1 in object 2, but also
object 1 becomes visible if object 2 is behind it:

/////////////////////////

camera {
 right x*4/3
 location  <0, 0, -3>
 look_at   <0, 0, 0>
}

light_source { <0, 2, -1> color rgb <1,1,1>}

sky_sphere {
    pigment {
      gradient x
      color_map {
        [0 color rgb <0,0,1>]
        [1 color rgb <1,1,1>]
      }
      scale 2
      translate -1
    }
}

#declare Matt_Glass = box {
 <0,0,0>,<1,0.2,0.005>
 pigment {color rgbf <1,1,1,1>}
}

#declare Reflective_Glass = box {
 <-1,-1,0>,<1,1,0.005>
 texture {
  pigment {colour rgbf <1,1,1,1>}
  finish {reflection 0.1}
 }
}

object {Matt_Glass rotate 50*y}
object {Reflective_Glass rotate -50*y}

/////////////////////////

I know this situation sounds a bit artificial, but I've been modelling a
room design which has some custom-shaped mirrors. I took what I thought
would be the easiest way of doing it, and drew bitmap pictures of the
mirrors' shapes to use as material maps of transparent and mirrored
textures. They look perfect when viewed directly, but when a reflection of
one of them is seen in one of the room's windows, the entire object can be
seen - both the mirrored parts and the parts which are supposed to be
transparent. I guess that, unless anyone knows of a way to make this work
correctly, I'll have to model the things as prisms.

This feels like a POV-Ray design limitation rather than a bug - anyone know
for sure?

Povray V3.1g.watcom.Win32
Windows NT4 WS SP4
Dell Latitude PII 300

Paul Showering
Chippenham
UK

Post a reply to this message

Increase max_trace_level, something like 10 should suffice in the example scene.

Margus

"Paul E. Showering" wrote:
> 
> Transparent objects appear to interact in strange ways. For example, if you
> take 2 transparent objects and make object 1 matt and object 2 reflective,
> then not only can you see the reflection of object 1 in object 2, but also
> object 1 becomes visible if object 2 is behind it:
>

Post a reply to this message

Margus Ramst wrote:
> Increase max_trace_level, something like 10 should suffice in the example
scene.
>

Thanks! In fact, just increasing it to 6 worked. Guess I should read the
documentation more thoroughly one day (only been using POV for 7 years!). I
didn't guess that max_trace_level would still apply to a ray that was just
transmitted and not reflected at the same time.

Paul

Post a reply to this message