I have been trying to create some "halo like" objects in the new Povray by
using the media command, but I cannot seem to get a media type (like a
sphere) to render with the "feathered edge" that a halo has.  The edge of a
halo beautifully fades into its background, but a media's edge seems to end
somewhat abruptly.  Is there any way to make the a media "feather" the edge
like the old halo does?
Does anyone have a good example of same?

Post a reply to this message

As mentioned in other posts, media ignores the transparency and filter
elements.  If you want it to fade out, you need to fade to <0,0,0> 
Which means that no light is being emitted (or absorbed, depending
on what type of media).

-Nathan Kopp

Post a reply to this message

The Key points are 
1. scaling the color map
2. making the first and last statements in the color map 0

You can mess with everything else to your taste

Hope this helps

Mike Hazelgrove



// Persistence Of Vision raytracer version 3.1 sample scene by Mike
Hazelgrove
// based on Hollow3 by Dieter Bayer.
//
// This scene shows a flame.
// by Mike Hazelgrove based on Hollow3
//

#include "colors.inc"

camera {
  location <-1.5, 30, -50>
  look_at <0, 25, 35>
  angle 35
}

background { color rgb<0.3,0.3,0> }

light_source { <100, 100, -200> color White }


sphere { 0, 1
  pigment {rgbf<1,1,1,1>}
  interior {
    media {
      emission 0.5
      intervals 20
      samples 1, 10
      confidence 0.9999
      variance 1/1000
      density {
       spherical
       scallop_wave
        turbulence 0.5
        color_map {
          [0.0 color rgb <0, 0, 0>] //You need this
          [0.25 color rgb <1, 0., 0>]
          [0.5 color rgb <1, 1, 0>]
          [0.75 color rgb <1, 0, 0>]
          [1.0 color rgb <0, 0, 0>]// you need this
        }
        scale 0.5 //you need this
      }
    }
  }
  scale 3
  scale <1,3,1>
  translate 25*y
  hollow
}

Patrick Dugan <pat### [at] ipanet> wrote in article
<35d3774e.0@news.povray.org>...
> 
> I have been trying to create some "halo like" objects in the new Povray
by
> using the media command, but I cannot seem to get a media type (like a
> sphere) to render with the "feathered edge" that a halo has.  The edge of
a
> halo beautifully fades into its background, but a media's edge seems to
end
> somewhat abruptly.  Is there any way to make the a media "feather" the
edge
> like the old halo does?
> Does anyone have a good example of same?
> 
> 
> 
> 
> 
> 
> 
>

Post a reply to this message