/**********************************************************************************
 Persistence of Vision Ray Tracer Scene Description File
 File name   : vaxis_rotate_test.pov
 Version     : 3.7 
 Description : testing the function for positioning (non-scaled) cylinders
               
 Date        : December 2010
 Author      : Thomas A. M. de Groot
**********************************************************************************/

// Render settings 3.7 (right-click on a line below):
// +w640 +h640 +a0.3 +am2 +bm2 +rp3

//=================================================================================
// VERSION AND GAMMA SWITCHES
//=================================================================================
#declare MPov       = off;

#if (MPov)
  #version unofficial megapov 1.21;
  #include "tone_mapping.inc"	     //include file for Clip_Colors()
  #declare Gamma = 1.0;
#else
  #version 3.7;
  #declare Gamma = 1.0;
#end

// ----------------------------------------

camera {
  location  <0.0, 3.5, -1.0>
  direction 1.5*z
  right     x*image_width/image_height
  look_at   <0.0, 0.0,  0.0>
}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}

light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <1, 1, 1>  // light's color
  translate <-30, 30, -30>
}

// ----------------------------------------
plane {
  y, 0
  pigment { color rgb <0.7,0.5,0.3> }
}

#local OvalScale = <0.4, 1, 0.8>;

cylinder {
  <0, 0, 0>, <0, 0.01, 0>, 1
  scale OvalScale
  pigment {rgb <1,1,0>}
}

#declare HolePost =
cylinder {
  <0, 0, 0>, <0, 0.5, 0>, 0.03
  pigment {rgb <1,0,0>}
}

#local N = 22.5;

union {
  #while (N < 360)
    #local Pos = vaxis_rotate (<0, 0, 1.1>, y, N)*OvalScale;

    object {HolePost
      translate Pos
    }
    
    #local N = N + 45.0;
  #end
}