POV-Ray : Newsgroups : povray.binaries.images : find the Santa Claus Server Time: 28 Apr 2017 12:02:34 GMT
  find the Santa Claus (Message 1 to 8 of 8)  
From: omniverse
Subject: find the Santa Claus
Date: 23 Dec 2016 23:45:01
Message: <web.585db643351d89f49c5d6c810@news.povray.org>
Made a Merry Christmas picture and by pure coincidence ol' St. Nick seems to
have been reflected in some of the red ornaments. Not done on purpose. Just
snow-reflected light.

For the curious, adding scene here:

/* treeless ornaments around "warm" glow */

//cmd:+am2 +a0.2 +j1

#version 3.7;

global_settings{assumed_gamma 1.0
 radiosity{count 123 normal on media on}
}

light_source{<100,100,-100>,<0.2,0.4,0.6>*0.7
 area_light <5,0,0>,<0,0,5>,4,4
 area_illumination
 media_interaction off
 media_attenuation off}

light_source{<0,7.5,0>,<0.9,0.5,0.3>*0.9
 area_light <0.5,0,0>,<0,0,0.5>,6,6 circular orient
 area_illumination
 fade_distance 9 fade_power 2
 media_interaction on
 media_attenuation off}

camera{location <0,2.4,-24>
 up y right image_width/image_height*x
 look_at <0,5,0>}

// starry sky
#declare StarY = function {
 pigment { brick rgb <1,1,0> rgb 0 mortar 0.001 }
}

sphere{0,360 // stars
 hollow on
texture {
  pigment {
    function { StarY(x,y,z).red}
    turbulence 3 scale 33
    }
    finish { diffuse 0 ambient 1 emission 1 }
}
texture{pigment{rgbf<1,1,0,1>}}
 radiosity {importance 0.1}
}

sphere{0,1 // sky color
 hollow on
 pigment{
  function {abs(y)}
  color_map{
   [0 rgbt <0.6,0.1,0.2,0.3>]
   [0.1 rgbt <0.3,0.1,0.5,0.7>]
   [0.3 rgbt <0.2,0.4,0.9,0.8>]
   [1 rgbt <0.1,0.3,0.9,1>]
  }
 }
 finish{diffuse 0 ambient 1 emission 1}
 scale 333
 radiosity {importance 0.5}
}

// localized air haze
media{method 3 samples 200 scattering{1,0.03}
density{spherical density_map{[0.93 rgb 0][1 rgb 0.67]}}
scale 334}

// ornaments
#for(It,0,36,1)

sphere{<3-It/12,1+It/3,0>, 1-It/40
 rotate y*(360*It/6)
 material{
  texture{
 pigment{rgb <0,1,0>}
 finish{fresnel 1.33
  ambient 0
  brilliance 3
  diffuse albedo 0.5
  specular albedo 0.9 roughness 0.01
  reflection{0,1 fresnel on falloff 0.9 exponent 2}
 }
  }
  interior{ior 1.5}
 }
 radiosity {importance 1}
}

sphere{<3-It/12,1+It/3,0>, 1-It/40
 rotate y*(145+360*It/6)
 material{
  texture{
 pigment{rgb <1,0,0>}
 finish{fresnel 1.2
  ambient 0
  brilliance 4
  diffuse albedo 0.5
  specular albedo 0.9 roughness 0.01
  reflection{0,1 fresnel on falloff 0.9 exponent 3}
 }
  }
  interior{ior 1.5}
 }
 radiosity {importance 1}
}

#end // ornaments

// ground snow
height_field {
  function 2000,2000 {
    pattern {
      bozo scale 0.1
      }
    }
  translate -0.5
  scale <67,3,67>
  texture{
  pigment{rgb 1}
  normal{bumps 0.1 scale 0.3}
  finish{ambient 0.15 diffuse albedo 0.9
   specular albedo 3 roughness 0.01
   crand 0.1
  }
  }
  texture{
  pigment{bumps color_map{[0 rgb 1][0.2 rgbt 1]} scale 0.02}
  //normal{bumps 0.1 scale 0.3}
  finish{ambient 0.15 emission 0.05 diffuse albedo 9
   specular albedo 9 roughness 0.01
   //crand 0.1
  }
  }
  interior{ior 1.34}
  translate y*0.25
 radiosity {importance 0.75}
}


Post a reply to this message


Attachments:
Download 'ws no tree snow warm glow.png' (619 KB)

