POV-Ray : Newsgroups : povray.binaries.images : regarding wax experiment Server Time
28 Mar 2024 11:32:44 EDT (-0400)
  regarding wax experiment (Message 1 to 7 of 7)  
From: omniverse
Subject: regarding wax experiment
Date: 14 Dec 2016 22:40:01
Message: <web.5852107c74049ba59c5d6c810@news.povray.org>
Branching off of the message by Clipka in the animations group at:

http://news.povray.org/58516d06%241%40news.povray.org

As was suggested in the thread there, to only set mm_per_unit and leave that
alone, I was only able to get a similar appearance from subsurface scattering by
using a translucency of <10,10,10>. This is without knowing of a typical range
for it, and which I can only consider a rather large value. Mainly because of a
tendency to go transparent at such high numbers.

Wanted to demonstrate here how ior affects SSLT, somewhat masking my
insufficient result while attempting to duplicate the real world experiment
(shown at link within initial message above).

Thanks for any further input or observations about using SSLT. Everything I've
done with it is trial and error, and although I do try to set mm_per_unit to
each scene scale I often fail unless tweaking that to be a less or more.

Bob


Post a reply to this message


Attachments:
Download 'wax_sslt-ior.jpg' (45 KB)

Preview of image 'wax_sslt-ior.jpg'
wax_sslt-ior.jpg


 

From: omniverse
Subject: Re: regarding wax experiment
Date: 15 Dec 2016 01:25:00
Message: <web.585236dae6b304bb9c5d6c810@news.povray.org>
Thought I would try scattering media in an attempt to find how it differs from
subsurface scattering.

Found that all (using method 3 defaults) media scattering types, except 5 with
some change to eccentricity, do not cause the kind of light/dark (or top/bottom,
lit/unlit) differences if all else is the same.

This image shows the scattering type 5 with eccentricity 0, upper block of wax,
and eccentricity 0.2 for the lower.

Might be common knowledge but I wasn't sure yet about potential characteristics
of media to mimic SSLT, without special adjustments or trickery like changing
parameters of separate instances. Maybe I'm learning something. :)

Bob


Post a reply to this message


Attachments:
Download 'wax_media08.jpg' (17 KB)

Preview of image 'wax_media08.jpg'
wax_media08.jpg


 

From: INVALID ADDRESS
Subject: Re: regarding wax experiment
Date: 17 Dec 2016 14:25:08
Message: <349534550.503627044.576020.gdsHYPHENentropyAThotmaolDOTcom@news.povray.org>
The lower set of wax, were it slightly blue, would most closely resemble
silica aerogel to my eye. 

Very nice either way, what were the textures used for these if you don't
mind my asking?

Ian


Post a reply to this message

From: omniverse
Subject: Re: regarding wax experiment
Date: 17 Dec 2016 16:50:00
Message: <web.5855b2fee6b304bbad52daeb0@news.povray.org>
[GDS|Entropy] <gdsHYPHENentropyAThotmaolDOTcom> wrote:
> The lower set of wax, were it slightly blue, would most closely resemble
> silica aerogel to my eye.
>
> Very nice either way, what were the textures used for these if you don't
> mind my asking?

Can't answer till late tonight I'm away from home.  The media is thick anyway,
but what makes them look opaque mostly seems to be the refraction.


Post a reply to this message

From: omniverse
Subject: Re: regarding wax experiment
Date: 18 Dec 2016 15:55:00
Message: <web.5856f789e6b304bb9c5d6c810@news.povray.org>
"omniverse" <omn### [at] charternet> wrote:
> [GDS|Entropy] <gdsHYPHENentropyAThotmaolDOTcom> wrote:
> > The lower set of wax, were it slightly blue, would most closely resemble
> > silica aerogel to my eye.
> >
> > Very nice either way, what were the textures used for these if you don't
> > mind my asking?
>
> Can't answer till late tonight I'm away from home.  The media is thick anyway,
> but what makes them look opaque mostly seems to be the refraction.

Sorry, slipped my mind. I had tried all the other media scattering types, some
multiplied by 3 not just 2, but deleted as I changed them. Here it is:

/* testing for correct wax SSLT properties */
//cmd:-kfi1 -kff50 -sf8 -ef8 +am2 +a0.2 +fj

