The attached image is a high-quality render of a simple scene containing an
opaque red sphere and a glass sphere on a white plane with a point light in
between. I've set this up for benchmarking various settings, and because I've
been explaining some of the more advanced pov-ray features to a friends who is
new to it.

I noticed that in this particular scene, the caustics created by the photons
when I have photon mapping and dispersion turned on create these concentric
rings...this only seems to happen when the light source is parallel with the
center of the glass sphere...if I move it up a little I get a focuses circle
caustic.

I'm guessing this this is due to the photons reflecting around the inside of the
sphere, but am wondering if the effect is realistic or if it should be
considered an artifact? I actually looked for photos with a similar effect, but
haven't yet found one.

Post a reply to this message

Attachments:
Download 'quality_test_6_6m64s.png' (131 KB)

Preview of image 'quality_test_6_6m64s.png'

Am 05.12.2013 17:18, schrieb jceddy:

> I noticed that in this particular scene, the caustics created by the photons
> when I have photon mapping and dispersion turned on create these concentric
> rings...this only seems to happen when the light source is parallel with the
> center of the glass sphere...if I move it up a little I get a focuses circle
> caustic.
>
> I'm guessing this this is due to the photons reflecting around the inside of the
> sphere, but am wondering if the effect is realistic or if it should be
> considered an artifact? I actually looked for photos with a similar effect, but
> haven't yet found one.

This is definitely an artifact.

Post a reply to this message

> This is definitely an artifact.

Am I seeing the spiral pattern that the photons are shot in?  I thought that
might be the case, but dismissed the idea...

Post a reply to this message

>
>> This is definitely an artifact.
>
> Am I seeing the spiral pattern that the photons are shot in?  I thought that
> might be the case, but dismissed the idea...
>
>
It's indeed the spiral pattern in whitch the photons are shot that you 
see here.

Solutions:
Reduce spacing (suggestion: actual spacing/4 or 5) OR increase count 
(suggestion: actual count *16 to *25).

Add some jitter to your photons to hide the regularity of the spiral.


Alain

Post a reply to this message

> It's indeed the spiral pattern in whitch the photons are shot that you
> see here.
>
> Solutions:
> Reduce spacing (suggestion: actual spacing/4 or 5) OR increase count
> (suggestion: actual count *16 to *25).
>
> Add some jitter to your photons to hide the regularity of the spiral.
>
>
> Alain

Thanks for the advice.

I had to increase jitter to 1.0 to get rid of any noticeable spiral pattern in
the caustic.

I messed around with increasing the photon count/decreasing spacing, but so far
haven't found a happy medium where the artifacts are minimized and the photons
actually take little enough memory for the scene to render (on the machine I'm
rendering this on, the program basically dies somewhere between 3-4 GB memory
used...it's an 8 GB machine).

Not complaining, I know photons ain't easy!
Just wondering if anyone knows of any other optimizations that I might not know
of that would reduce memory usage?

In the meantime I'm fiddling around with the scene itself to come up with
something where the artifacts aren't so noticeable.

Post a reply to this message

jceddy wrote:

> In the meantime I'm fiddling around with the scene itself to come up with
> something where the artifacts aren't so noticeable.

I think the problem is that the light source is so close to the photon
target, causing the spiral to be shot over huge angular extent.

I also wonder about the photon spacing itself ... I would have expected
the spacing between "spiral arms" and photons on an arm to be roughly 
balanced. But maybe your setup strongly magnifies them radially?

Post a reply to this message

On 05/12/13 21:16, jceddy wrote:
> 
> Thanks for the advice.
> 
> I had to increase jitter to 1.0 to get rid of any noticeable spiral pattern in
> the caustic.
> 
> I messed around with increasing the photon count/decreasing spacing, but so far
> haven't found a happy medium where the artifacts are minimized and the photons
> actually take little enough memory for the scene to render (on the machine I'm
> rendering this on, the program basically dies somewhere between 3-4 GB memory
> used...it's an 8 GB machine).
> 
> Not complaining, I know photons ain't easy!
> Just wondering if anyone knows of any other optimizations that I might not know
> of that would reduce memory usage?
> 
> In the meantime I'm fiddling around with the scene itself to come up with
> something where the artifacts aren't so noticeable.
> 

Could you post your source code so we can all play with the scales and
settings?

John
-- 
Protect the Earth
It was not given to you by your parents
You hold it in trust for your children

Post a reply to this message

> Could you post your source code so we can all play with the scales and
> settings?

Sure:


#version 3.7;
global_settings{ assumed_gamma 1.0 }

#declare Photons = off;
#declare Dispersion = off;
#declare Radiosity = off;

global_settings {
  max_trace_level 50

  #if(Photons)
    photons {
      //count 4000000
      spacing 0.002
      autostop 0
      jitter 1.0
    }
  #end

  #if(Radiosity)
    radiosity {
      pretrace_start 0.128          // start pretrace at this size
      pretrace_end   0.002          // end pretrace at this size
      count 1600                    // higher -> higher quality (1..1600) [35]
      nearest_count 20              // higher -> higher quality (1..10) [5]
      error_bound 0.5               // higher -> smoother, less accurate [1.8]
      recursion_limit 5             // how much interreflections are calculated
(1..5+) [3]
      low_error_factor 1.0          // reduce error_bound during last pretrace
step
      gray_threshold 0.0            // increase for weakening colors (0..1) [0]
      minimum_reuse 0.005           // reuse of old radiosity samples [0.015]
      maximum_reuse 0.1
      brightness 1                  // brightness of radiosity effects (0..1)
[1]
      adc_bailout 0.005
    }
  #end
}

camera {
  location <0, 5, -10.001>
  look_at <0, 1, 0>
  up y
}

plane {
  y, 0

  pigment { color rgb 1 }
  finish { ambient 0 diffuse 1 }
}

sphere {
  <-2, 1, 0>, 1

  pigment { color rgb <1, 0, 0> }
  finish { ambient 0 diffuse 1 }
}

sphere {
  <2, 1, 0>, 1

  pigment { color rgbf <1, 1, 1, 0.9> }
  finish { ambient 0 diffuse 0.9 reflection 0.1 }
  interior {
    ior 1.3

    #if(Dispersion)
      dispersion 1.007
      dispersion_samples 28
    #end

    #if(!Photons)
      caustics 0.5
    #end
  }

  #if(Photons)
    photons {
      target
      reflection on
      refraction on
    }
  #end
}

light_source {
  <0, 1, 0>
  color rgb 1
}

Post a reply to this message

Was playing around with something else and now am thinking that I can reduce the
dispersion samples to help with this.

Post a reply to this message

Yeah, I brought dispersion samples down from 28 to 7 and was able to cut the
photon spacing in half, casting 4 times as many photons, and the image looks a
lot better.

The caustic in the shadow is still a little rough, but it just makes it look
like the glass has minor imperfections, which isn't such a big deal.

Post a reply to this message