/*
 
 __________________
   MSet-basic.pov
 2011  Samuel Benge
 ŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻ
  
*/
#version 3.7;

// the main macro
#macro iterate(iters)
 
 // interior (basin) coloring/patterning
 #local iterate_1 = function(x,y,PX,PY){ 0 }
 
 // main loop (no recursive functions, they were too touchy)
 #local i = 0;
 #while(i<iters)
  #local iterate_2 = iterate_1; #undef iterate_1
  
  /* separate the function into: 1) further tests, 2) exterior coloring */
  #local iterate_1 =
   function(x,y,PX,PY){
    select(
     
     // testing against the magnitude
     (x*x+y*y)/2-2,
     
     /* carrying the function over for further testing (next iteration) */
     iterate_2(
      
      /* the Mandelbrot Set, carrying the complex numbers over */
      x*x-y*y +PX,  
      x*y*2   +PY,
      
      /* carrying the pixel variables over */
      PX,
      PY
     ),
     
     // coloring method
     /* for normalized smoothing, replace with i-(log(log(sqrt(x*x+y*y))))/log(2.0)/iters-i/iters */
     1-(i-1)/iters
     
    )
   }
  #undef iterate_2
  #local i=i+1;
 #end
 
 /* The final result.
    "*iters/256" is needed to correct the coloring
    remove it for normalized smoothing             */
 function{ iterate_1( x, y, x, y )*iters/256}
 
 #undef iterate_1
#end // iterate

plane{z,0
 pigment{
  // the pattern encapsulates nicely :)
  iterate(256)
  frequency 4
  scale 1/2
 }
 finish{ambient 1.3}
}

camera{
 orthographic
 location -z
}

global_settings{assumed_gamma 1.0}