#version 3.7;

#declare SSLT=no;

#declare MM=25.4;//*clock;//4;  /* mm_per_unit */
#declare ST=10;//8+12*clock;//1.5; /* translucency */

global_settings{assumed_gamma 1.0
 ambient_light 1
 radiosity {
  #if(SSLT=yes)
  subsurface on
  #end
  media on
 }
 #if(SSLT=yes)
 subsurface{
  samples 500,50
 }
 #end
 mm_per_unit MM}

light_source{-z*99,1 rotate <60,-15,0>}
/*
light_source{-z*9,<0.75,0.9,1>
 spotlight point_at 0 radius 6 falloff 10
 rotate 90*y}
*/
camera{location -z*9 look_at -y/2 angle 50
 rotate <30,30,0>}

sphere{0,1 hollow pigment{
 uv_mapping checker rgb 0 rgb 1 scale 0.05}
 //function{abs(y)} // room
 //color_map{[0 rgb 0][1 rgb 1]} scale 2 translate -y}
 scale 111}

box{-1,1 hollow scale <2,0.5,1> translate y*0.511
 // upper wax block
 pigment{rgbf 0.99} finish{brilliance 2
 diffuse albedo 0.8,0.2
 specular 0.1 roughness 0.1
 //subsurface{translucency ST}
 }
 interior{ior 1.445
  media{emission 0 absorption 0
   scattering{5,<1,1,1>*2 eccentricity 0}
   density {rgb<1,1,1>*2}
  }
 }
 }

box{-1,1 hollow off scale <1.95,0.01,0.95>
 // foil sheet between wax blocks
 pigment{rgb 0.1} finish{diffuse 0.1
 specular 0.9 roughness 0.01
 reflection{0.5}
 }}

box{-1,1 hollow scale <2,0.5,1> translate -y*0.511
 // lower wax block
 pigment{rgbf 0.99} finish{brilliance 2
 diffuse albedo 0.8,0.2
 specular 0.1 roughness 0.1
 //subsurface{translucency ST}
 }
 interior{ior 1.445
  media{emission 0 absorption 0
   scattering{5,<1,1,1>*2 eccentricity 0.2}
   density {rgb<1,1,1>*2}
  }
 }
 }

text{ttf "times", concat(str(MM,-2,1)," mm per unit"),0.1,0
 pigment {rgb <0.4,0.8,1>}
 scale <0.75,0.75,0.75>
 rotate <30,30,0>
 translate <-2.25,-2.5,-1>
}

#if(SSLT=yes)
text{ttf "times", concat(str(ST,-2,1)," translucency"),0.1,0
 no_shadow
 pigment {rgb <1,0.4,0.2>}
 scale <0.5,0.5,0.5>
 rotate <30,30,0>
 translate <-3,2.75,-1>
}
#else
text{ttf "times","scattering media",0.1,0
 no_shadow
 pigment {rgb <1,0.4,0.2>}
 scale <0.5,0.5,0.5>
 rotate <30,30,0>
 translate <-3,2.75,-1>
}
#end


Post a reply to this message

From: INVALID ADDRESS
Subject: Re: regarding wax experiment
Date: 28 Dec 2016 19:57:40
Message: <621835683.504665342.218214.gdsHYPHENentropyAThotmaolDOTcom@news.povray.org>
Very cool, thanks! It is always good to have cool effects like these out
there for everyone to learn from.

Ian

