POV-Ray : Newsgroups : povray.binaries.images : Biohazard Symbol Server Time
28 Mar 2024 11:11:16 EDT (-0400)
  Biohazard Symbol (Message 1 to 8 of 8)  
From: Dave Blandston
Subject: Biohazard Symbol
Date: 3 May 2018 23:30:00
Message: <web.5aebd29271205310cfd0510a0@news.povray.org>
Hello,

This is a simple object but I'll share it in case anyone finds it useful or
interesting (as always).

Regards,
Dave Blandston

* * * * * * * * * *

#version 3.7;

global_settings {assumed_gamma 2.2}

camera {
   orthographic
   location <0, 0, -120>
   direction <0, 0, 1>
   look_at <0, 0, 0>
} //camera

#macro MakeBiohazardSymbol (Border)

   //Makes a biohazard symbol 1 unit thick (along the z axis) with the front at
z = -1 and the back at z = 0.

   #local R1 = 30;
   #local R2 = 21;
   #local R3 = 6;
   #local R4 = 27;
   #local R5 = 20;
   #local R6 = R2 - 2;

   #local Part0 = object {
      difference {
         cylinder {<0, 0, -1> <0, 0, 0>, R1 - Border}
         box {<-4 - Border, 8, -1.1> <4 + Border, 30.1, .1>}
      } //difference
      translate 22 * y
   } //object

   #local Part1 = object {
      intersection {
         difference {
            cylinder {<0, 0, -1> <0, 0, 0>, R4 - Border translate -22 * y}
            cylinder {<0, 0, -1.1> <0, 0, .1>, R5 + Border translate -22 * y}
         } //difference
         cylinder {<0, 0, -1.1> <0, 0, .1>, R6 - Border translate 8 * y}
      } //intersection
      translate 22 * y
   } //object

   #declare BiohazardSymbol = object {
      union {
         difference {
            union {
               object {Part0}
               object {Part0 rotate -120 * z}
               object {Part0 rotate 120 * z}
            } //union
            cylinder {<0, 0, -1.1> <0, 0, .1>, R2 + Border translate 30 * y}
            cylinder {<0, 0, -1.1> <0, 0, .1>, R2 + Border translate 30 * y
rotate -120 * z}
            cylinder {<0, 0, -1.1> <0, 0, .1>, R2 + Border translate 30 * y
rotate 120 * z}
            cylinder {<0, 0, -1.1> <0, 0, .1>, R3 + Border}
            box {<-1 - Border, 0, -1.1> <1 + Border, 10, .1>}
            box {<-1 - Border, 0, -1.1> <1 + Border, 10, .1> rotate -120 * z}
            box {<-1 - Border, 0, -1.1> <1 + Border, 10, .1> rotate 120 * z}
         } //difference
         object {Part1}
         object {Part1 rotate -120 * z}
         object {Part1 rotate 120 * z}
      } //union
   } //object

#end //#macro MakeBiohazardSymbol

MakeBiohazardSymbol (0)
object {BiohazardSymbol texture {pigment {color <240, 75, 0> / 255} finish
{emission 1}}}

MakeBiohazardSymbol (.5)
object {BiohazardSymbol texture {pigment {color <204, 255, 0> / 255} finish
{emission 1}} translate -.0001 * z}


Post a reply to this message


Attachments:
Download 'biohazardsymbol.png' (37 KB)

Preview of image 'biohazardsymbol.png'
biohazardsymbol.png


 

From: Dave Blandston
Subject: Re: Biohazard Symbol
Date: 4 May 2018 13:45:01
Message: <web.5aec9bb0977bfaaccfd0510a0@news.povray.org>
I neglected to include the value required to center the object vertically, which
is approximately -5.361.

Regards,
Dave Blandston


Post a reply to this message

From: Tor Olav Kristensen
Subject: Re: Biohazard Symbol
Date: 5 May 2018 18:15:00
Message: <web.5aee2c25977bfaac79917fa00@news.povray.org>
"Dave Blandston" <nomail@nomail> wrote:
> Hello,
>
> This is a simple object but I'll share it in case anyone finds it useful or
> interesting (as always).

The thin red border is a nice detail.

--
Tor Olav Kristensen
http://subcube.com


Post a reply to this message

From: Thomas de Groot
Subject: Re: Biohazard Symbol
Date: 6 May 2018 03:00:07
Message: <5aeea7f7$1@news.povray.org>
Would do well on the bio trash bin ;-)

Well done!

-- 
Thomas


Post a reply to this message

From: Dave Blandston
Subject: Re: Biohazard Symbol
Date: 6 May 2018 14:30:07
Message: <web.5aef4911977bfaaccfd0510a0@news.povray.org>
"Tor Olav Kristensen" <tor### [at] TOBEREMOVEDgmailcom> wrote:
> The thin red border is a nice detail.

Thanks! While I was researching the correct measurements for the symbol I
noticed there are lots of images of the symbol with a border but none of the
ones I saw were technically correct. I believe this one is correct. My actual
purpose for the border is to use a 3-D raised border to add an element of
interest and match other objects in a certain scene I'm working on. The
biohazard symbol looks awesome in my scene!

Regards,
Dave Blandston


Post a reply to this message

From: Dave Blandston
Subject: Re: Biohazard Symbol
Date: 6 May 2018 14:35:03
Message: <web.5aef4a0f977bfaaccfd0510a0@news.povray.org>
Thomas de Groot <tho### [at] degrootorg> wrote:
> Would do well on the bio trash bin ;-)
>
> Well done!

Thank you for the kind words! It's funny you would mention that because after I
learned how the symbol is actually supposed to look I noticed the one on my
wife's insulin needle container is incorrect. Amateurs...

Regards,
Dave Blandston


Post a reply to this message

From: Cousin Ricky
Subject: Re: Biohazard Symbol
Date: 6 May 2018 17:29:12
Message: <5aef73a8$1@news.povray.org>
On 2018-05-03 11:25 PM (-4), Dave Blandston wrote:
> This is a simple object but I'll share it in case anyone finds it useful or
> interesting (as always).

I made this 3-D interpretation about 9 years ago.  I can't remember 
where I got the dimensions (I most likely eyeballed them), so I can't 
vouch for their correctness.


Post a reply to this message


Attachments:
Download 'biohazard-au.jpg' (20 KB)

Preview of image 'biohazard-au.jpg'
biohazard-au.jpg


 

From: Dave Blandston
Subject: Re: Biohazard Symbol
Date: 7 May 2018 00:35:00
Message: <web.5aefd737977bfaaccfd0510a0@news.povray.org>
Cousin Ricky <ric### [at] yahoocom> wrote:
> I made this 3-D interpretation about 9 years ago.  I can't remember
> where I got the dimensions (I most likely eyeballed them), so I can't
> vouch for their correctness.

Very nice. In my opinion there's something especially interesting about the
biohazard symbol and portraying it in gold is very suitable; not to mention the
checkered plane!

Regards,
Dave Blandston


Post a reply to this message

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.