Preview of image 'ws no tree snow warm glow.png'
ws no tree snow warm glow.png


 

From: omniverse
Subject: Re: find the Santa Claus
Date: 24 Dec 2016 07:45:01
Message: <web.585e26f8a436ddeb9c5d6c810@news.povray.org>
I posted that scene file in haste and neglected to warn about it using
unofficial 3.7 feature fresnel finish. And to say it's a slow render. Maybe this
would be better:

/* treeless ornaments around "warm" glow */

//cmd:+am2 +a0.2 +j1

#version 3.7; // 3.7 or use 3.71 with alpha or UberPOV

#local Radiosity=on;

#local Media=on;

#local Subsurface=off;

global_settings{assumed_gamma 1.0
 max_trace_level 8
 #if(Radiosity=on)
 radiosity{count 123
  adc_bailout 2/1
  normal on media on
 } #end
 #if(Subsurface=on)
 subsurface{samples 60,40 radiosity on}
 #end
 //mm_per_unit 50
}

// moonlight
light_source{<100,100,-100>,<0.2,0.4,0.6>*0.7
 area_light <5,0,0>,<0,0,5>,4,4
 area_illumination
 media_interaction off
 media_attenuation off}

// warm glow light
light_source{<0,7.5,0>,<0.9,0.5,0.3>*0.9
 area_light <0.33,0,0>,<0,0,0.33>,8,8 circular orient
 area_illumination
 fade_distance 9 fade_power 2
 media_interaction on
 media_attenuation on}

camera{location <0,2.4,-24>
 up y right image_width/image_height*x
 look_at <0,5,0>}

// starry sky
#declare StarY = function {
 pigment { brick rgb <1,1,0> rgb 0 mortar 0.001 }
}

sphere{0,333.33 // stars
 hollow on
texture {
  pigment {
    function { StarY(x,y,z).red}
    turbulence 3 scale 33 // bricks into stars
    }
    finish { diffuse 0 ambient 1 emission 1 }
}
texture{pigment{rgbf<1,1,0,1>}}
 radiosity {importance 0.1}
}

sphere{0,1 // sky color
 hollow on
 pigment{
  function {abs(y)}
  color_map{
   [0 rgbt <0.6,0.1,0.2,0.3>]
   [0.1 rgbt <0.3,0.2,0.5,0.5>]
   [0.3 rgbt <0.2,0.4,0.9,0.8>]
   [1 rgbt <0.1,0.3,0.9,1>]
  }
 }
 finish{diffuse 0 ambient 1 emission 1}
 scale 333
 radiosity {importance 0.8}
}

// localized air haze
#if(Media=on)
media{method 3 samples 50,50
 jitter 0.1
 scattering{1,0.03}
density{spherical density_map{[0.93 rgb 0][1 rgb 0.67]}}
scale 334}
#end


// ornaments
#for(It,0,36,1)

sphere{<3-It/12,1+It/3,0>, 1-It/40
 rotate y*(360*It/6)
 material{
  texture{
 pigment{rgb <0,1,0>}
 finish{
  #if(version>3.7)fresnel 1.33 #end
  ambient 0 emission 0.05
  brilliance 3
  diffuse albedo 0.5
  specular albedo 0.9 roughness 0.01
  reflection{0,1 fresnel on falloff 0.9 exponent 2}
 }
  }
  interior{ior 1.5}
 }
 radiosity {importance 1}
}

sphere{<3-It/12,1+It/3,0>, 1-It/40
 rotate y*(145+360*It/6)
 material{
  texture{
 pigment{rgb <1,0,0>}
 finish{
  #if(version>3.7)fresnel 1.2 #end
  ambient 0 emission 0.05
  brilliance 4
  diffuse albedo 0.5
  specular albedo 0.9 roughness 0.01
  reflection{0,1 fresnel on falloff 0.9 exponent 3}
 }
  }
  interior{ior 1.5}
 }
 radiosity {importance 1}
}

#end // ornaments


// ground snow
height_field {
  function 500,500 {
    pattern {
      bozo scale 0.1
      }
  }
  translate -0.5
  scale <67,3,67>
  texture{
  pigment{rgb 1}
  normal{bumps 0.1 scale 0.3}
  finish{ambient 0.15
   brilliance 0.8
   diffuse albedo 0.9
   specular albedo 3 roughness 0.01
   crand 0.1
   subsurface{translucency <0.8,0.9,1>}
  }
  }
  texture{
  pigment{bumps color_map{[0 rgb 1][0.2 rgbt 1]} scale 0.02}
  //normal{bumps 0.1 scale 0.3}
  finish{ambient 0.15 emission 0.05
   brilliance 0.4
   diffuse albedo 9
   specular albedo 9 roughness 0.01
   //crand 0.1
  }
  }
  interior{ior 1.34}
  translate y*0.25
 radiosity {importance 0.8}
}


