#version 3.6;


#local EdgeL =
spline { natural_spline
  0/3 <-.1,0,0>
  1/3 <-4,0,2>
  2/3 <-4,0,5>
  3/3 <-.01,0,10>
}     

#local EdgeR =
spline { natural_spline
  0/3 <.1,0,0>
  1/3 <4,0,2>
  2/3 <4,0,5>
  3/3 <.01,0,10>
}  

#local Spine =
spline { natural_spline
  0/3 <0,0,0>
  1/3 <0,1,2>
  2/3 <0,0,5>
  3/3 <0,0,10>
}

//left side using patches

#local Grain=15;

#local I=0;#while (I<Grain)  
  
  #local Indx0 = I/Grain; 
  #local Indx1 = (I+.3332)/Grain;   
  #local Indx2 = (I+.6667)/Grain;
  #local Indx3 = (I+1.0)/Grain;
  
  #local P = 
  array [16] {
    EdgeL(Indx0),
    .66*(EdgeL(Indx0)-Spine(Indx0))+Spine(Indx0),
    .33*(EdgeL(Indx0)-Spine(Indx0))+Spine(Indx0),
    Spine(Indx0), 
  
    EdgeL(Indx1),
    .66*(EdgeL(Indx1)-Spine(Indx1))+Spine(Indx1),
    .33*(EdgeL(Indx1)-Spine(Indx1))+Spine(Indx1),
    Spine(Indx1), 
    
    EdgeL(Indx2),
    .66*(EdgeL(Indx2)-Spine(Indx2))+Spine(Indx2),
    .33*(EdgeL(Indx2)-Spine(Indx2))+Spine(Indx2),
    Spine(Indx2), 
    
    EdgeL(Indx3),
    .66*(EdgeL(Indx3)-Spine(Indx3))+Spine(Indx3),
    .33*(EdgeL(Indx3)-Spine(Indx3))+Spine(Indx3),
    Spine(Indx3), 
  }; 
    
  bicubic_patch {
    type 1        // patch_type (0..1)
    flatness 0.05  // flatness value
    u_steps 5     // # of triangles to subdivide (1-5)
    v_steps 5     // # of triangles to subdivide (1-5)
    P[0]  P[4]  P[8]  P[12]
    P[1]  P[5]  P[9]  P[13]
    P[2]  P[6]  P[10] P[14]
    P[3]  P[7]  P[11] P[15] 
        
    pigment { rgb 1 }  
    normal { bumps 1 scale .005 }
  }
    
#local I=I+1;#end  



//right side using triangles

#include "shapes.inc"
#local Grain=45;

mesh {
  #local I=1;#while (I<=Grain)  

    #local A = Spine((I-1)/Grain);
    #local B = EdgeR((I-1)/Grain); 
    #local C = EdgeR(I/Grain); 
    #local D = Spine(I/Grain);    

    #local An = vcross ( B-A, D-A );
    #local Bn = vcross ( C-B, A-B );
    #local Cn = vcross ( D-C, B-C );
    #local Dn = vcross ( A-D, C-D ); 
  
    //Quad(
    //  A,
    //  B,
    //  C,
    //  D
    //)
    
    Smooth_Quad( 
      A,An,
      B,Bn, 
      C,Cn,
      D,Dn 
    )
        
  #local I=I+1;#end

  pigment { rgb 1 }  
  normal { bumps 1 scale .005 }
}
    

plane {
  y, -1
  pigment { 
        checker 
        color rgb .7
        color rgb <1,1,.9>  
        scale 10
  }
}
camera {
  location  vrotate (<0,0, -10>,<40,90,0>)  
  right     x*image_width/image_height
  look_at   <0.0, 0.0, 5.0>
}
light_source {
  0
  color rgb 1 // light's color
  translate vrotate (<0,0, -1000>,<60,60,0>)  
}