//
// visible_light_source.pov
//
// 2004 Sam Benge
// This scene demonstrates a
// technique for making light_sources
// visible in POV-Ray 3.5.
//
// This code is free for any kind of use.
//

global_settings{ 
 assumed_gamma 1 
}

#default{ finish{ ambient 0 }}

#declare lpos=<.25,.15,1>*100000;
#declare cpos=<0,5,-30>;

camera{ 
 fisheye 
 right x*.5*1.33 up y*.5 
 location cpos
 look_at y*5
 angle 50 
}

background{rgb<.1 .2 .5>}

fog{
 rgb<.7 .6 .3>
 distance 10000
 fog_type 2
 fog_alt 900
 fog_offset 0
}

// Light Setup
light_source{lpos,<1 1 .6>*2 }
cylinder{
 cpos,lpos,1
 open
 pigment{rgbt 1}
 finish{
  specular .3 roughness .005
  phong 1 phong_size 50000
 }
 hollow no_shadow
}

// Water
plane{y,-10
 finish{
  reflection{0,1 fresnel}
  specular .3 roughness .005
  phong 1 phong_size 50000
 }
 normal{
  average
  normal_map{
   [1 granite -.8 scale 30 poly_wave .2]
   [1 granite -.6 scale 10 poly_wave .2]
   [1 granite -.4 scale 3 poly_wave .2]
  }  
 }
 interior{ior 1.33}
 hollow
}