Post a reply to this message

From: Dave Blandston
Subject: Re: find the Santa Claus
Date: 24 Dec 2016 23:00:00
Message: <web.585efddfa436ddeb6ae7df010@news.povray.org>
"omniverse" <omn### [at] charternet> wrote:
> Made a Merry Christmas picture and by pure coincidence ol' St. Nick seems to
> have been reflected in some of the red ornaments. Not done on purpose. Just
> snow-reflected light.

Hey, that's pretty cool! Merry Christmas!

Regards,
Dave Swaim


Post a reply to this message

From: omniverse
Subject: Re: find the Santa Claus
Date: 25 Dec 2016 07:40:01
Message: <web.585f7704a436ddeb9c5d6c810@news.povray.org>
"Dave Blandston" <nomail@nomail> wrote:
> "omniverse" <omn### [at] charternet> wrote:
> > Made a Merry Christmas picture and by pure coincidence ol' St. Nick seems to
> > have been reflected in some of the red ornaments. Not done on purpose. Just
> > snow-reflected light.
>
> Hey, that's pretty cool! Merry Christmas!
>
> Regards,
> Dave Swaim

Thanks Dave! I can't seem to post the scene file without leaving an error or
problem but I will try a third time anyway:

/* treeless ornaments around "warm" glow */

//cmd:+am2 +a0.2 +j1

#version 3.71; // 3.7 or use 3.71 with alpha or UberPOV

#local Radiosity=on;

#local Media=on;

#local Subsurface=on;

global_settings{assumed_gamma 1.0
 max_trace_level 8
 #if(Radiosity=on)
 radiosity{count 123
  adc_bailout 1/32 // fix for blank/black areas,
                // seen with 1/128, for example.
                // This was 2/1 before and meant to be 1/2, oops!
                // Something about HF or isosurface when used
                // with radiosity?
  normal on media on
 } #end
 #if(Subsurface=on)
 subsurface{samples 60,40 radiosity on}
 #end
 //mm_per_unit 50
}

// moonlight
light_source{<100,100,-100>,<0.2,0.4,0.6>*0.7
 area_light <5,0,0>,<0,0,5>,4,4
 area_illumination
 media_interaction off
 media_attenuation off}

// warm glow light
light_source{<0,7.5,0>,<0.9,0.5,0.3>*0.9
 area_light <0.33,0,0>,<0,0,0.33>,8,8 circular orient
 area_illumination
 fade_distance 9 fade_power 2
 media_interaction on
 media_attenuation on}

camera{location <0,2.4,-24>
 up y right image_width/image_height*x
 look_at <0,5,0>}

// starry sky
#declare StarY = function {
 pigment { brick rgb <1,1,0> rgb 0 mortar 0.001 }
}

sphere{0,333.33 // stars
 hollow on
texture {
  pigment {
    function { StarY(x,y,z).red}
    turbulence 3 scale 33 // bricks into stars
    }
    finish { diffuse 0 ambient 1 emission 1 }
}
texture{pigment{rgbf<1,1,0,1>}}
 radiosity {importance 0.1}
}

sphere{0,1 // sky color
 hollow on
 pigment{
  function {abs(y)}
  color_map{
   [0 rgbt <0.6,0.1,0.2,0.3>]
   [0.1 rgbt <0.3,0.2,0.5,0.5>]
   [0.3 rgbt <0.2,0.4,0.9,0.8>]
   [1 rgbt <0.1,0.3,0.9,1>]
  }
 }
 finish{diffuse 0 ambient 1 emission 1}
 scale 333
 radiosity {importance 0.8}
}

// localized air haze
#if(Media=on)
media{method 3 samples 50,50 // increase to reduce banding
 // jitter 0.1  // too messy?
 scattering{1,0.03}
density{spherical density_map{[0.93 rgb 0][1 rgb 0.67]}}
scale 334}
#end


// ornaments
#for(It,0,36,1)

