/*
Example of the use of the HSL (Hue, Saturation, Lightness) macros for
specifying colours developed by Margus Ramst <margus@peak.edu.ee>
posted in news.povray.binaries.utilities on 10 July 1999
<davidwilkinson@cwcom.net>
*/


//"hslft" lets you specify colours with the
//hue-saturation-lightness colour model.
//You can also use "hsl", "hslf" and "hslt" as shortcuts,
//just like "rgb", "rgbf" and "rgbt";
//H - hue; circular spectrum running red-green-blue-red
//S - saturation, i.e. the amount of colour in relation to gray
//L - lightness of the colour
//F,T - filter and transmit of the colour


#include "colors.inc"
#include "HSL.inc" // These are the HSL macros

global_settings
{
  assumed_gamma 1.0
}

// ----------------------------------------
camera
{ 
  location  <4, 3, -10.0>
  direction 1.5*z
  right     4/3*x
  look_at   <4, 3,  0.0> 
  orthographic
}

light_source
{
  <4, 3, -1000>
  color rgb 1  
}

// starting conditions
#declare Hue =0;
#declare Sat =0.4;
#declare Light=1;
#declare Filt=0;
#declare Transm=0;

#declare Count=0;
#declare Line =0;
#while (Line<6)
   #while (Count<8)
        box { 0,0.9 pigment {hslft(Hue,Sat,Light,Filt,Transm)} translate <Count,Line,0> }
        text { ttf "timrom.ttf" concat("Hue=",str(Hue,0,2)) 5, 0
               pigment { Black } scale 0.2 translate <Count,Line+.4,-1>
        }
        text { ttf "timrom.ttf" concat("Sat=",str(Sat,0,2)) 5, 0
            pigment { Black } scale 0.2 translate <Count,Line+0.2,-1>
        }
        text { ttf "timrom.ttf" concat("Light=",str(Light,0,2)) 5, 0
            pigment { Black } scale 0.2 translate <Count,Line,-1>
        }
     #declare Hue = Hue + 1/8;
     #declare Count=Count+1;
   #end
 #declare Count = 0; 
 #declare Hue=0;
 #declare Sat=Sat+0.6/5;
 #declare Line=Line+1;
#end