/*
 Translucent Effect
 2006 Sam Benge

 ~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~
 ~ distribute this file freely ~
 ~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~

*/

global_settings{ assumed_gamma 1 }

#default{ finish{ambient 0 } }

camera{ 
 fisheye 
 right x*.5*1.33 up y*.5
 location<.034,.017,-15>
 angle 20
}

// resolution of area_light
#declare l_res = 2; // 5 is good
// rotation of light_source, also affects sky_sphere
#declare lrot = <90,0,0>;
// color of light_source, also affects sky_sphere
#declare lcol = <1,1,.9>*2;

light_source{y*100000,lcol rotate lrot area_light x*50000,z*50000,l_res,l_res jitter adaptive 1 orient circular }
sky_sphere{pigment{spherical scale 2 translate y*1 rotate lrot turbulence .2 lambda 3 poly_wave 1.5 color_map{[0 rgb<.1 .1 .4>][1 rgb lcol]}}}

// your object here
#declare obj=
 // this intersection renders slowly!
 intersection{
  plane{y,1 rotate x*31.7} 
  plane{y,1 rotate x*-31.7}
  plane{-y,1 rotate x*31.7} 
  plane{-y,1 rotate x*-31.7}
  plane{x,1 rotate z*31.7} 
  plane{x,1 rotate z*-31.7}
  plane{-x,1 rotate z*31.7} 
  plane{-x,1 rotate z*-31.7}
  plane{z,1 rotate y*31.7} 
  plane{z,1 rotate y*-31.7}
  plane{-z,1 rotate y*31.7} 
  plane{-z,1 rotate y*-31.7}
  sphere{0,1.075 inverse}
  
  cylinder{y*-1.1,y*1.1,.5 rotate x*31.7 inverse}
  cylinder{y*-1.1,y*1.1,.5 rotate x*-31.7 inverse}
  cylinder{x*-1.1,x*1.1,.5 rotate z*31.7 inverse}
  cylinder{x*-1.1,x*1.1,.5 rotate z*-31.7 inverse}
  cylinder{z*-1.1,z*1.1,.5 rotate y*31.7 inverse}
  cylinder{z*-1.1,z*1.1,.5 rotate y*-31.7 inverse}
  
  rotate<-60,52,0>
 }


#declare transmit_color = <0,1,0>;

// this object won't show
object{obj
 texture{
  pigment{rgbt 1}
 }
 interior{
  fade_power 2
  fade_distance .01
  fade_color transmit_color
  
  // change absorption to a higher value for less light penetration
  media{absorption 5 }
 }
 hollow
 no_image
 
 // it's translated a tiny bit away from the camera
 translate z*.001
}

// give this object a new pigment and/or surface normal
object{obj
 pigment{crackle poly_wave .1}
 finish{
  brilliance 0 diffuse .5 ambient 0
  specular 1 roughness .01
  //reflection{0,1 falloff 2}
 }
 double_illuminate
 no_shadow
}