 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Hi!
Now Blender2Povray exporter in working order.
On our site users started showing interest to my work and to try to create
scenes.
The rust became the first problem.
I looked at structure of rust in textures.inc and used it for a bearing holder.
Look very bad.
Help us to create, please, a realistic rust on the bearing
Files of a scene are here::
http://news.povray.org/povray.binaries.scene-files/message/%3Cweb.52f5e09fa98583267a3e03fe0%40news.povray.org%3E/#%3Cwe
b.52f5e09fa98583267a3e03fe0%40news.povray.org%3E
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
How about this? Different variations possible (see below). Textures
courtesy of Xplo Eristotle.
//start code
// Metal textures by Xplo Eristotle
// RUST
#declare XE_rust =
texture {
pigment
{
granite
color_map
{
[ 0.0 rgb <0.809995, 0.299123, 0.113405>*.8 ]
[ 0.4 rgb <0.209995, 0.096941, 0.031510>*1.2 ]
[ 0.6 rgb <0.209995, 0.096941, 0.031510>*1.2 ]
[ 1.0 rgb <0.569986, 0.052720, 0.005707>*.9 ]
}
scale .5
turbulence 1
}
normal { wrinkles }
}
// IRON
#declare XE_iron =
texture {
pigment { color rgb <0.25, 0.25, 0.25> }
normal { granite .3 scale .2 }
finish { roughness .01 specular .5 reflection .05 diffuse .8 }
}
// IRON WITH RUST FLAKES (TdG)
#declare XE_iron_2 =
texture {
pigment {
marble
pigment_map {
[0.00 color rgb <0.25, 0.25, 0.25>]
[0.20 color rgb <0.30, 0.30, 0.30>]
[0.45 color rgb <0.809995, 0.299123, 0.113405>*0.8]
[0.50 color rgb <0.25, 0.25, 0.25>]
[0.65 color rgb <0.23, 0.23, 0.23>]
[0.90 color rgb <0.24, 0.24, 0.24>]
[1.00 color rgb <0.25, 0.25, 0.25>]
}
scale 0.2
warp {turbulence 0.5}
}
normal {granite 0.3 scale 0.2}
finish {
roughness 0.01
specular 0.5
reflection 0.05
diffuse 0.8
}
}
// RUSTY IRON
#declare XE_rusty_iron =
texture {
bozo
texture_map
{
[ 0.0 XE_rust ]
[ 1.0 XE_iron ]
}
turbulence 1
omega .3
lambda 4
warp { turbulence 1 }
}
// STEEL
#declare XE_steel =
texture {
pigment { color rgb <0.5, 0.5, 0.5> }
normal { wrinkles .02 scale .1 }
finish
{
roughness .001
specular 1
diffuse .2
reflection .5
}
}
// RUSTY STEEL
#declare XE_rusty_steel =
texture {
bozo
texture_map
{
[ 0.0 XE_rust ]
[ 0.2 XE_rust ]
[ 0.5 XE_iron ]
[ 0.6 XE_steel ]
[ 1.0 XE_steel ]
}
turbulence 1
omega .6
lambda 4
warp { turbulence 1 }
}
//end code
Thomas
Post a reply to this message
Attachments:
Download 'rusty_bearing.png' (237 KB)
Preview of image 'rusty_bearing.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Thomas de Groot <tho### [at] degroot org> wrote:
> How about this? Different variations possible (see below). Textures
> courtesy of Xplo Eristotle.
>
Thomas, thanks!
I will try to use your example for settings in a blender. :)
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 8-2-2014 12:00, LanuHum wrote:
> Thomas de Groot <tho### [at] degrootorg> wrote:
>> How about this? Different variations possible (see below). Textures
>> courtesy of Xplo Eristotle.
>>
>
> Thomas, thanks!
> I will try to use your example for settings in a blender. :)
>
>
>
You are welcome indeed. As far as my texture collection goes, Xplo's
rust textures are the best I have seen here.
Thomas
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Some thoughts about different settings.
ini file: Display_Gamma=1
Using version 3.7, you may want to take advantage of the sRGB colour
space. Personally, I have my Display_Gamma set permanently to: sRGB.
Pigments:
You may want to play with srgb too inside the pigments. Change all 'rgb'
to 'srgb' and see the difference. If you want exactly the same output
you may need to tweak the rgb values, making them lighter.
Textures:
After some more testing and for a better result, I advice to change the
XE_rusty_steel texture to:
#declare XE_rusty_steel =
texture {
bozo
texture_map
{
[ 0.0 XE_rust ]
[ 0.2 XE_rust ]
[ 0.5 XE_steel ]
[ 1.0 XE_steel ]
}
turbulence 1
omega .6
lambda 4
warp { turbulence 1 }
}
Using sRGB colours without changing their values, you get the following
image. Left = XE_rusty_iron; Right = XE_rusty_steel.
Thomas
Post a reply to this message
Attachments:
Download 'rusty_bearing.png' (553 KB)
Preview of image 'rusty_bearing.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Thomas de Groot <tho### [at] degrootorg> wrote:
> How about this? Different variations possible (see below). Textures
> courtesy of Xplo Eristotle.
>
> //start code
> // Metal textures by Xplo Eristotle
>
> #declare XE_iron_2 =
> texture {
> pigment {
> marble
> pigment_map {
> [0.00 color rgb <0.25, 0.25, 0.25>]
> [0.20 color rgb <0.30, 0.30, 0.30>]
> [0.45 color rgb <0.809995, 0.299123, 0.113405>*0.8]
> [0.50 color rgb <0.25, 0.25, 0.25>]
> [0.65 color rgb <0.23, 0.23, 0.23>]
> [0.90 color rgb <0.24, 0.24, 0.24>]
> [1.00 color rgb <0.25, 0.25, 0.25>]
> }
> scale 0.2
> warp {turbulence 0.5}
> }
> normal {granite 0.3 scale 0.2}
> finish {
> roughness 0.01
> specular 0.5
> reflection 0.05
> diffuse 0.8
> }
> }
>
> #declare XE_rusty_steel =
> texture {
> bozo
> texture_map
> {
> [ 0.0 XE_rust ]
> [ 0.2 XE_rust ]
> [ 0.5 XE_iron ]
> [ 0.6 XE_steel ]
> [ 1.0 XE_steel ]
> }
> turbulence 1
> omega .6
> lambda 4
> warp { turbulence 1 }
> }
> //end code
>
> Thomas
XE_iron_2 declare, but not used.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 8-2-2014 14:39, LanuHum wrote:
> Thomas de Groot <tho### [at] degrootorg> wrote:
>> How about this? Different variations possible (see below). Textures
>> courtesy of Xplo Eristotle.
>>
>> //start code
>> // Metal textures by Xplo Eristotle
>>
>
>> #declare XE_iron_2 =
>> texture {
>> pigment {
>> marble
>> pigment_map {
>> [0.00 color rgb <0.25, 0.25, 0.25>]
>> [0.20 color rgb <0.30, 0.30, 0.30>]
>> [0.45 color rgb <0.809995, 0.299123, 0.113405>*0.8]
>> [0.50 color rgb <0.25, 0.25, 0.25>]
>> [0.65 color rgb <0.23, 0.23, 0.23>]
>> [0.90 color rgb <0.24, 0.24, 0.24>]
>> [1.00 color rgb <0.25, 0.25, 0.25>]
>> }
>> scale 0.2
>> warp {turbulence 0.5}
>> }
>> normal {granite 0.3 scale 0.2}
>> finish {
>> roughness 0.01
>> specular 0.5
>> reflection 0.05
>> diffuse 0.8
>> }
>> }
>>
>
>> #declare XE_rusty_steel =
>> texture {
>> bozo
>> texture_map
>> {
>> [ 0.0 XE_rust ]
>> [ 0.2 XE_rust ]
>> [ 0.5 XE_iron ]
>> [ 0.6 XE_steel ]
>> [ 1.0 XE_steel ]
>> }
>> turbulence 1
>> omega .6
>> lambda 4
>> warp { turbulence 1 }
>> }
>> //end code
>>
>> Thomas
>
> XE_iron_2 declare, but not used.
>
Yes, you can choose your own combinations ;-)
Thomas
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Thomas de Groot <tho### [at] degrootorg> wrote:
> Yes, you can choose your own combinations ;-)
>
> Thomas
I already understood it.
But, it would be desirable to see still options of other users.
Me completely rusty surface interests also.
And, for some reason it seems to me that normal works at the bearing badly.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 8-2-2014 18:02, LanuHum wrote:
> But, it would be desirable to see still options of other users.
In p.b.scene-files I have given a collection of rusty metals by several
authors.
> Me completely rusty surface interests also.
> And, for some reason it seems to me that normal works at the bearing badly.
In the image: left = Ke_old_pitted_iron from the collection. normals are
looking 'normal' to my eyes ;-)
Thomas
Post a reply to this message
Attachments:
Download 'rusty_bearing.png' (702 KB)
Preview of image 'rusty_bearing.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
And as I am never entirely satisfied, here is a version with a HDRI
environment.
Left = XE_rusty_steel; Right = Ke_old_pitted_iron
Thomas
Post a reply to this message
Attachments:
Download 'rusty_bearing.png' (953 KB)
Preview of image 'rusty_bearing.png'
|
|
| |
| |
|
|
|
|
| |
