POV-Ray : Newsgroups : povray.binaries.scene-files : Rusty bearing Server Time: 23 Jul 2019 12:15:02 GMT
  Rusty bearing (Message 1 to 8 of 8)  
From: LanuHum
Subject: Rusty bearing
Date: 8 Feb 2014 07:50:01
Message: <web.52f5e09fa98583267a3e03fe0@news.povray.org>



Post a reply to this message


Attachments:
Download 'rusty_bearing.7z.zip' (483 KB)

From: Le Forgeron
Subject: Re: Rusty bearing
Date: 8 Feb 2014 08:57:26
Message: <52f5f176$1@news.povray.org>
Bogus ini file.

Possible Parse Error: Cannot find file
'/home/leonid/blender/povwip/povwip.pov',
 even after trying to append file type extension.

Pov file seems ok


Post a reply to this message

From: LanuHum
Subject: Re: Rusty bearing
Date: 8 Feb 2014 09:20:01
Message: <web.52f5f649d4e1acd97a3e03fe0@news.povray.org>
Le_Forgeron <jgr### [at] freefr> wrote:
> Bogus ini file.
>
> Possible Parse Error: Cannot find file
> '/home/leonid/blender/povwip/povwip.pov',
>  even after trying to append file type extension.
>
> Pov file seems ok

In the Rusty_bearing.ini file you have to change ways to the.
Input_File_Name ='\bla\bla\bla\Rusty_bearing.pov'
Output_File_Name = '\bla\bla\bla\Rusty_bearing.png'


Post a reply to this message

From: Alain
Subject: Re: Rusty bearing
Date: 8 Feb 2014 19:22:00
Message: <52f683d8$1@news.povray.org>
Le 14-02-08 04:18, LanuHum a écrit :
> Le_Forgeron <jgr### [at] freefr> wrote:
>> Bogus ini file.
>>
>> Possible Parse Error: Cannot find file
>> '/home/leonid/blender/povwip/povwip.pov',
>>   even after trying to append file type extension.
>>
>> Pov file seems ok
>
> In the Rusty_bearing.ini file you have to change ways to the.
> Input_File_Name ='\bla\bla\bla\Rusty_bearing.pov'
> Output_File_Name = '\bla\bla\bla\Rusty_bearing.png'
>
>
>

Or beter still: Put the files in a folder and remove the path before the 
files' names.

Hint: When publishing scenes, remove any paths, especialy any absolute 
ones, and put all required files in a single folder.


Post a reply to this message

From: Thomas de Groot
Subject: Re: Rusty bearing: a collection of rusty metals
Date: 9 Feb 2014 08:34:11
Message: <52f73d83$1@news.povray.org>
I have made a selection of rusty metals that have been offered over the 
years in these newsgroups. Names of authors (and sometimes dates) are 
given for each of them. You have already Xplo's. This list is certainly 
not exhaustive but it is what I have collected.

Thomas

//----------------------------------------------------------------------
// Old pitted iron texture
// Created by Kenneth (povray.binaries.images 01-04-2009)

#declare Ke_old_pitted_iron =
texture {
   pigment {
   granite  // AGATE works well for this too.
     color_map {
       [0.000 rgb .8*<.4, .4, .380>]
       [0.153 rgb <0.4, 0.4, 0.4>]
       [0.398 rgb .5*<0.7, 0.4, 0.25>]
       [0.398 rgb .2*<0.7, 0.7, 0.7>]
       [1.000 rgb <0.545, 0.380, 0.345>]
     }
   }
   finish {
     ambient 0 // 0.2
     diffuse 1
     phong .6
     phong_size 24
   }
   normal {granite .7 scale 9}
   scale 0.05	//use for scaling to object size (TdG)
}

//----------------------------------------------------------------------
// Rusty steel
// Created by Mike Sobers (povray.binaries.images 30-03-2009)

#declare radiosity_on = true;
#declare globalreflection = 1;

