The documentation reads, "The sky sphere can contain several pigment 
layers..." But if I use more than one transparent pigment on a 
sky_sphere, the transparent areas show black instead of the first 
pigment layer.

In all three images, a blue gradient is used as the first pigment layer. 
  In cases 1 and 2, one partially transparent pigment is layered over 
the blue gradient, and the result is as I expect.  In the third case, 2 
partially transparent pigments are layered over the blue gradient, and 
the blue does not show at all.

The render stats indicate that only one trace level is used.

As a sanity check, I applied the same pigments to a sphere at the lower 
left.  In all cases, the sphere renders as I expect.

Am I missing something, or is this a bug?

----------[BEGIN CODE]----------
// +KFF3
#version 3.6;

#include "colors.inc"
#include "skies.inc"

global_settings { assumed_gamma 1 max_trace_level 5 }

camera
{ ultra_wide_angle
   location <0, 0.2, 0>
   look_at <0, 5.2, 5>
   angle 135
}

plane { y, 0 pigment { rgb 1 } }

#declare P1 = pigment
{ gradient y color_map
   { [0 rgb <0.5, 0.75, 1.0>]
     [1 rgb <0.1, 0.15, 0.2>]
   }
}

#declare P2 = pigment
{ wood color_map
   { [0.0 rgb <1, 0.8, 0.6> transmit 0]
     [0.7 rgb <1, 0.8, 0.6> transmit 1]
   }
   ramp_wave
}

sky_sphere
{ pigment { P1 }
   #switch (frame_number)
     #case (1)
       pigment { P2 }
       #break
     #case (2)
       pigment { P_Cloud1 scale 0.1 }
       #break
     #case (3)
       pigment { P2 }
       pigment { P_Cloud1 scale 0.1 }
       #break
   #end
}

#default { finish { ambient 1 diffuse 0 } }

sphere
{ 0, 1
   texture { pigment { P1 } }
   #switch (frame_number)
     #case (1)
       texture { pigment { P2 } }
       #break
     #case (2)
       texture { pigment { P_Cloud1 scale 0.1 } }
       #break
     #case (3)
       texture { pigment { P2 } }
       texture { pigment { P_Cloud1 scale 0.1 } }
       #break
   #end
   translate 2.5 * z
   rotate -35 * y
}
-----------[END CODE]-----------

The results are the same in POV-Ray versions 3.6.1, 3.7, and 
3.7.1-alpha.8150025.

Post a reply to this message

Attachments:
Download 'sky_layers1.jpg' (9 KB) Download 'sky_layers2.jpg' (20 KB) Download 'sky_layers3.jpg' (25 KB)

Preview of image 'sky_layers1.jpg'

Preview of image 'sky_layers2.jpg'

Preview of image 'sky_layers3.jpg'

Cousin Ricky <ric### [at] yahoocom> wrote:
> The documentation reads, "The sky sphere can contain several pigment
> layers..." But if I use more than one transparent pigment on a
> sky_sphere, the transparent areas show black instead of the first
> pigment layer.
>
> In all three images, a blue gradient is used as the first pigment layer.
>   In cases 1 and 2, one partially transparent pigment is layered over
> the blue gradient, and the result is as I expect.  In the third case, 2
> partially transparent pigments are layered over the blue gradient, and
> the blue does not show at all.
>
> The render stats indicate that only one trace level is used.
>
> As a sanity check, I applied the same pigments to a sphere at the lower
> left.  In all cases, the sphere renders as I expect.
>
> Am I missing something, or is this a bug?

> The results are the same in POV-Ray versions 3.6.1, 3.7, and
> 3.7.1-alpha.8150025.




I can confirm this for 3.6.2, but not for 3.7.0msvc10.win64.

Here it renders correct down to max_trace_level 1.


Norbert

Post a reply to this message

Attachments:
Download 'limit to sky_sphere layers3.jpg' (97 KB)

Preview of image 'limit to sky_sphere layers3.jpg'

"Norbert Kern" <nor### [at] t-onlinede> wrote:

> I can confirm this for 3.6.2, but not for 3.7.0msvc10.win64.


I've to add the additional point, that it only renders correct with 3.7, when
the version statement is changed to "#version 3.7;", otherwise it's like you
described...


Norbert

Post a reply to this message

"Norbert Kern" <nor### [at] t-onlinede> wrote:
> "Norbert Kern" <nor### [at] t-onlinede> wrote:
>
> > I can confirm this for 3.6.2, but not for 3.7.0msvc10.win64.
>
>
> I've to add the additional point, that it only renders correct with 3.7, when
> the version statement is changed to "#version 3.7;", otherwise it's like you
> described...

Ah, so it appears to have been a bug in 3.6, which was corrected in 3.7, but
retained in compatibility mode.

Post a reply to this message

Am 09.01.2016 um 23:01 schrieb Cousin Ricky:
> "Norbert Kern" <nor### [at] t-onlinede> wrote:
>> "Norbert Kern" <nor### [at] t-onlinede> wrote:
>>
>>> I can confirm this for 3.6.2, but not for 3.7.0msvc10.win64.
>>
>>
>> I've to add the additional point, that it only renders correct with 3.7, when
>> the version statement is changed to "#version 3.7;", otherwise it's like you
>> described...
> 
> Ah, so it appears to have been a bug in 3.6, which was corrected in 3.7, but
> retained in compatibility mode.

Exactly.

I wasn't aware of this effect in particular, but POV-Ray 3.6 did have
some peculiar quirks when it came to sky spheres. This was changed in
POV-Ray 3.7, with the aim that

- sky sphere behaviour is consistent with that of a textured sphere with
an emission-only finish, and

- background behaviour is consistent with that of a sky sphere with
uniform pigment.

Post a reply to this message