/*
 Translucent Effect
 2006 Sam Benge

 ~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~
 ~ distribute this file freely ~
 ~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~

*/

global_settings{ assumed_gamma 1 }

#default{ finish{ambient 0 } }

camera{ 
 fisheye 
 right x*.5*1.33 up y*.5
 location<.034,.017,-15>
 angle 30
}

//
// area_light samples
#declare l_res = 3; // 4 or 5 is good; higher = better

// rotation of light_source, also affects sky_sphere
#declare lrot = <25,25,0>;

// color of light_source, also affects sky_sphere
#declare lcol = <1,1,.9>*2;
//

light_source{y*100000,lcol rotate lrot area_light x*50000,z*50000,l_res,l_res jitter adaptive 1 orient circular }
light_source{<-1,0,.5>*100000,.5 area_light x*50000,z*50000,l_res,l_res jitter adaptive 1 orient circular }
sky_sphere{pigment{spherical scale 2 translate y*1 rotate lrot turbulence .2 lambda 3 poly_wave 1.5 color_map{[0 rgb<.1 .1 .4>][1 rgb lcol]}}}

// your object here
#declare obj=
 // everything must be inside merge or intersection brackets
 merge{
   
  // put translucent objects below
  intersection{
   sphere{0,1.1}
   box{-1,1 }
   cylinder{x*-1.2,x*1.2,.3 inverse}
   cylinder{y*-1.2,y*1.2,.3 inverse}
   cylinder{z*-1.2,z*1.2,.3 inverse}
   
   // put double_illuminate here
   double_illuminate
  }
  
  // put all other objects here
  merge{   
   box{-.85,.85}
   
   pigment{rgb .5}
  }
  rotate<-30,45,0>
 }

#declare transmit_color = <0,1,0>;

// this object won't show
object{obj
 texture{
  pigment{rgbt 1}
 }
 interior{
  fade_power 2
  fade_distance .01
  fade_color transmit_color
  
  // change absorption to a higher value for less light penetration
  media{absorption 3 }
 }
 hollow
 no_image
 
 // it's translated a tiny bit away from the camera
 translate z*.001
}

// this object shows
// give it a new pigment and/or surface normal
object{obj
 pigment{crackle poly_wave .1}
 finish{
  brilliance 0 diffuse .5 ambient 0
  specular 1 roughness .01
  reflection{0,.5 falloff 3}
 }
 
 no_shadow
}