#declare base =
texture {
   pigment { color rgb <0.91, 0.95, 0.91>*0.5}
   normal {
      wrinkles
       normal_map {
         [ 0.00 granite 0.00 scale 0.001]
         [ 0.20 granite 0.0 ]
         [ 0.28 wrinkles 0.05 turbulence 0.5 scale 0.005]
         [ 0.38 wrinkles 0.05 turbulence 0.5 scale 0.005]
         [ 0.40 granite 0.0 ]
         [ 0.62 granite 0.05 turbulence 0.5 scale 0.005]
         [ 0.90 granite 0.0 ]
         [ 1.00 granite 0.00 scale 0.001]
       }
   turbulence 0.05
   scale 300
   }
   #if (radiosity_on)
     finish {
       ambient 0.0
       brilliance 2
       diffuse 0.3
       metallic
       specular 0.80
       roughness 1/2000
       reflection 0.9*globalreflection
     }
   #else
     finish {
       ambient 0.01
       brilliance 2
       diffuse 0.3
       metallic
       specular 0.80
       roughness 1/2000
       reflection 0.9*globalreflection
     }
   #end
}

#declare tex1 =
texture {
   pigment {
     granite
     color_map {
       [ 0 color rgb <0.7, 0.4, 0.2> ]
       [ 1 color rgb <0.6, 0.2, 0.05> ]
     } turbulence 0.2 scale 0.5
   }
   normal {
     bumps 0.2
     turbulence 0.05
     scale 0.5
   }
   #if (radiosity_on)
     finish {
       ambient 0.0
       brilliance 2
       diffuse 0.3
       metallic
       specular 0.20
       roughness 1/20
       reflection 0.1*globalreflection
     }
   #else
     finish {
       ambient 0.01
       brilliance 2
       diffuse 0.3
       metallic
       specular 0.20
       roughness 1/20
       reflection 0.1*globalreflection
     }
   #end
}

#declare tex2 =
texture {
   wrinkles
   texture_map {
      [0  base]
      [0.5 tex1 ]

   }
   scale 0.2 turbulence 0.5
}

#declare MS_RustySteel =
texture {
   wrinkles
   texture_map {
      [0.00  base]
      [0.10  base]
      [0.10  tex2 scale 0.005]
      [0.11  tex2 scale 0.005]
      [0.12  base]
      [0.50  base]
      [0.70  tex2 scale 0.05]
   }
   scale 0.2 turbulence 0.5
}

//----------------------------------------------------------------------
// A rusty iron
// Created by Meothuru (povray.binaries.images 29-03-2009)

#declare Me_RustyIron =
texture {
   pigment {
     spherical
     turbulence <1, 1, 1>
     omega 1
     lambda 6
     color_map {
       [ 0.1 color rgb <0.478431, 0.513725, 0.462745> ]
     }
   }
   normal {
     boxed
     30
     turbulence <1, 1, 1>
     omega 1
     lambda 6
     frequency 15
   }
   finish {
     ambient rgb <0, 0, 0>
     diffuse 0.3
     specular 0.6
     conserve_energy
     reflection {
       rgb <0.1, 0.1, 0.1>
       metallic 1
     }
   }
   scale 15
}

//----------------------------------------------------------------------
// Corroded metal (can also be used for stone with patina)
// Created by Meothuru (povray.text.scene-files 13-11-2007)

// uncomment the lines below to get the metal corrosion. otherwise 
'stone' texture
#declare Me_corrodedMetal1 =
//texture {T_Silver_3C}
texture {
   pigment {
     cells
     turbulence 1 octaves 5 omega 1 lambda 5
     //pigment_map {
     //  [0	Black filter 0.0]
     //  [1	White filter 0.99]
     //}
   }
   normal {
     cells -5
     turbulence 1 octaves 5 omega 1 lambda 5
     accuracy 0.001
   }
}

// and with color variation as given by Grassblade:
#declare Me_corrodedMetal2 =
texture {
   pigment {
     cells
     turbulence 1 octaves 5 omega 1 lambda 5
     color_map {
       [0.0 color rgb <0.5,0.3,0.1>]
       [0.5 color rgb <0.45, 0.45, 0.45>]
       [1.0 color rgb <0.5,0.3,0.1>]
     }
   }
   normal {
     cells -5
     turbulence 1 octaves 5 omega 1 lambda 5
     accuracy 0.001
   }
}

