"omniverse" <omn### [at] charternet> wrote:

> Your rendering got my attention right away, and then I couldn't think what it
> reminded me of until now. Zardoz, the floating stone head from the 1970's movie
> of same name.

The rendering is very good, I agree - I really like the subject matter and the
composition of the image - it grabs the attention right away.

I had that stone head bouncing around in my mind for - probably decades - and
couldn't figure out what it was that I saw it in.  Then one day I was over a
friend's house, and he had Zardoz playing on his TV!

"What is _this_?!" I asked.
"Zardoz." - with a look and tone suggesting "Everybody knows Zardoz.  Of course
it's Zardoz - what else would it be?"

There's a few more movies or tv shows like that, that I've since tracked down
and identified, but there are still a few more kicking around, that I can't
recall where I saw them or when.

Might be a good topic for pr-off-topic.  "Identify this fuzzily recalled and
ill-described memory fragment of a thing I saw when I was a kid."
That will surely be a future raytracing competition topic...  :D

Post a reply to this message

clipka <ano### [at] anonymousorg> wrote:
> Am 13.05.2017 um 22:43 schrieb Simon J. Cambridge:
>
> > What do you folks reckon?
>
> For a scene that doesn't use radiosity I think it looks surprisingly good.

Here is the basis for the landscape:

------------------------------------

#version 3.7;

#include "functions.inc"

#declare MultSun=1.5;

global_settings {
    assumed_gamma 1.0
}

#declare CamPos=<0, 50, 300>;

camera {
    location  CamPos
    right     x*image_width/image_height
    look_at   <0, 80, 0>
    angle     40
}

light_source {
    CamPos
    color rgb 0.1
    shadowless
}

light_source {
    <-100000, 100000, 200000>
    rgb <0.9, 0.8, 0.7>*MultSun
}

#declare C_SkyPurple =rgb <171,113,161>/255;
#declare C_SkyBlue   =rgb <161,184,213>/255;

#declare P_Sky=pigment{
    gradient z
    pigment_map{
        [0 pigment_pattern{function{max(0,min(1,y))}} color_map{[0
C_SkyBlue][0.5 C_SkyPurple]}]
        [1 pigment_pattern{function{max(0,min(1,y))}} color_map{[0
C_SkyBlue*0.1][0.5 C_SkyPurple*0.1]}]
    }
    scale <1,1,2>
    translate -z
}

sky_sphere { pigment { P_Sky } }

fog{fog_type 2 fog_alt 250 fog_offset 0 rgb <0.6, 0.4, 0.2> distance 20000}

#declare F1 = function{ f_ridged_mf(x, y, z, 0.1, 3.1, 8 ,0.7, 0.8, 2) }

isosurface {
    function {
        y - F1(x, y, z)*0.1
    }

    max_gradient 1.3

    contained_by { box { <-200, -10, -200>, <200, 1, 200> } }

    texture {
        pigment
        {
            function { F1(x, y, z) }
            color_map
            {
                [0.0 rgb <0.97, 0.65, 0.47>*0.5]
                [0.5 rgb <0.98, 0.76, 0.56>*0.5]
                [1.0 rgb <0.99, 0.85, 0.61>*0.5]
            }
        }
        finish {
            diffuse 0.7
            specular 0.1
        }
    }

    scale 500
}

------------------------------------

As I said, I went back to basics to see what I could come up with. Getting
bogged down in artefact removal, mesh misbehaviour and upping the values so that
you get really slow render times was beginning to hurl the hairs from my head.

As to the image, I tried adding texture to the cloth, and the only way I like
the finished result is if the texture is all but unnoticeable. So I am going to
keep it 'prawn cocktail' (See comedy show 'Goodness Gracious Me' for an
explanation of 'prawn cocktail')

Cheers,

Simon.

http://www.landofthefirst.com/

Post a reply to this message