POV-Ray : Newsgroups : povray.binaries.images : Page with minimal surfaces Server Time
29 Mar 2024 09:56:08 EDT (-0400)
  Page with minimal surfaces (Message 1 to 10 of 12)  
Goto Latest 10 Messages Next 2 Messages >>>
From: Norbert Kern
Subject: Page with minimal surfaces
Date: 26 Jul 2019 11:45:01
Message: <web.5d3b1ef93b1ce97daaf669a10@news.povray.org>
Hi,
I found a website with a whole bunch of minimal surfaces generated with
Mathematica - https://minimalsurfaces.blog/ together with their povray-files.

Here is a pimped example.

Regards Norbert


Post a reply to this message


Attachments:
Download 'prismatic k-noids.jpg' (622 KB)

Preview of image 'prismatic k-noids.jpg'
prismatic k-noids.jpg


 

From: Thomas de Groot
Subject: Re: Page with minimal surfaces
Date: 27 Jul 2019 02:41:47
Message: <5d3bf22b$1@news.povray.org>
Op 26/07/2019 om 17:40 schreef Norbert Kern:
> Hi,
> I found a website with a whole bunch of minimal surfaces generated with
> Mathematica - https://minimalsurfaces.blog/ together with their povray-files.
> 
> Here is a pimped example.
> 
> Regards Norbert
> 

Oooohhh!

[drools]

-- 
Thomas


Post a reply to this message

From: Norbert Kern
Subject: Re: Page with minimal surfaces
Date: 27 Jul 2019 03:30:00
Message: <web.5d3bfca98fedcac0aaf669a10@news.povray.org>
Thomas de Groot <tho### [at] degrootorg> wrote:
>
> Oooohhh!
>
> [drools]
>
> --
> Thomas


Simple - ...


// https://minimalsurfaces.blog/home/repository/spheres/prismatic-k-noids/

#version 3.7;

#declare RAD = 64;

global_settings {
        assumed_gamma 2.2
        max_trace_level 5
        noise_generator 2
        #if(RAD > 0)
                radiosity {
                        pretrace_start 0.08
                        pretrace_end 0.04/RAD
                        count 30*RAD
                        nearest_count min (20, RAD)
                        error_bound 2/RAD
                        low_error_factor 0.5
                        recursion_limit 1
                        gray_threshold 0
                        minimum_reuse 0.015
                        brightness 1
                        adc_bailout 0.005
                        normal on
                        media on
                }
        #end
}

#include "stdinc.inc"

#declare stereo = 0;
camera {
 location <0.6,0,-4>+stereo*<.1,0,0>
  right x*image_width/image_height
 angle 47
        look_at <-0.3,-0.18,0>
}

sphere {
        0, 1000
        pigment {
                image_map {
                        hdr "pisa.hdr"
//http://gl.ict.usc.edu/Data/HighResProbes/probes/pisa.hdr
                        gamma 2.2
                        map_type 1
                        interpolate 2
                }
        }
        finish {emission 8 diffuse 0}
        rotate <240,0,0>
        no_image
}

background {color White}

//______________________________________________________________________________

// normal from Jim Holsenback  compass final
http://news.povray.org/povray.binaries.images/thread/%3C4d6ae61a@news.povray.org%3E/?ttop=372340&toff=200
// everything else adapted from Tekno Frannansa  Metallic paint - v2
http://news.povray.org/povray.binaries.scene-files/message/%3C3ec17be0%241%40news.povray.org%3E/#%3C3ec17be0%241%40news
.povray.org%3E

#declare T1 =
material {
        texture {
         pigment {color srgb 0.1}
         finish {diffuse 0.8}
        }
        texture {
         pigment {color srgbt <1,1,1,1>}
         finish {
          diffuse 1
          ambient 0
          specular 0.9
          metallic
          roughness 0.005
                        brilliance 8
                        reflection {0, 0.09 falloff 15}
         }
         normal {facets coords 0.8 size 0.05}
        }
        texture {
         pigment {color srgbt 1}
         finish {
          diffuse 1
          ambient 0
          reflection {0.08, 0.5 fresnel on}
          conserve_energy
          specular 0.5
          roughness 0.001
         }
         normal {facets coords 0.05 size 0.05}
        }
 interior {ior 1.54}
 scale 0.3
}

