POV-Ray : Newsgroups : povray.binaries.images : Small abstract Server Time
28 Mar 2024 18:17:10 EDT (-0400)
  Small abstract (Message 1 to 10 of 14)  
Goto Latest 10 Messages Next 4 Messages >>>
From: Norbert Kern
Subject: Small abstract
Date: 19 May 2019 05:55:00
Message: <web.5ce1265c730aefac3c1c78400@news.povray.org>
Hello to everyone,

here is a abstract with a small source.
It's not perfect, but nice enough to show -

#version 3.7;

global_settings {
        assumed_gamma 2.2
        max_trace_level 5
        noise_generator 2
}

#include "stdinc.inc"

camera {
        location <0,1,-7.7>
        look_at <0,-5.6,0>
        angle 30*image_width/image_height
        right image_width/image_height*x
        rotate z*30
}

#declare p2 = function {pattern {crackle metric 1 translate x*37}}
#declare FN = function (x,y,z) {(sin (p2 (x,0,z)*4*pi)+1)*(1-p2 (x,0,z))}

#declare base_pat =
pigment {
        #local Curve    = 0.125;
        #local Omega    = 0.5;
        #local Lambda   = 2.5;
        #local Octaves  = 8;
        pigment_pattern {
                average
                pigment_map {
                        #local octave = 0;
                        #while (octave < Octaves)
                                [pow (Omega, octave)
                                        pigment_pattern {
                                                function {FN (x,y,z)}
                                                scale pow (Lambda, -octave)
                                                color_map {
                                                        [0      srgb 1]
                                                        [1      srgb 0]
                                                }
                                        }
                                        poly_wave 1/Curve
                                ]
                                #local octave = octave+1;
                        #end
                }
        }
        poly_wave Curve
        color_map {
                [0      srgb 1]
                [1      srgb 0]
        }
}

#declare fac = -0.1;
#declare diff = 0;
#declare Color = <79,171,182>/255;

plane {
        y, -0.0001
        texture {
         pigment {
                 pigment_pattern {base_pat}
                 pigment_map {
                         [0              srgb 0]
                         [fac+0.36-diff  srgb 0]
                         [fac+0.36+diff  srgb Color+<0,40,-40>/255]
                         [fac+0.42-diff  srgb Color+<0,40,-40>/255]
                         [fac+0.42+diff  srgb 0]
                         [fac+0.56-diff  srgb 0]
                         [fac+0.56+diff  srgb Color+<0,-40,40>/255]
                         [fac+0.62-diff  srgb Color+<0,-40,40>/255]
                         [fac+0.62+diff  srgb 0]
                         [1              srgb 0]
                        }
                }
                normal {granite 0.02 scale 0.001}
                finish {brilliance 4 diffuse 0 ambient 0 emission 0.7}
        }
}

box {
        <-20,0.0001,-20>, <20,1,20>
        hollow
        material {
         texture {
                pigment {color srgbt 1}
         }
                interior {
                 media {
                  emission srgb 2
                                density {
                                 pigment_pattern {base_pat}
                                 density_map {
                                         [0              srgb 0]
                                         [fac+0.36-diff  srgb 0]
                                         [fac+0.36+diff  srgb
Color+<0,40,-40>/255]
                                         [fac+0.42-diff  srgb
Color+<0,40,-40>/255]
                                         [fac+0.42+diff  srgb 0]
                                         [fac+0.56-diff  srgb 0]
                                         [fac+0.56+diff  srgb
Color+<0,-40,40>/255]
                                         [fac+0.62-diff  srgb
Color+<0,-40,40>/255]
                                         [fac+0.62+diff  srgb 0]
                                         [1              srgb 0]
                                        }
                                }
                                method 2
                                intervals 1
                                samples 1600
                 }
                }
        }
}


Norbert


Post a reply to this message

From: Norbert Kern
Subject: Re: Small abstract
Date: 19 May 2019 06:00:00
Message: <web.5ce1287c5e75640e3c1c78400@news.povray.org>
and here the image...


Post a reply to this message


Attachments:
Download 'media_abstract.jpg' (741 KB)

Preview of image 'media_abstract.jpg'
media_abstract.jpg


 

From: Thomas de Groot
Subject: Re: Small abstract
Date: 19 May 2019 06:52:49
Message: <5ce13581$1@news.povray.org>
On 19-5-2019 11:58, Norbert Kern wrote:
> and here the image...
> 
> 

This is very beautiful indeed. Can be anything, from a cityscape to a 
microchip, and everything in between.

Thank you!

-- 
Thomas


Post a reply to this message

From: Ton
Subject: Re: Small abstract
Date: 19 May 2019 07:05:00
Message: <web.5ce138245e75640e939601860@news.povray.org>
> and here the image...

It sure is nice enough to show.
Well done.

Cheers
Ton.


Post a reply to this message

From: Thomas de Groot
Subject: Re: Small abstract
Date: 19 May 2019 07:10:30
Message: <5ce139a6$1@news.povray.org>
On 19-5-2019 11:58, Norbert Kern wrote:
> and here the image...
> 
> 

Question: shouldn't 'method 2' not be 'method 3' in the media?

-- 
Thomas


Post a reply to this message

From: Paolo Gibellini
Subject: Re: Small abstract
Date: 20 May 2019 05:00:56
Message: <5ce26cc8$1@news.povray.org>
Norbert Kern wrote on 19/05/2019 11:58:
> and here the image...
> 
> 
Ethereal and relaxing.
Paolo


Post a reply to this message

From: Norbert Kern
Subject: Re: Small abstract
Date: 20 May 2019 15:30:01
Message: <web.5ce300095e75640e3c1c78400@news.povray.org>
Thomas de Groot <tho### [at] degrootorg> wrote:
>
> This is very beautiful indeed. Can be anything, from a cityscape to a
> microchip, and everything in between.
>
> Thank you!
>
> --
> Thomas



I like the variability of the crackle pattern too - it can contain everything...

Norbert


Post a reply to this message

From: Norbert Kern
Subject: Re: Small abstract
Date: 20 May 2019 15:30:01
Message: <web.5ce300315e75640e3c1c78400@news.povray.org>
"Ton" <ton### [at] gmailcom> wrote:
> > and here the image...
>
> It sure is nice enough to show.
> Well done.
>
> Cheers
> Ton.

Thank you very much

Norbert


Post a reply to this message

From: Norbert Kern
Subject: Re: Small abstract
Date: 20 May 2019 15:35:01
Message: <web.5ce300ad5e75640e3c1c78400@news.povray.org>
Thomas de Groot <tho### [at] degrootorg> wrote:
> On 19-5-2019 11:58, Norbert Kern wrote:
>
> Question: shouldn't 'method 2' not be 'method 3' in the media?
>
> --
> Thomas


I tried method 3, but it was slower, not better - but I made the test in an
early stage...

Norbert


Post a reply to this message

From: Norbert Kern
Subject: Re: Small abstract
Date: 20 May 2019 15:35:01
Message: <web.5ce301005e75640e3c1c78400@news.povray.org>
Paolo Gibellini <p.g### [at] gmailcom> wrote:


> Ethereal and relaxing.
> Paolo


That's a very kind comment - thank's for that

Norbert


Post a reply to this message

Goto Latest 10 Messages Next 4 Messages >>>

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.