//or:
#declare Me_corrodedMetal3=
texture {
   cells
   turbulence 1 octaves 5 omega 1 lambda 5
   texture_map {
     [0.0 Me_corrodedMetal2]
     [0.5 MGrayFro]	//T_Silver_3C]
     [1.0 Me_corrodedMetal2]
   }
}

//----------------------------------------------------------------------
// Cast metal Texture
// Created By Tim Attwood

#declare TA_CastMetal =
texture {
    pigment{rgb <0.8, 0.8, 0.8>}		//(0.5) change to needs (TdG)
    normal{facets coords 1 scale 1}	//(scale 0.1)
    finish {
       ambient 0
       brilliance 2
       diffuse 0.7		//(0.6) change to needs (TdG)
       metallic
       specular 0.50
       roughness 5/60
       reflection 0.1
    }
    scale 0.35
}

//-------------------------------------------------------
// Rusty Chrome texture by David Anjo
#declare TM_Rusty_Chrome =
texture {
  pigment {
   granite
   color_map {
       [0.00 color rgb<0.400, 0.400, 0.400>]
       [0.70 color rgb<0.498, 0.498, 0.498>]
       [0.70 color rgb<0.898, 0.518, 0.278>]
       [0.75 color rgb<0.698, 0.137, 0.000>]
       [0.80 color rgb<0.698, 0.400, 0.078>]
       [0.80 color rgb<0.698, 0.439, 0.078>]
       [0.85 color rgb<0.498, 0.298, 0.278>]
       [0.85 color rgb<0.498, 0.318, 0.278>]
       [0.90 color rgb<0.878, 0.498, 0.278>]
       [0.90 color rgb<0.498, 0.498, 0.498>]
       [1.00 color rgb<0.400, 0.400, 0.400>]
   }
  }
  finish {
   brilliance 6.0
   phong 0.25    metallic
   reflection 0.05
  }
}


Post a reply to this message

From: LanuHum
Subject: Re: Rusty bearing: a collection of rusty metals
Date: 9 Feb 2014 09:15:01
Message: <web.52f746a7caa2b3387a3e03fe0@news.povray.org>
Thomas de Groot <tho### [at] degrootorg> wrote:
> I have made a selection of rusty metals that have been offered over the
> years in these newsgroups. Names of authors (and sometimes dates) are
> given for each of them. You have already Xplo's. This list is certainly
> not exhaustive but it is what I have collected.
>
> Thomas

Thanks!


Post a reply to this message

From: Cousin Ricky
Subject: Re: Rusty bearing: a collection of rusty metals
Date: 9 Feb 2014 22:30:01
Message: <web.52f800f2caa2b338192ae5f10@news.povray.org>
Thomas de Groot <tho### [at] degrootorg> wrote:
> I have made a selection of rusty metals that have been offered over the
> years in these newsgroups. Names of authors (and sometimes dates) are
> given for each of them. You have already Xplo's. This list is certainly
> not exhaustive but it is what I have collected.

Thanks, not only for the textures, but for your careful documentation of
sources.


Post a reply to this message

From: Thomas de Groot
Subject: Re: Rusty bearing: a collection of rusty metals
Date: 10 Feb 2014 08:17:56
Message: <52f88b34$1@news.povray.org>
On 9-2-2014 23:28, Cousin Ricky wrote:
> Thanks, not only for the textures, but for your careful documentation of
> sources.
>

You are welcome. I believe giving sources is the natural thing to do. 
The code reflects the maker and sometimes it is necessary to go back to 
sources, but essentially, the codes are graciously given to us for our 
own use and where possible, we should give credit to the authors. 
Possibly my old scientific training in monitoring references ;-)

Thomas


Post a reply to this message

Copyright 2003-2008 Persistence of Vision Raytracer Pty. Ltd.