POV-Ray : Newsgroups : povray.binaries.images : Motion Blur Server Time: 23 Oct 2019 02:41:59 GMT
  Motion Blur (Message 1 to 3 of 3)  
From: Bald Eagle
Subject: Motion Blur
Date: 27 May 2018 13:05:01
Message: <web.5b0aac22260ed1c310874a080@news.povray.org>
Just a few VERY rough very quick illustrations.
Just enough to give the idea of where to go from here.

#version 3.7;
// Quick and dirty "motion blur"   Bald Eagle May 2018
global_settings {assumed_gamma 1.0}

#include "colors.inc"

sky_sphere {pigment {rgb <1, 1, 1>*0.2}}

camera {
   location <0, 0, -25>    // position & direction of view
  look_at  <0, 0, 0>
  right x*image_width/image_height           // horizontal size of view
  up y // vertical size of view
 }

light_source {<25, 25, -150> color White}

#declare Rad = 2.5;
#declare Ball = sphere {<0, 0, 0>, Rad}

#declare Num = 20;
#for (N, 0, Num)
 object {Ball translate <(-N*N/10)+10, 0, N/100> pigment {rgbt <1, 0, 0, N/Num>}
finish {specular 0.01} }
#end

#declare Motionline = cylinder {<-1, 0, 0>, <-0.1, 0, 0>, Rad/Num pigment
{gradient x color_map {[0 rgb <1, 0, 0>] [1 rgbt <1, 0, 0, 1>]}} }

#declare Y = 7;
object {Ball translate x*10 pigment {rgb <1, 0, 0>} translate -y*Y}

#for (YY, 0, Rad*2)
#declare ML = object {Motionline scale <-Num, 1, 1> translate -x*Num translate
x*10 translate -y*Y}
object {ML translate  y*YY/2*0.9}
object {ML translate -y*YY/2*0.9}
#end

#declare Medialine =
cylinder {<-1, 0, 0>, <-0.1, 0, 0>, Rad*0.99
 pigment {rgbt 1}
 hollow
 interior {
  media {
   emission <1, 0, 0>*0.5
   scattering {1, <1, 1, 1> extinction 2}
   density {gradient x
    color_map {
     [0.0 rgb 0.0]//border
     //[0.5 rgb 0.1]
     [1.0 rgb <1, 0, 0>]//center
    } // end color_map
   } // end of density
  } // end of media ----
 } // end of interior
}


object {Ball translate x*10 pigment {rgb <1, 0, 0>} translate y*Y}
object {Medialine scale <Num, 1, 1> translate x*12.5 translate y*Y}


Post a reply to this message


Attachments:
Download 'blurtest.png' (104 KB)

Preview of image 'blurtest.png'
blurtest.png


 

From: Paolo Gibellini
Subject: Re: Motion Blur
Date: 28 May 2018 08:09:46
Message: <5b0bb94a$1@news.povray.org>
Bald Eagle wrote on 27/05/2018 15:01:
> 
> Just a few VERY rough very quick illustrations.
> Just enough to give the idea of where to go from here.
> 

The third example is cool ;-)
Paolo


Post a reply to this message

From: Alain
Subject: Re: Motion Blur
Date: 28 May 2018 19:49:34
Message: <5b0c5d4e@news.povray.org>
Le 18-05-28 à 04:09, Paolo Gibellini a écrit :
> Bald Eagle wrote on 27/05/2018 15:01:
>>
>> Just a few VERY rough very quick illustrations.
>> Just enough to give the idea of where to go from here.
>>
> 
> The third example is cool ;-)
> Paolo

Yes, very cartoony. It must be noted that all 3 examples are not 
realistic at all.
With realistic motion blur, the image of the object is evenly spread 
over the full distance if the speed is constant.


Post a reply to this message

Copyright 2003-2008 Persistence of Vision Raytracer Pty. Ltd.