#version 3.1;
global_settings{assumed_gamma 1.0}

light_source{
  <500,500,-500>
  color rgb <1,1,1>
}
camera{
    location<15.0,10.0,-25>
    look_at<15.0,10.0,0.0>
    orthographic
}                                                      

#declare s=seed(7);
//#declare Bend=240;
#declare Tx=0;
#declare Ty=0;

#while (Ty<22)
  #while (Tx<31)
  
    #if (Ty=0 & Tx=30)
      #declare Bend=2400;
    #else
      #declare Bend=240;
    #end
    
    #declare A=vrotate(vaxis_rotate(<-0.25,0.25,0>,<1,1,0>,(pow((rand(s)-0.5),3)*Bend))+<-0.25,0.25,0>,<(pow((rand(s)-0.5),3)*Bend),(pow((rand(s)-0.5),3)*Bend),0>);
    #declare B=vrotate(<0,0.5,0>,<(pow((rand(s)-0.5),3)*Bend),0,0>);
    #declare C=vrotate(vaxis_rotate(<0.25,0.25, 0>,<1,-1, 0>,(pow((rand(s)-0.5),3)*Bend))+<0.25,0.25,0>,<(pow((rand(s)-0.5),3)*Bend),(pow((rand(s)-0.5),3)*Bend),0>);
    #declare D=vrotate(<-0.5,0,0>,<0,(pow((rand(s)-0.5),3)*Bend),0>);
    #declare E=<0,0,0>;
    #declare F=vrotate(<0.5,0,0>,<0,(pow((rand(s)-0.5),3)*Bend),0>);
    #declare G=vrotate(vaxis_rotate(<-0.25,-0.25,0>,<-1,1,0>,(pow((rand(s)-0.5),3)*Bend))+<-0.25,-0.25,0>,<(pow((rand(s)-0.5),3)*Bend),(pow((rand(s)-0.5),3)*Bend),0>);
    #declare H=vrotate(<0,-0.5,0>,<(pow((rand(s)-0.5),3)*Bend),0,0>);
    #declare I=vrotate(vaxis_rotate(<0.25,-0.25,0>,<-1,-1,0>,(pow((rand(s)-0.5),3)*Bend))+<0.25,-0.25,0>,<(pow((rand(s)-0.5),3)*Bend),(pow((rand(s)-0.5),3)*Bend),0>);
   
    #declare N1= vnormalize(vcross((A-B),(D-B)));
    #declare N2= vnormalize(vcross((B-E),(D-E)));
    #declare N3= vnormalize(vcross((B-E),(F-E)));
    #declare N4= vnormalize(vcross((B-C),(F-C)));
    #declare N5= vnormalize(vcross((H-G),(D-G)));
    #declare N6= vnormalize(vcross((D-E),(H-E)));
    #declare N7= vnormalize(vcross((H-E),(F-E)));
    #declare N8= vnormalize(vcross((I-H),(F-H)));

    #declare NA= N1;
    #declare NB=(N1+N2+N3+N4)/4;
    #declare NC= N4;
    #declare ND=(N1+N2+N5+N6)/4;
    #declare NE=(N2+N3+N6+N7)/4;
    #declare NF=(N3+N4+N7+N8)/4; 
    #declare NG= N5;
    #declare NH=(N5+N6+N7+N8)/4;
    #declare NI= N8;
    
    mesh {
      smooth_triangle {A,NA, B,NB, D,ND}
      smooth_triangle {D,ND, B,NB, E,NE}
      smooth_triangle {E,NE, B,NB, F,NF}
      smooth_triangle {B,NB, C,NC, F,NF}
      smooth_triangle {D,ND, G,NG, H,NH}
      smooth_triangle {D,ND, H,NH, E,NE}
      smooth_triangle {E,NE, H,NH, F,NF}
      smooth_triangle {H,NH, I,NI, F,NF}
      scale <1,2,1>
      translate <Tx,Ty,0>
      pigment {rgb 1}
    }  

    #declare Tx=Tx+1;
  #end
  #declare Tx=0;
  #declare Ty=Ty+2;
#end