plane {y, -0.9 material {T1} rotate x*-30}

//______________________________________________________________________________

#declare tr = 0.0;

#declare spherecolor = srgb <0.76,0.76,0.8>/4;
#declare rodcolor1 = srgb <0.82459,0.822353,0.70061>;
#declare rodcolor2 = srgb <0.823507,0.67435,0.564063>;

#declare RodFinish  =
finish {
        ambient 0
        diffuse 0.424433
        brilliance 16.992
        phong 0.482
        phong_size 66.886667
        specular 0.129467
        roughness 0.1203
        reflection {
                0.13, 0.34
                fresnel on
                falloff 1
                exponent 1
                metallic 0.5
        }
        conserve_energy
}

#declare SphereFinish =
finish {
        ambient 0
        diffuse 0.424433
        brilliance 16.992
        phong 0.482
        phong_size 66.886667
        specular 0.129467
        roughness 0.1203
        reflection {
                0.13, 0.34
                fresnel on
                falloff 1
                exponent 1
                metallic 0.5
        }
        conserve_energy
}

//______________________________________________________________________________

#declare mesh_texture1 =
texture {
        pigment {color srgb <1,0.6,0.2>*0.7}
        finish {
                ambient 0
                diffuse 0.1
                specular 3
                roughness 0.04
                reflection {0.5 metallic}
                metallic
                brilliance 1.5
        }
 normal {
  granite 0.07
  scale 0.002
 }
}

//______________________________________________________________________________

// material based on - Bill Hails  Textures.inc for Tea pic
http://news.povray.org/povray.binaries.scene-files/attachment/%3C4456112b%40news.povray.org%3E/us-ascii?ttop=393045&tof
f=300

#macro Porcelain (col)

#local P_Porcelain = pigment {color srgb col}

#local N_Porcelain =
normal {
 average
 normal_map {
  [1      bozo 0.633 scale 0.5]
  [1      bozo 0.633]
  [1      bozo 0.633 scale 2]
  [1      bumps 0.15
   warp {turbulence 1}
   scale 0.2
  ]
  [1      bumps 0.1
   warp {turbulence 0.5}
   scale 0.001
  ]
 }
}

#local F_Porcelain =
finish {
 ambient 0
 diffuse 0.62
 brilliance 0.8
 reflection {0.1, 0.3 fresnel on}
 conserve_energy
}

#local T_Porcelain =
texture {
 pigment {P_Porcelain}
 normal {N_Porcelain}
 finish {F_Porcelain}
}

#local I_Porcelain = interior {ior 1.53}

texture {
        T_Porcelain
        scale 0.5
}

#end

#declare mesh_texture2 = Porcelain (<0.2,1,1>)

//_____________________________________________________________________________

// thicknesses of spheres and rods

#declare scal = 1.1;

#declare linerad = 0.002/scal;
#declare sphererad = 2*linerad/scal;

// include generated file

#include "dummy.pov"
//https://www.dropbox.com/sh/gvoq3405ec2xlbb/AAA7u11nrDdchYAeR9Cu75R_a/n%3D3%2C%20b%3D0.8?dl=0&subfolder_nav_tracking=1


#declare fundpiece1 =
object {
        union {
         object {
                        MESHtriangles
          texture {mesh_texture2}
          interior_texture {mesh_texture1}
         }
         object {
                        MESHspheres
          pigment {spherecolor }
          finish {SphereFinish}
         }
         object {
                        MESHhorlines
          pigment {rodcolor1}
          finish {RodFinish}
         }
         object {
                        MESHverlines
          pigment {rodcolor2}
          finish {RodFinish}
         }
        }
}

object {
 object {fundpiece1}
 scale scal
 rotate <0,0,-90>
 rotate <-130,0,0>

}


Post a reply to this message

