|
 |
Stephen <mca### [at] aol com> wrote:
> I do like Barbara Hepworth's work. Have you been to her house and studio
> in St Ives?
>
> I think that we need a different view to show it off better.
>
> --
> Regards
> Stephen
Hi Stephen,
I have been to her house/studio once but about 15 years ago so it is not fresh
in my mind. My daughter did a piece on her for her art homework which reminded
me of her works and as I was looking for something to add to a garden scene I
thought this would work well.
I agree, her work is very interesting and having modelled one I am tempted to do
some more of these.
A different view attached plus the source for the scene below (it was a really
easy piece to model as it is just a blob.
Sean
// PoVRay 3.7 Scene File " ... .pov"
// author: ...
// date: ...
//--------------------------------------------------------------------------
#version 3.7;
#declare useRad=1;
#declare radQuality=10;
#declare useFocalBlur=10;
global_settings {
#if(useRad)
ambient_light 0
radiosity {
#if(useRad = 2)
pretrace_start 0.08 // start pretrace at this size
pretrace_end 0.001 // end pretrace at this size
#end
#if(useRad = 1)
pretrace_start 1 // start pretrace at this size
pretrace_end 1 // end pretrace at this size
always_sample off //
#end
count 20*radQuality 50*radQuality // higher -> higher
quality (1..1600) [35]
nearest_count 10+(radQuality) //10+(radQuality/2) // higher ->
higher quality (1..10) [5]
low_error_factor .5 // reduce error_bound during last pretrace
step
gray_threshold 0.0 // increase for weakening colors (0..1) [0]
minimum_reuse 0.015 // reuse of old radiosity samples [0.015]
adc_bailout 0.01/2
error_bound 1.5-(radQuality/10) // higher -> smoother, less
accurate [1.8]
recursion_limit 2 // how much interreflections are calculated
(1..5+) [3]
brightness 1 // brightness of radiosity effects (0..1) [1]
normal on // take surface normals into account [off]
}
#end
}
sky_sphere {
pigment{
image_map{ hdr "building_probe.hdr"
map_type 1 interpolate 2}
}// end pigment
emission rgb 1
rotate <0,-20,0> //
}
//--------------------------------------------------------------------------
#include "colors.inc"
#include "textures.inc"
#include "glass.inc"
#include "metals.inc"
#include "golds.inc"
#include "stones.inc"
#include "woods.inc"
#include "shapes.inc"
#include "shapes2.inc"
#include "functions.inc"
#include "math.inc"
#include "transforms.inc"
box { <-500, 0, -500> <500, 1, 500> material { texture { pigment { rgb 0.9 }
finish { specular 0 roughness 0.01 brilliance 1 diffuse albedo 0.5 reflection
{ 0.1 0.5 fresnel on } conserve_energy } } interior { ior 1.6 } } }
camera {
location <0 , 5.6 ,-6.5>
// location <0.65 , 12.5 ,-14.0>
look_at <0, 2 0>
right x*image_width/image_height
#if(useFocalBlur)
aperture 0.01 // [0...N] larger is narrower depth of field (blurrier)
blur_samples useFocalBlur*10 // number of rays per pixel for sampling
focal_point <0,2.1,0.4> // point that is in focus <X,Y,Z>
confidence 0.9+(0.009*useFocalBlur) //0.8999+(useFocalBlur/1000) //
[0...<1] when to move on while sampling (smaller is less accurate)
variance 1/(20000*useFocalBlur) // [0...1] how precise to calculate
(smaller is more accurate)
#end
}
#declare sculptBaseTex1 = texture{ pigment{ color rgb<0.02,0.02,0.025>}
finish { specular albedo 0.1 roughness 0.1 diffuse albedo 0.5
brilliance 2 metallic 0.25 reflection { 0.008, 0.02 fresnel on } conserve_energy
}//reflection{ 0.3 metallic 0.5} }
normal { wrinkles 0.1 scale 0.001 }
}
texture{ pigment{ wrinkles turbulence 1 omega 0.9 lambda 4 scale 0.2
colour_map {
[ 0.35 rgbt <0.01, 0.19, 0.16, 1> ]
[ 1.0 rgbt <0.01, 0.19, 0.16, 0.8> ]
}
}
}
#declare sculptBaseTex2 = texture{ pigment{ granite colour_map { [ 0.0
rgb<0.01,0.01,0.015> ] [ 0.5 rgb <0.02, 0.02, 0.03> ][ 1 rgb <0.6, 0.55, 0.5> ]
}
scale .1
turbulence 0.15
omega 0.65
lambda 2.3 }
finish { specular albedo 0.1 roughness 0.05 diffuse albedo 0.5
brilliance 2 reflection { 0.01, 0.04 fresnel on } conserve_energy
}//reflection{ 0.3 metallic 0.5} }
// normal { wrinkles 0.1 scale 0.001 }
}
#declare sculptDryTex =
texture{ pigment{ color rgb<0.025,0.021,0.016>}
finish { specular albedo 0.1 roughness 0.9 diffuse albedo 0.6
brilliance 3 metallic 0.5 reflection { 0.008, 0.02 fresnel on } conserve_energy
}//reflection{ 0.3 metallic 0.5} }
normal { wrinkles 0.1 scale 0.001 }
}
texture{ pigment{ wrinkles turbulence 1 omega 0.9 lambda 4 scale 0.2
colour_map {
[ 0.35 rgbt <0.01, 0.19, 0.16, 1> ]
[ 1.0 rgbt <0.01, 0.19, 0.16, 0.5> ]
}
}
}
#declare sculptWetTex =
texture{ pigment{ color rgb<0.025,0.021,0.016>*0.2}
finish { specular 0.2 roughness 0.05 diffuse 0.05 brilliance 10
metallic 1 reflection { 0.01, 0.025 fresnel on } conserve_energy }//reflection{
0.3 metallic 0.5} }
normal { wrinkles 0.1 scale 0.001 }
}
texture{ pigment{ wrinkles turbulence 1 omega 0.9 lambda 4 scale 0.2
colour_map {
[ 0.35 rgbt <0.01, 0.19, 0.16, 5>*0.2 ]
[ 1.0 rgbt <0.01, 0.19, 0.16, 2.5>*0.2 ]
}
}
}
//#declare sculptDryTex = texture { pigment { rgb <1, 0, 0> } }
//#declare sculptWetTex = texture { pigment { rgb <0, 0, 1> } }
#declare st2 = texture {
spherical poly_wave 4
texture_map {
[ 0.0 sculptDryTex scale <0.166, 0.5, 0.5> ]
[ 0.025 sculptDryTex scale <0.166, 0.5, 0.5> ]
[ 0.1 sculptWetTex scale <0.166, 0.5, 0.5> ]
}
scale <6, 2, 2>
translate <0, -1.2, 0>
}
#declare sculptMat = material {
texture { st2 }
interior { ior 1.6 }
}
#declare sculpture = blob { // ---------------------------------- blob object
threshold 0.5
sphere { <0, 0, 0>, 2, 2.25 scale <1.25, 1, 1> translate <-2.5, 0,0 > }
sphere { <0, 0, 0>, 2, 2.2 scale <1.25, 1, 1> translate <-2, 0,0 > }
sphere { <0, 0, 0>, 2.03, 2.15 scale <1.25, 1, 1> translate <-1.5, 0,0 > }
sphere { <0, 0, 0>, 2.06, 2.1 scale <1.25, 1, 1> translate <-1, 0,0 > }
sphere { <0, 0, 0>, 2.09, 2.05 scale <1.25, 1, 1> translate <-0.5, 0,0 > }
sphere { <0, 0, 0>, 2.12, 2 scale <1.25, 1, 1> translate <0, 0,0 > }
sphere { <0, 0, 0>, 2.09, 2.05 scale <1.25, 1, 1> translate <0.5, 0, 0> }
sphere { <0, 0, 0>, 2.06, 2.1 scale <1.25, 1, 1> translate <1, 0, 0> }
sphere { <0, 0, 0>, 2.03, 2.15 scale <1.25, 1, 1> translate <1.5, 0, 0> }
sphere { <0, 0, 0>, 2, 2.2 scale <1.25, 1, 1> translate <2, 0, 0> }
sphere { <0, 0, 0>, 2, 2.25 scale <1.25, 1, 1> translate <2.5, 0, 0> }
#declare cutterZ=-0.4;
#declare cutterY=0.2;
#declare cutterRad=1.4;
#declare cutterStrength=-5;
sphere { <0, 0, 0>, cutterRad*1.05, cutterStrength scale <1.25, 1, 1>
translate <0, cutterY, cutterZ> }
sphere { <0, 0, 0>, cutterRad*1.05, cutterStrength scale <1.25, 1, 1>
translate <0.25, cutterY, cutterZ> }
sphere { <0, 0, 0>, cutterRad*1.05, cutterStrength scale <1.25, 1, 1>
translate <0.5, cutterY, cutterZ> }
sphere { <0, 0, 0>, cutterRad*1.05, cutterStrength scale <1.25, 1, 1>
translate <0.75, cutterY, cutterZ> }
sphere { <0, 0, 0>, cutterRad*1.04, cutterStrength scale <1.25, 1, 1>
translate <1, cutterY, cutterZ> }
sphere { <0, 0, 0>, cutterRad*1.03, cutterStrength scale <1.25, 1, 1>
translate <1.25, cutterY, cutterZ> }
sphere { <0, 0, 0>, cutterRad*1.02, cutterStrength scale <1.25, 1, 1>
translate <1.5, cutterY, cutterZ> }
sphere { <0, 0, 0>, cutterRad*1.01, cutterStrength scale <1.25, 1, 1>
translate <1.75, cutterY, cutterZ> }
sphere { <0, 0, 0>, cutterRad*0.99, cutterStrength scale <1.25, 1, 1>
translate <2, cutterY, cutterZ> }
sphere { <0, 0, 0>, cutterRad*1.05, cutterStrength scale <1.25, 1, 1>
translate <-0.25, cutterY, cutterZ> }
sphere { <0, 0, 0>, cutterRad*1.05, cutterStrength scale <1.25, 1, 1>
translate <-0.5, cutterY, cutterZ> }
sphere { <0, 0, 0>, cutterRad*1.05, cutterStrength scale <1.25, 1, 1>
translate <-0.75, cutterY, cutterZ> }
sphere { <0, 0, 0>, cutterRad*1.04, cutterStrength scale <1.25, 1, 1>
translate <-1, cutterY, cutterZ> }
sphere { <0, 0, 0>, cutterRad*1.03, cutterStrength scale <1.25, 1, 1>
translate <-1.25, cutterY, cutterZ> }
sphere { <0, 0, 0>, cutterRad*1.02, cutterStrength scale <1.25, 1, 1>
translate <-1.5, cutterY, cutterZ> }
sphere { <0, 0, 0>, cutterRad*1.01, cutterStrength scale <1.25, 1, 1>
translate <-1.75, cutterY, cutterZ> }
sphere { <0, 0, 0>, cutterRad*0.99, cutterStrength scale <1.25, 1, 1>
translate <-2, cutterY, cutterZ> }
cylinder { <0, 0.2, 0.5> <0, 0.1, 4> 0.9, -15 }
cylinder { <0, 0.2, 0.5> <0, 0.1, 5> 0.8, -15 rotate <0, -55, 0> translate
<-2, 0, 0> }
cylinder { <0, 0.2, 0.5> <0, 0.1, 5> 0.8, -15 rotate <0, 55, 0> translate <2,
0, 0> }
// base connection
cylinder { <-1.25, 0, 0> <1.25, 0, 0> 1, 2 scale <1, 0.3, .25> translate <0,
-2.1, 0> }
} //--------------------------------- end of blob object
union {
object { sculpture material { sculptMat } }
// base
object{ // Round_Box(A, B, WireRadius, UseMerge)
Round_Box(<-2.5,-1,-0.8>,<2.5,0,0.8>, 0.035 , 0)
texture{ sculptBaseTex1 }
translate<0,-1.825,0>
} // ---------------------------------------------------------
object{ // Round_Box(A, B, WireRadius, UseMerge)
Round_Box(<-2.8,-2.5,-1.1>,<2.8,-0.4,1.1>, 0.05 , 0)
texture{ sculptBaseTex2 }
translate<0,-1.825,0>
} // ---------------------------------------------------------
// add pool of water
box { <-2, -1.25, -1> <2, -0.65, 1>
material {
texture {
pigment { rgbf <0.98, 0.99, 0.98, 0.99> }
//normal { dents 0.1 scale 0.05 turbulence 0.7 rotate <90, 0, 0> }
finish { specular albedo 0.15 roughness 0.005 diffuse albedo 0.05 brilliance 4
ambient 0 reflection { 0.015 0.75 fresnel on } conserve_energy }
}
interior {
ior 1.37 // index of refraction
caustics 1.0 // faked caustics (0..1)
fade_power 1001 // values larger than 1000 give realistic exponential
attenuation
fade_distance 1 // distance where light reaches half intensity
fade_color <0, .3, 0> // color for fading
}
}}
rotate<0,40,0>
translate <0, 2.5+1.825, 0>
scale 0.5
translate <0, 1, 0>
}
Post a reply to this message
Attachments:
Download 'sculpture.png' (601 KB)
Preview of image 'sculpture.png'
|
|
