POV-Ray : Newsgroups : povray.binaries.images : Revisited and more... Server Time: 27 Jul 2017 22:49:07 GMT
  Revisited and more... (Message 1 to 7 of 7)  
From: Simon J  Cambridge
Subject: Revisited and more...
Date: 1 Jul 2017 13:00:01
Message: <web.59579c3eba06669ca5f566f0@news.povray.org>
Hi folks,

I have just revamped my website (all images made in POV-ray of course) and added
a new section for the large stuff.

Here is the link to the new section:

http://www.landofthefirst.com/prophecy/prophecy.html

I have reworked some of the previous images posted ('Rising from the ashes', 'a
touch of the beksinski's' and 'the reds are coming') and added ten more. What I
would really like to know is what you folks think?

Many thanks in advance,

Simon.

http://www.landofthefirst.com/


Post a reply to this message

From: Simon J  Cambridge
Subject: Re: Revisited and more...
Date: 4 Jul 2017 10:10:01
Message: <web.595b6882379f403df017eb620@news.povray.org>
"Simon J. Cambridge" <nomail@nomail> wrote:
> Hi folks,
>
> I have just revamped my website (all images made in POV-ray of course) and added
> a new section for the large stuff.
>
> Here is the link to the new section:
>
> http://www.landofthefirst.com/prophecy/prophecy.html
>
> I have reworked some of the previous images posted ('Rising from the ashes', 'a
> touch of the beksinski's' and 'the reds are coming') and added ten more. What I
> would really like to know is what you folks think?
>
> Many thanks in advance,
>
> Simon.
>
> http://www.landofthefirst.com/

Oops, I meant to post an image as well!


Post a reply to this message


Attachments:
Download 'dance.jpg' (646 KB)

Preview of image 'dance.jpg'
dance.jpg


 

From: LanuHum
Subject: Re: Revisited and more...
Date: 4 Jul 2017 18:20:06
Message: <web.595bdc37379f403d7a3e03fe0@news.povray.org>
"Simon J. Cambridge" <nomail@nomail> wrote:

>
> What I would really like to know is what you folks think?
>

I liked this
http://www.landofthefirst.com/ell/lore/images/water.jpg


Post a reply to this message

From: LanuHum
Subject: Re: Revisited and more...
Date: 4 Jul 2017 18:35:00
Message: <web.595bdf25379f403d7a3e03fe0@news.povray.org>
"LanuHum" <Lan### [at] yandexru> wrote:
> "Simon J. Cambridge" <nomail@nomail> wrote:
>
> >
> > What I would really like to know is what you folks think?
> >
>
> I liked this
> http://www.landofthefirst.com/ell/lore/images/water.jpg

Very beautiful
http://www.landofthefirst.com/prophecy/images/theeye.jpg
function ridged and warp spherical???


Post a reply to this message

From: Simon J  Cambridge
Subject: Re: Revisited and more...
Date: 5 Jul 2017 11:25:01
Message: <web.595cca7e379f403daa3fb0cc0@news.povray.org>
"LanuHum" <Lan### [at] yandexru> wrote:
> "LanuHum" <Lan### [at] yandexru> wrote:
> > "Simon J. Cambridge" <nomail@nomail> wrote:
> >
> > >
> > > What I would really like to know is what you folks think?
> > >
> >
> > I liked this
> > http://www.landofthefirst.com/ell/lore/images/water.jpg
>
> Very beautiful
> http://www.landofthefirst.com/prophecy/images/theeye.jpg
> function ridged and warp spherical???

Thank you, LanuHum.

'Water' took a fair amount of time to get right (or to get it to a point where I
liked it). It's interesting that this scene uses radiosity, (gamma 2.2 as well,
I think) and that a number of others I have done don't. I am still investigating
the why's and the wherefore's (as to when to use and when not to).

'TheEye' might surprise you. It's an inverted 'witch_of_agnesi' modified with
granite. Here is the code: (alas the eye itself is a mesh! I used aoi for the
skin and radial for the iris.)

########

#version 3.7;

#include "functions.inc"

#declare AreaOK=0;

#declare sun=2;

global_settings { assumed_gamma 1.0 }

#declare cpos=<0, 100, 0>;

camera {
    location  cpos
    right     x*image_width/image_height
    look_at   <0, 0, 0>
    angle     40
}

light_source {
    cpos
    color rgb 0.1
    shadowless
}

sky_sphere { pigment { rgb 0 } }

#declare Pig01=
pigment {
    granite
    turbulence 0.14
    color_map {
        [0.0 color rgb 0.0]
        [0.5 color rgb 0.2]
        [1.0 color rgb 0.5]
    }
    scale <1, 0.1, 1>
}

#declare Pig02=
pigment {
    granite
    turbulence 0.21
    color_map {
        [0.0 color rgb 0.0]
        [0.5 color rgb 0.2]
        [1.0 color rgb 0.5]
    }
    scale <1, 0.1, 1>
}

#declare fnPig01 = function { pigment { Pig01 translate 1000 } }
#declare fnPig02 = function { pigment { Pig02 translate 2000 } }

#declare fct=0.3;

#declare F1 = function {-f_witch_of_agnesi(x,y,z, 0.5, 0.09) -
(fnPig01(x,0,z).gray*fct*fnPig02(x,0,z).gray)}

#declare T_Upper=
texture {
    pigment
    {
        rgb <0.98, 0.26, 0.16>
    }
    finish {
        diffuse 0.7
        specular 0.1
    }
}

#declare T_Lower=
texture {
    pigment
    {
        rgb 0
    }
    finish {
        ambient 0
        diffuse 0
    }
}

#declare Terrain=
isosurface {
    function {
        F1(x, y, z)
    }

    open

    max_gradient 7

    contained_by{box{<-20, 0, -20>, <20, 2, 20>}}

    texture {
        gradient y
        scale 2
        texture_map
        {
            [0.00 T_Upper]
            [0.45 T_Lower]
        }
    }

    scale <500, 1000, 500>*1.4

    rotate <180, 0, 0>
}

light_group
{
    object { Terrain }

    light_source {
        <0, 200000, 0>
        color rgb <0.9, 0.8, 0.7>*sun
        #if (AreaOK=1)
            area_light 4000*x 4000*y 4, 4
            jitter
            orient
            circular
        #end
    }

    global_lights on
}

#######

As you can see I stripped the code back to the bare minmum. (And the eye itself
has its own light group.)

Cheers,

Simon.


Post a reply to this message

From: Kenneth
Subject: Re: Revisited and more...
Date: 14 Jul 2017 22:55:01
Message: <web.59694b22379f403d883fb31c0@news.povray.org>
"Simon J. Cambridge" <nomail@nomail> wrote:

>
> Oops, I meant to post an image as well!

I like the look of the grass, and especially the trees and their textures. Well
done.


Post a reply to this message

From: Simon J  Cambridge
Subject: Re: Revisited and more...
Date: 15 Jul 2017 10:30:01
Message: <web.5969ed92379f403d34009c350@news.povray.org>
"Kenneth" <kdw### [at] gmailcom> wrote:
> "Simon J. Cambridge" <nomail@nomail> wrote:
>
> >
> > Oops, I meant to post an image as well!
>
> I like the look of the grass, and especially the trees and their textures. Well
> done.

Thank you, Kenneth.

The grass is from a modified macro from Gilles Tran (makeblade) and the trees
were created in Arbaro after rather a lot of fiddling.

Cheers,

Simon.


Post a reply to this message

Copyright 2003-2008 Persistence of Vision Raytracer Pty. Ltd.