omniverse <omn### [at] charternet> wrote:
> "omniverse" <omn### [at] charternet> wrote:
>> [GDS|Entropy] <gdsHYPHENentropyAThotmaolDOTcom> wrote:
>>> The lower set of wax, were it slightly blue, would most closely resemble
>>> silica aerogel to my eye.
>>> 
>>> Very nice either way, what were the textures used for these if you don't
>>> mind my asking?
>> 
>> Can't answer till late tonight I'm away from home.  The media is thick anyway,
>> but what makes them look opaque mostly seems to be the refraction.
> 
> Sorry, slipped my mind. I had tried all the other media scattering types, some
> multiplied by 3 not just 2, but deleted as I changed them. Here it is:
> 
> /* testing for correct wax SSLT properties */
> //cmd:-kfi1 -kff50 -sf8 -ef8 +am2 +a0.2 +fj
> 
> #version 3.7;
> 
> #declare SSLT=no;
> 
> #declare MM=25.4;//*clock;//4;  /* mm_per_unit */
> #declare ST=10;//8+12*clock;//1.5; /* translucency */
> 
> global_settings{assumed_gamma 1.0
>  ambient_light 1
>  radiosity {
>   #if(SSLT=yes)
>   subsurface on
>   #end
>   media on
>  }
>  #if(SSLT=yes)
>  subsurface{
>   samples 500,50
>  }
>  #end
>  mm_per_unit MM}
> 
> light_source{-z*99,1 rotate <60,-15,0>}
> /*
> light_source{-z*9,<0.75,0.9,1>
>  spotlight point_at 0 radius 6 falloff 10
>  rotate 90*y}
> */
> camera{location -z*9 look_at -y/2 angle 50
>  rotate <30,30,0>}
> 
> sphere{0,1 hollow pigment{
>  uv_mapping checker rgb 0 rgb 1 scale 0.05}
>  //function{abs(y)} // room
>  //color_map{[0 rgb 0][1 rgb 1]} scale 2 translate -y}
>  scale 111}
> 
> box{-1,1 hollow scale <2,0.5,1> translate y*0.511
>  // upper wax block
>  pigment{rgbf 0.99} finish{brilliance 2
>  diffuse albedo 0.8,0.2
>  specular 0.1 roughness 0.1
>  //subsurface{translucency ST}
>  }
>  interior{ior 1.445
>   media{emission 0 absorption 0
>    scattering{5,<1,1,1>*2 eccentricity 0}
>    density {rgb<1,1,1>*2}
>   }
>  }
>  }
> 
> box{-1,1 hollow off scale <1.95,0.01,0.95>
>  // foil sheet between wax blocks
>  pigment{rgb 0.1} finish{diffuse 0.1
>  specular 0.9 roughness 0.01
>  reflection{0.5}
>  }}
> 
> box{-1,1 hollow scale <2,0.5,1> translate -y*0.511
>  // lower wax block
>  pigment{rgbf 0.99} finish{brilliance 2
>  diffuse albedo 0.8,0.2
>  specular 0.1 roughness 0.1
>  //subsurface{translucency ST}
>  }
>  interior{ior 1.445
>   media{emission 0 absorption 0
>    scattering{5,<1,1,1>*2 eccentricity 0.2}
>    density {rgb<1,1,1>*2}
>   }
>  }
>  }
> 
> text{ttf "times", concat(str(MM,-2,1)," mm per unit"),0.1,0
>  pigment {rgb <0.4,0.8,1>}
>  scale <0.75,0.75,0.75>
>  rotate <30,30,0>
>  translate <-2.25,-2.5,-1>
> }
> 
> #if(SSLT=yes)
> text{ttf "times", concat(str(ST,-2,1)," translucency"),0.1,0
>  no_shadow
>  pigment {rgb <1,0.4,0.2>}
>  scale <0.5,0.5,0.5>
>  rotate <30,30,0>
>  translate <-3,2.75,-1>
> }
> #else
> text{ttf "times","scattering media",0.1,0
>  no_shadow
>  pigment {rgb <1,0.4,0.2>}
>  scale <0.5,0.5,0.5>
>  rotate <30,30,0>
>  translate <-3,2.75,-1>
> }
> #end
> 
> 
> 
>


Post a reply to this message

From: omniverse
Subject: Re: regarding wax experiment
Date: 28 Dec 2016 21:15:01
Message: <web.58647084e6b304bb9c5d6c810@news.povray.org>
[GDS|Entropy] <gdsHYPHENentropyAThotmaolDOTcom> wrote:
> Very cool, thanks! It is always good to have cool effects like these out
> there for everyone to learn from.

YW! This kind of thing is what I always have trouble with, finding what the best
possible variation of something is.

Might be something to take note of for future example scene files, having
certain features shown in a range of settings instead of best/good way. I
realize the documentation attempts to tell this about everything, but only what
might be best and doesn't show how things can differ.

Don't know if there's a limit to this possibility, because even with the
radiosity examples there can be so much tweaking involved from scene to scene.

Bob


Post a reply to this message

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.