|
 |
Thomas de Groot <tho### [at] degroot org> wrote:
> Op 25/08/2022 om 14:11 schreef ingo:
> > 4.
>
> Covered by paper and lit from below? Intriguing image...
>
---%<------%<------%<---
// PoVRay 3.7 Scene File " 4 .pov"
// author: ingo
//--------------------------------------------------------------------------
// Still:
//cmd: +w1920 +h1080 +a0.05 +am2 +r4
// Animated:
//cmd: +w720 +h400 +kfi0 +kff719 +kc +a0.05 +am2 +r4
//ffmpeg -r 30 -f image2 -s 720x400 -i 0_animblurr%03d.png -vcodec libx265 -crf
20 -preset veryslow -pix_fmt yuv420p animblurr_0.mp4
#version 3.7;
global_settings{ assumed_gamma 1.0 }
#default{ finish{ ambient 0.1 diffuse 0.9 }}
//
sphere{
<0.5,0,-.04>0.03 pigment{rgb <1,0,0>}
}
text {
internal 1 "4"
0.1, 0
pigment{rgb 1}
}
#declare T = object {
text {
internal 1 "4"
0.2, 0
pigment{rgb 1}
}
}
#declare Tmin = min_extent(T);
#declare Tmax = max_extent(T);
#debug concat("Tmin : ",vstr(3,Tmin,",",0,-1),"\n")
#debug concat("Tmax : ",vstr(3,Tmax,",",0,-1),"\n")
object {
T
translate <-Tmax.x/2,0,0>
rotate<0, clock * 365, 0>
translate<-0.2+(Tmax.x/2) , 0.3, -0.1>
}
object {
T
translate <-Tmax.x,0,0>
rotate<0, clock * 365, 0>
translate<-0.2+(Tmax.x/2) , 0.3, -0.1>
}
object {
T
translate <Tmax.x,0.1 ,0.05>
rotate<0, clock * -365, 0>
translate<-0.2+(Tmax.x/2) , 0.3, -0.1>
}
object {
T
translate <Tmax.x+0.2, 0.15 ,0>
rotate<-clock * 365, -clock * 365, 0>
translate<-0.2+(Tmax.x/2) , 0.3, -0.1>
}
object {
T
scale 1.5
translate <Tmax.x-1.7, -0.15 ,0.2>
rotate<0, clock * 365 * 2, 0>
translate<-0.2+(Tmax.x/2) , 0.3, -0.1>
pigment{rgb <0.1,0,1.2>}
}
camera {
perspective angle 65
location <-0.5 , 0.5 ,-2.0>
right x*image_width/image_height
look_at <0.0 , 0.5 , 0.0>
aperture 45
blur_samples 80
focal_point <0.3, 0.5, 0.02>
}
light_source{< -3000,3000,-3000> rgb <0.2,0.3,.7>}
light_source{<0,0.5,-.2> color rgb <1.2,0.3,.7>}
light_source{<0,-10.5,-2> color rgb 1.5}
light_source{<-3,10.5,2> color rgb <0.9,0.3,.7>}
background{rgb <0.2,0.0,0.03>}
---%<------%<------%<---
Post a reply to this message
|
|
|
|
Another quick one. I's nice to have a new fast machine :)
---%<------%<------%<---
// PoVRay 3.7 Scene File " 4 .pov"
// author: ingo
//--------------------------------------------------------------------------
// Still:
//cmd: +w1920 +h1080 +a0.05 +am2 +r4
#version 3.7;
global_settings{ assumed_gamma 1.0 }
#default{ finish{ ambient 0.1 diffuse 0.9 }}
#declare Stick = union{
#local A = <0,1,0>;
#local B = <0,-1,0>;
sphere{
A, 0.1
texture {
pigment { colour rgb <1,0,0>}
}
}
sphere{
B, 0.1
texture {
pigment { colour rgb <1,0,0>}
}
}
cylinder{
A, B, 0.01
texture {
pigment {colour rgb 0}
}
}
//translate<-3,0,0>
}
#for (i, -6, 6, 0.05)
object{
Stick
rotate<i*15 ,i, abs(i*40)>
translate <i,i/3,0>
}
#end
light_source{<-3,10.5,2> color rgb <0.9,0.3,.7>}
background{rgb 1}
camera {
perspective angle 65
location <0 , 0 , -5.0>
right x*image_width/image_height
look_at <0.2 , 0 , 0.0>
aperture 45
blur_samples 80
focal_point <0.2, 0, 0>
}
---%<------%<------%<---
Post a reply to this message
Attachments:
Download 'sticks_02.jpg' (97 KB)
Preview of image 'sticks_02.jpg'
|
|
