// Celestin #2 
// (c)2005 - LightBeam
// Megapov 1.1 on Athlon XP 3200+ & 1Go DDR400MHz
// Mandrake 10.1 Official on linux 2.6.8
// Render time : 65 seconds.

// NB: Mes plus plates excusances auprès de mes potaux Français
// mais comme je distribois eul'code sur le p.b.s.c euj'dois bien
// me faire universellement comprendre ;-)

#version unofficial MegaPov 1.1;

// Usefull for the aoi direction
#declare macam = <0.0, 3.0, -4.4>;

camera {location macam
	look_at <0.0, 1.2, 0.0>
	angle 31.0
 right x*image_width/image_height
	// The Depth of field effect
	aperture 0.14 // Comment this line to disable the DOF
	focal_point <0.0, 1.2, -0.1>
	blur_samples 100.0
}

// Main light source
light_source {<130.0, 200.0, -150.0>1.0}
// opposite ambient light (clearer shadows)
light_source {<-50.0, 60.0, -200.0>0.3 shadowless}

// The macro to make the cell effect
#macro cell(rvb,debut)	
	texture {
	 pigment {aoi macam color_map {[1.0 rgb rvb][debut rgb 0.0]}}	
	 finish {brilliance 0.0 phong 0.3 phong_size 1.0 /*specular 0.2 roughness 0.1*/}		
	}
#end

// The soil
plane {y, -0.02
	texture {
	 pigment {rgb <0.643, 0.675, 0.773>}	
		finish {reflection 0.09}
		normal {leopard 1.2 scale 0.034 sine_wave rotate y*-12.0}
	}
}

// The balls
sphere {<1.0, 0.2, -0.65>0.2 
 cell(rgb <0.333, 0.667, 0.498>,0.4)	
}
sphere {<-2.1, 0.6, 2.4>0.6 
 cell(rgb <0.306, 0.655, 1.000>,0.4)
}
sphere {<2.3, 0.6, 4.0>0.6 
 cell(rgb <1.000, 0.333, 0.498>,0.4)
}
sphere {<-1.0, 0.6, 9.0>0.6 
 cell(rgb <0.333, 0.667, 0.498>,0.4)
}
sphere {<1.5, 0.5, 16.0>0.5 
 cell(rgb <1.000, 0.000, 0.000>,0.35)
}

// Shoes
#declare shoe = union {
	difference {
	 sphere {0.0, 0.4 scale <0.5, 0.6, 0.9>}
	 box {<-0.5, -0.5, -0.5><0.5, 0.0, 0.5>}		
	}
	sphere {0.0, 0.4 scale <0.5, 0.1, 0.9>}	
	translate y*0.05
	cell(rgb <0.553, 0.271, 0.110>,0.4)
}

#declare shoe2 = union {
	difference {
	 sphere {0.0, 0.4 scale <0.5, 0.6, 0.90>}
	 box {<-0.5, -0.5, -0.5><0.5, 0.0, 0.50>}		
		box {<-0.014, 0.1, -0.4><0.014, 0.3, 0.0>}
		cylinder {<0.0, 0.2, 0.05><0.0, 0.3, 0.05>0.1}
  difference {
			cylinder {<-0.3, 0.0, 0.0><0.3, 0.0, 0.3>0.16 scale <1.0, 0.5, 1.0>}
			cylinder {<-0.4, 0.0, 0.0><0.4, 0.0, 0.3>0.14 scale <1.0, 0.5, 1.0> translate <0.0, 0.06, -0.06>}
			translate <0.0, 0.1, -0.15>
		}
	}
	sphere {0.0, 0.400 scale <0.5, 0.1, 0.9>}	
	sphere {0.0, 0.399 scale <0.5, 0.6, 0.9> pigment {rgb 0.05}}
	scale 0.9
	translate y*0.05
	cell(1.0,0.4)
}

union {
 object {shoe2 rotate y*45.00 translate x*-0.36}
	object {shoe2 rotate y*-10.0 translate x*0.360}
}