From: Thomas de Groot
Subject: Re: Page with minimal surfaces
Date: 27 Jul 2019 03:43:55
Message: <5d3c00bb@news.povray.org>
Op 27/07/2019 om 09:26 schreef Norbert Kern:
> Thomas de Groot <tho### [at] degrootorg> wrote:
>>
>> Oooohhh!
>>
>> [drools]
>>
>> --
>> Thomas
> 
> 
> Simple - ...
> 

Thanks for all this! It is going to be interesting to explore this site...

-- 
Thomas


Post a reply to this message

From: Jim Holsenback
Subject: Re: Page with minimal surfaces
Date: 27 Jul 2019 06:49:41
Message: <5d3c2c45$1@news.povray.org>
On 7/26/19 11:40 AM, Norbert Kern wrote:
> Hi,
> I found a website with a whole bunch of minimal surfaces generated with
> Mathematica - https://minimalsurfaces.blog/ together with their povray-files.
> 
> Here is a pimped example.
> 
> Regards Norbert
> 

nice ... appreciate the shout out for the normal!


Post a reply to this message

From: Norbert Kern
Subject: Re: Page with minimal surfaces
Date: 27 Jul 2019 18:45:00
Message: <web.5d3cd3798fedcac0aaf669a10@news.povray.org>
Jim Holsenback <ash### [at] nospamcom> wrote:

> nice ... appreciate the shout out for the normal!



What normal exactly?


Norbert


Post a reply to this message

From: Bald Eagle
Subject: Re: Page with minimal surfaces
Date: 27 Jul 2019 20:35:00
Message: <web.5d3ced718fedcac04eec112d0@news.povray.org>
"Norbert Kern" <nor### [at] t-onlinede> wrote:
> Jim Holsenback <ash### [at] nospamcom> wrote:
>
> > nice ... appreciate the shout out for the normal!
>
>
>
> What normal exactly?
>
>
> Norbert


"
// normal from Jim Holsenback  compass final
http://news.povray.org/povray.binaries.images/thread/%3C4d6ae61a@news.povray.org%3E/?ttop=372340&toff=200
"

vide supra


Post a reply to this message

From: Norbert Kern
Subject: Re: Page with minimal surfaces
Date: 28 Jul 2019 09:50:01
Message: <web.5d3da6e98fedcac0aaf669a10@news.povray.org>
Jim Holsenback <ash### [at] nospamcom> wrote:
> On 7/26/19 11:40 AM, Norbert Kern wrote:
> > Hi,
> > I found a website with a whole bunch of minimal surfaces generated with
> > Mathematica - https://minimalsurfaces.blog/ together with their povray-files.
> >
> > Here is a pimped example.
> >
> > Regards Norbert
> >
>
> nice ... appreciate the shout out for the normal!



You deserve it - it is Material 477 out of 2435 together with 14 other entries.

Here is an example with the original material - maybe you want to correct it...

Norbert


Post a reply to this message


Attachments:
Download 'minimal surface2.jpg' (594 KB)

Preview of image 'minimal surface2.jpg'
minimal surface2.jpg


 

From: jr
Subject: Re: Page with minimal surfaces
Date: 31 Jul 2019 16:40:01
Message: <web.5d41fb898fedcac03936914a0@news.povray.org>
hi,

"Norbert Kern" <nor### [at] t-onlinede> wrote:
> Here is a pimped example.

meant to ask, what is reflected on the left inside?  is it a face?  anyway,
gorgeous colours.


regards ,jr.


Post a reply to this message

From: Norbert Kern
Subject: Re: Page with minimal surfaces
Date: 3 Aug 2019 04:55:01
Message: <web.5d454acc8fedcac050fe39060@news.povray.org>
"jr" <cre### [at] gmailcom> wrote:
>
> meant to ask, what is reflected on the left inside?  is it a face?  anyway,
> gorgeous colours.
>
>
> regards ,jr.

Thank you,

there are reflections from the Pisa hdr - my fault...
Here is an example with less defects like that.

Norbert


Post a reply to this message


Attachments:
Download 'schoen-h-t.jpg' (688 KB)

Preview of image 'schoen-h-t.jpg'
schoen-h-t.jpg


 

Goto Latest 10 Messages Next 2 Messages >>>

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.