sphere{<3-It/12,1+It/3,0>, 1-It/40
 rotate y*(360*It/6)
 material{
  texture{
 pigment{rgb <0,1,0>}
 finish{
  #if(version>3.7)fresnel 1.33 #end
  ambient 0 emission 0.05
  brilliance 3
  diffuse albedo 0.5
  specular albedo 0.9 roughness 0.01
  reflection{0,1 fresnel on falloff 0.9 exponent 2}
 }
  }
  interior{ior 1.5}
 }
 radiosity {importance 1}
}

sphere{<3-It/12,1+It/3,0>, 1-It/40
 rotate y*(145+360*It/6)
 material{
  texture{
 pigment{rgb <1,0,0>}
 finish{
  #if(version>3.7)fresnel 1.2 #end
  ambient 0 emission 0.05
  brilliance 4
  diffuse albedo 0.5
  specular albedo 0.9 roughness 0.01
  reflection{0,1 fresnel on falloff 0.9 exponent 3}
 }
  }
  interior{ior 1.5}
 }
 radiosity {importance 1}
}

#end // ornaments


// ground snow
intersection { // add thickness for subsurface scattering
 box{<-0.01,0.01,-0.01>,<0.99,1.01,0.99>}
height_field {
  function 333,333 {
    pattern {
      bozo scale 0.1
      }
  }
  smooth
} // HF
  translate -0.5
  scale <67,3,67>

  texture{
  pigment{rgb 1}
  normal{bumps 0.1 scale 0.3}
  finish{ambient 0.15
   brilliance 0.8
   diffuse albedo 0.9
   specular albedo 3 roughness 0.01
   crand 0.1
   subsurface{translucency <0.8,0.9,1>}
  }
  }
  texture{
  pigment{bumps color_map{[0 rgb 1][0.2 rgbt 1]} scale 0.02}
  //normal{bumps 0.1 scale 0.3}
  finish{ambient 0.15 emission 0.05
   brilliance 0.4
   diffuse albedo 9
   specular albedo 9 roughness 0.01
   //crand 0.1
  }
  }
  interior{ior 1.34}
  translate y*0.25
 radiosity {importance 0.8}
} // intersection


Post a reply to this message

From: Stephen
Subject: Re: find the Santa Claus
Date: 25 Dec 2016 09:26:43
Message: <585f90d3@news.povray.org>
On 12/25/2016 7:36 AM, omniverse wrote:
> I will try a third time anyway:


I don't think that is Santa but the Grinch. :-)

It is good, though.

Happy Christmas to one and all.

-- 

Regards
     Stephen


Post a reply to this message


Attachments:
Download 'grinch.png' (323 KB)

Preview of image 'grinch.png'
grinch.png


 

From: Alain
Subject: Re: find the Santa Claus
Date: 25 Dec 2016 22:39:32
Message: <58604aa4@news.povray.org>
Le 16-12-23 à 18:41, omniverse a écrit :
> Made a Merry Christmas picture and by pure coincidence ol' St. Nick seems to
> have been reflected in some of the red ornaments. Not done on purpose. Just
> snow-reflected light.
>
You can also see Frosty.


Post a reply to this message

From: omniverse
Subject: Re: find the Santa Claus
Date: 26 Dec 2016 01:45:01
Message: <web.586075f1a436ddeb9c5d6c810@news.povray.org>
Stephen <mca### [at] aolcom> wrote:
>
> I don't think that is Santa but the Grinch. :-)
>
> It is good, though.

Thanks Stephen. I should have thought of Grinch too, yeah.

Wow, that lit up air sure is trouble to render. As is the snow if subsurface
scattering is used.

And always my main complaint, it's slooooow to render! ;)  Although radiosity
alone is fast for this.

Yep, maybe frosty was getting in there too. All like anti-vampires, can't see
them just their reflections.

Bob


Post a reply to this message

From: gibe
Subject: Re: find the Santa Claus
Date: 30 Dec 2016 16:15:01
Message: <web.58668778a436ddebd00459b0@news.povray.org>
"omniverse" <omn### [at] charternet> wrote:
> Made a Merry Christmas picture and by pure coincidence ol' St. Nick seems to
> have been reflected in some of the red ornaments. Not done on purpose. Just
> snow-reflected light.
>
> For the curious, adding scene here:
>
> /* treeless ornaments around "warm" glow */
>
>

A nice scene, Merry Xmas!
Paolo


Post a reply to this message

Copyright 2003-2008 Persistence of Vision Raytracer Pty. Ltd.