//test it
#include "rad_def.inc"
#include "shapes.inc"
#include "shapesq.inc"
#include "logo.inc"

#include "cheapworld.inc"

global_settings {
/*	radiosity {
		Rad_Settings(Radiosity_OutdoorLQ, on, on)
	}*/	//not needed for space scenes, but good on planets that have concave bits.
}

camera {
	right			x*image_width/image_height
	up				y
	direction	z*1
	
	#declare fCamDist = 2.5;
	location -fCamDist*z
}




/*************************************************/
//change this for some wierder shapes (pick a number between 0 & 6)
#declare nObjectType = 0;
/*************************************************/



#switch (nObjectType)

	#case(0)
		sphere {
			0, 1
			texture { tCheapWorldAndAtmos }
			//rotate -y*clock*360 - z*30
			rotate -30*y
			no_shadow
		}
		
		//Atmosphere for spherical planet
		cone { 0, 0, -z/fCamDist, sqrt(fCamDist*fCamDist - 1)/fCamDist
			open
			double_illuminate
			no_shadow
			hollow on
		
			pigment {
				spherical
				colour_map {
					[0	rgb <.5,.7,1>	transmit 1]
					[.02/1.02	rgb <.5,.7,1>	transmit 0]
				}
			}
			finish {
				diffuse 1
				ambient 0
				brilliance 1.5
			}
			normal {
				spherical 12
				scale 2
			}
			
			scale 1.02
		}
	#break;
	
	#case(1)
		blob {
			sphere { x*.7, .8, 3 rotate y*0 }
			sphere { x*.7, .8, 3 rotate y*120 }
			sphere { x*.7, .8, 3 rotate y*240 }
			texture { tCheapWorldAndAtmos }
		
			scale 1
		
			rotate <-30, 20, 0>
			no_shadow
		}
	#break;
	
	#case (2)
		superellipsoid {
			<.1,.1>

			scale .7
		
			texture { tCheapWorldAndAtmos }
		
			rotate <-30, -20, 0>
			no_shadow
		}
	#break;

	#case (3)
		superellipsoid {
			<1,.1>

			scale .7
		
			texture { tCheapWorldAndAtmos }
		
			rotate <-30, -20, 0>
			no_shadow
		}
	#break;

	#case (4)
		torus {
			.7,.3
		
			texture { tCheapWorldAndAtmos }
		
			rotate <-30, -20, 0>
			no_shadow
		}
	#break;

	#case (5)
		object {
			Povray_Logo
		
			texture { tCheapWorldAndAtmos }
		
			no_shadow
		}
	#break;

	#case (6)
		object {
			Monkey_Saddle
		
			texture { tCheapWorldAndAtmos }
		
			rotate <30, -25, 0>
			no_shadow
		}
	#break;

#end //switch


light_source {
	<-1,1,-1>*10000
	rgb 1
}