union {
// Shirt
sphere {<0.0, 0.90, 0.0>0.50
 cell(rgb <0.871, 0.102, 0.306>,0.4)
}
// Trousers
difference {
 sphere {<0.0, 0.90, 0.0>0.52}	
	box {<-0.6, 0.9, -0.6><0.6, 1.5, 0.6> pigment {rgb 0.0}}
 cell(rgb <0.373, 0.490, 0.667>,0.4)
}
// The Belt
difference {
 sphere {<0.0, 1.0, 0.0>0.522}	
	box {<-0.6, 0.0, -0.6><0.6, 0.9, 0.6> pigment {rgb 0.0}}
	box {<-0.6, 1.0, -0.6><0.6, 1.5, 0.6> pigment {rgb 0.0}}
 cell(rgb <0.710, 0.404, 0.227>,0.45)
}
// buckle belt
union {
 difference {
	 box {<-0.10, -0.10, -0.02><0.10, 0.10, 0.02>}
	 box {<-0.07, -0.07, -0.03><0.07, 0.07, 0.03>}
	}
	cylinder {<-0.1, 0.0, -0.01><0.0, 0.0, -0.01>0.007}
	//cell(rgb <0.710, 0.710, 0.710>,0.256)
	pigment {aoi macam color_map {[1.0 rgb 0.710][0.256 rgb 0.0]}}	
	finish {brilliance 0.0 phong 0.4 phong_size 1.0 reflection 0.4}		
	//
	scale 0.9
	translate <0.0, 0.96, -0.51>
}
// Head
sphere {<0.0, 1.70, 0.000>0.25 cell(rgb <1.000, 0.812, 0.608>,0.38)}
// Nose
sphere {<0.0, 1.69, -0.25>0.07 cell(rgb <1.000, 0.759, 0.541>,0.33)} 
// Ears
#declare oreille = difference {
	sphere {0.0, 0.10}
	sphere {0.0, 0.07 translate <0.0, 0.025, -0.05>}
	scale <0.7, 1.0, 0.5>
 cell(rgb <1.000, 0.812, 0.608>,0.33)
}

object {oreille rotate z*10.00 translate <-0.25, 1.72, 0.05>}
object {oreille rotate z*-10.0 translate <0.250, 1.72, 0.05>}

// Eyes
// White
union {
	sphere {<-0.1, 1.85, -0.16>0.05}
	sphere {<0.10, 1.85, -0.16>0.05}
	cell(rgb 1.0, 0.3)
}
// Blue-eyed ;-)
union {
	sphere {<-0.1, 1.87, -0.2>0.017}
	sphere {<0.10, 1.87, -0.2>0.017}
	cell(rgb <0.333, 0.667, 1.000>, 0.2)
}
// Hairs
union {
	#declare r = -40.0;
	#while (r <= 40.0)
		cone {<0.0, 0.26, 0.0>0.06<0.0, 0.5, 0.0>0.021 rotate z*r}
		#declare r = r + 10.0;
	#end
	cell(rgb <0.671, 0.514, 0.396>,0.24)
	translate y*1.65
}
// Yellow Buttons
union {
#declare r = -70.0;
#while (r <= -20.0)
	sphere {0.0,0.05 scale <1.0, 1.0, 0.4> translate z*-0.52 rotate x*-r
		cell(rgb <1.000, 1.000, 0.000>,0.2)
	}
	#declare r = r + 20.0;
#end
translate <0.0, 0.9, 0.0>
}
// Hands
union {
	sphere {0.0,0.1 scale <1.4, 1.0, 1.0> translate <0.64, 1.3, 0.0>}
	sphere {0.0,0.1 scale <1.4, 1.0, 1.0> translate <-0.73, 1.1, 0.0>}
	cell(rgb <1.000, 0.812, 0.608>,0.33)
}
	// Thumbs
union {
	sphere {0.0, 0.12 scale <0.3, 1.0, 0.3> rotate z*-33.0 translate <0.57, 1.40, -0.01>}
	sphere {0.0, 0.12 scale <0.3, 0.8, 0.3> rotate z*40.0 translate <-0.66, 1.19, 0.01>}
 cell(rgb <1.000, 0.812, 0.608>,0.2)
}
translate y*0.15
}