 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Hi,
I am trying out some HRD renders in Pov 3.7 RC7 and having some difficulty
finding good settings. After a lot of adjusting (mostly guesswork) I have the
following:
For Radiosity:
#default{ finish{ ambient 0 diffuse 1 conserve_energy }}
global_settings {
radiosity {
pretrace_start 0.08
pretrace_end 0.01
count 500
nearest_count 10
error_bound 2.5
recursion_limit 4
low_error_factor .5
gray_threshold 0.0
minimum_reuse 0.015
brightness 0.3
adc_bailout 0.01/2
}
}
For HDR sky_sphere:
sky_sphere {
pigment{
image_map{ hdr "galileo_probe.hdr"
gamma 1.1
map_type 1 interpolate 2}
}
emission rgb 0.6
rotate <0,40,0>
}
For finish on the main lantern (red painted finish):
finish {
specular 0.4
roughness 0.01
brilliance 2
diffuse 1
reflection 0.1
conserve_energy
}
This is probably the best of the renders I have done so far but I still find the
highlights to be too bright. Does anyone know of a good reference/tutorial on
these settings specific to POV?
Thanks
Sean
Post a reply to this message
Attachments:
Download 'lantern.png' (410 KB)
Preview of image 'lantern.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Am 07.03.2013 15:03, schrieb s.day:
> I am trying out some HRD renders in Pov 3.7 RC7 and having some difficulty
> finding good settings. After a lot of adjusting (mostly guesswork) I have the
> following:
I have made the experience that with 3.7 the most straightforward
settings also yield the most realistic results:
> global_settings {
"assumed_gamma 1.0" should go somewhere here.
> radiosity {
> pretrace_start 0.08
> pretrace_end 0.01
That's a pretty low-quality pretrace. I'd suggest a lower pretrace_end.
Shouldn't affect the overall brightness though.
> count 500
> nearest_count 10
> error_bound 2.5
I usually use a setting below 1.0, e.g. 0.8 or 0.5.
> recursion_limit 4
Recursion limit 2 is usually enough.
> low_error_factor .5
> gray_threshold 0.0
> minimum_reuse 0.015
> brightness 0.3
Whoa - stop there! For realism, you /do/ want brightness 1.0 (*). This
will significantly boost the effective diffuse brightness of your
object, and may already be enough to fit the brightness of the
highlights, so that all you might need to do is reduce the overall
brightness of the scene (we'll come to that in a moment).
(* There are actually some situations where a /higher/ brightness
setting may give you more realistic results, but don't bother about them
for now.)
> adc_bailout 0.01/2
>
> }
> }
>
> For HDR sky_sphere:
>
> sky_sphere {
> pigment{
> image_map{ hdr "galileo_probe.hdr"
> gamma 1.1
That should be 1.0 - or left out entirely. If you're going for realism,
don't tinker with it unless you know exactly what you're doing there: If
the author of the light probe did his homework, then by default POV-Ray
3.7 will give you exactly the right thing.
> map_type 1 interpolate 2}
> }
> emission rgb 0.6
THIS is where you're doing your overall scene brightness tweaking.
> rotate <0,40,0>
> }
>
>
> For finish on the main lantern (red painted finish):
>
> finish {
> specular 0.4
> roughness 0.01
As you have no conventional light sources (or do you?), you could just
as well set this to "specular 0.0".
> brilliance 2
Most diffuse surfaces have a brilliance quite close to 1.0. (Aside from
that, radiosity doesn't currently support brilliance settings other than
1.0 anyway.)
> diffuse 1
> reflection 0.1
Hold it right there again: What you're effectively saying here is that
100% of the incoming light is reflected diffusely, and another 10% is
reflected specularly, i.e. the object reflects a total of 110% of the
incoming light ;-)
A total reflection (diffuse + specular) of 80% is a lot more realistic.
By the way, when defining new materials it is good practice to use the
"albedo" keyword for all diffuse, specular and phong, as this allows to
employ a few rules that help you get realistic results (not only in
HDR-lit scenes):
diffuse albedo D
specular albedo S
phong albedo P
reflection { R fresnel }
For realism, you usually want D+R<1 and S+P<R, with S+P=R/2 being a good
guesstimate.
> conserve_energy
This setting has no effect unless you also use variable reflection, i.e.
either of:
reflection { 0.0 0.1 }
reflection { 0.0 0.1 fresnel }
reflection { 0.1 fresnel }
Using fresnel is a good idea anyway, not only for transparent but also
for opaque materials, even if that may seem counter-intuitive: Real-life
materials /all/ have an ior, and follow the fresnel law when polished.
(ior 1.6 is a good bet for opaque materials.)
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
clipka <ano### [at] anonymous org> wrote:
Firstly thanks a lot clipka, a very thorough answer and well explained, I read
somewhere that for HDR diffuse should be set to 1 (hence my mistake), the rest I
think I changed so many settings that I just ended up totally confused.
I did add a light_source but only as the HDR image was not looking good so I
added a low level light source, I have removed that now though.
I also tried albedo but without the correct settings etc I don't think I would
have ever got a good render.
I initially set error_bound to 0.8 but had so many artifacts it looked like an
oil painting (an interesting effect but not what I was after). I just copied the
radiosity settings from an old image that did not use HDR then started
tweaking...
I had assumed_gamma in a separate global_settings section but other than that
being correct most other things were not so good ;-)
I have re-rendered with the following changes below:
pretrace_end 0.001 (don't know if this is too far, certainly slowed down the
pretrace step).
error_bound 0.8
recursion_limit 2
brightness 1.0
removed the gamma from the sky_sphere
left emission at rgb 0.6 // will try tweaking this though.
For the finish
set specular to 0
set brilliance to 1
changed the settings to diffuse albedo 0.6 reflection { 0.2 fresnel }
Two more questions though..
1) Is variable reflection advised for most objects, I have previously only used
this for glass/water?
2) Without specular does roughness have an effect on the surface?
As you can see your advice has helped a lot, this is much better than any of my
previous attempts.
Thanks
Sean
Post a reply to this message
Attachments:
Download 'lantern_c.png' (225 KB)
Preview of image 'lantern_c.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
clipka <ano### [at] anonymousorg> wrote:
... forgot to mention, I also added an interior {ior 1.6} to the
texture/material.
Sean
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Am 07.03.2013 19:16, schrieb s.day:
> I initially set error_bound to 0.8 but had so many artifacts it looked like an
> oil painting (an interesting effect but not what I was after). I just copied the
> radiosity settings from an old image that did not use HDR then started
> tweaking...
Good that you mention this, because I completely forgot about this problem:
Radiosity currently doesn't do a good job with HDR light probes having
rather small bright regions (e.g. direct sunlight). There are two ways
to approach this problem:
(A) Create a blurred version of the light probe using an external
program, and use this one for radiosity:
sphere { <0,0,0>, 10000 // or some other large value
texture {
pigment { image_map {...} }
finish { emission 1 diffuse 0 specular 0 }
}
no_image
no_reflection
}
For reflections and background, the classic sky_sphere will be visible.
(B) Crank up the radiosity "count" value like mad; setting
"nearest_count" to the maximum value of 20 should also help.
> Two more questions though..
>
> 1) Is variable reflection advised for most objects, I have previously only used
> this for glass/water?
For realism, yes - variable reflection does improve the credibility of
any polished surface, and it doesn't slow down the render noticeably.
> 2) Without specular does roughness have an effect on the surface?
No; in radiosity-lit scenes, highlights will always be infinitely sharp
(unless you know how to achieve blurred reflections. There are ways, but
they come at a significant cost in render time; and even then the
blurriness will not be controlled by the roughness keyword.)
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
clipka <ano### [at] anonymousorg> wrote:
> Am 07.03.2013 19:16, schrieb s.day:
> Good that you mention this, because I completely forgot about this problem:
>
> Radiosity currently doesn't do a good job with HDR light probes having
> rather small bright regions (e.g. direct sunlight). There are two ways
> to approach this problem:
>
Thanks again, I am running another render with a higher count and nearest_count
set to 20 as there are a few artifacts still.
Also, I have tried a few different probes and all are much darker than the
galileo one I tried first, is it acceptable to increase emissions > 1 to
increase the light level or is there a better approach?
Thanks
Sean
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
clipka <ano### [at] anonymousorg> wrote:
> Most diffuse surfaces have a brilliance quite close to 1.0. (Aside from
> that, radiosity doesn't currently support brilliance settings other than
> 1.0 anyway.)
What about metallic surfaces? Is there a typical value? I find that 2.5 to 3.0
makes a good metallic impression on surfaces with low specular reflection.
> By the way, when defining new materials it is good practice to use the
> "albedo" keyword for all diffuse, specular and phong, as this allows to
> employ a few rules that help you get realistic results (not only in
> HDR-lit scenes):
>
> diffuse albedo D
> specular albedo S
> phong albedo P
> reflection { R fresnel }
>
> For realism, you usually want D+R<1 and S+P<R, with S+P=R/2 being a good
> guesstimate.
Wait, what?
I was under the impression that S+P should be equal to R, at least for polished
surfaces. Is this the case with metallic reflection, or does it only apply to
non-metallic variable reflection (such as, I presume, bright red enamel paint)?
I was mere hours away from uploading years of work on metallic finishes to the
Object Collection, and I need to know if I'm about to make any embarrassing
blunders.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"Cousin Ricky" <rickysttATyahooDOTcom> wrote:
> I was mere hours away from uploading years of work on metallic finishes to the
> Object Collection, and I need to know if I'm about to make any embarrassing
> blunders.
It can't be anymore embarrassing than mine.. I thought I knew what I was doing
with POV. I have only been using it on and off for about 25 years since I got a
copy with PC Format magazine. The magazine came with the source code to Mike
Millers jack in the box/rollercoaster scene on the disk and I (well my 386 PC)
spent several weeks tracing the scene.
Even after all this time I still have plenty to learn, I am obviously a slow
learner though ;-)
Sean
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Am 08.03.2013 00:51, schrieb s.day:
> Also, I have tried a few different probes and all are much darker than the
> galileo one I tried first, is it acceptable to increase emissions > 1 to
> increase the light level or is there a better approach?
It's absolutely acceptable, and is in fact /the/ official proper way to
boost your light probe's brightness without modifying the file itself.
Any other approach would either be physically wrong, unnecessarily
complicated, or both.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Am 08.03.2013 06:59, schrieb Cousin Ricky:
> clipka <ano### [at] anonymousorg> wrote:
>> Most diffuse surfaces have a brilliance quite close to 1.0. (Aside from
>> that, radiosity doesn't currently support brilliance settings other than
>> 1.0 anyway.)
>
> What about metallic surfaces? Is there a typical value? I find that 2.5 to 3.0
> makes a good metallic impression on surfaces with low specular reflection.
Metallic surfaces are indeed a special case. With non-metallic surfaces,
the diffuse reflection is usually a result of scattering within the
material itself (*), which is typically isotropic or near-isotropic,
resulting in a lambertian or near-lambertian diffuse reflection,
corresponding to a brilliance of 1.0.
(* As a matter of fact the classic diffuse term is actually just a rough
approximation of subsurface scattering, presuming a near-zero
translucency and ignoring ior.)
With metallic surfaces you do not have any scattering within the
material - instead, any diffuse-style reflection is the result of
repeated specular reflection at a very clustered surface. I wouldn't be
surprised if this indeed results in quite different characteristics. My
first guess, however, would be that those characteristics would be more
faithfully modelled with a very rough specular highlight, rather than a
high-brilliance diffuse term.
>> By the way, when defining new materials it is good practice to use the
>> "albedo" keyword for all diffuse, specular and phong, as this allows to
>> employ a few rules that help you get realistic results (not only in
>> HDR-lit scenes):
>>
>> diffuse albedo D
>> specular albedo S
>> phong albedo P
>> reflection { R fresnel }
>>
>> For realism, you usually want D+R<1 and S+P<R, with S+P=R/2 being a good
>> guesstimate.
>
> Wait, what?
>
> I was under the impression that S+P should be equal to R, at least for polished
> surfaces. Is this the case with metallic reflection, or does it only apply to
> non-metallic variable reflection (such as, I presume, bright red enamel paint)?
>
> I was mere hours away from uploading years of work on metallic finishes to the
> Object Collection, and I need to know if I'm about to make any embarrassing
> blunders.
For metallic surfaces S+P=R is indeed perfectly right, so you can go ahead.
For non-metallic surfaces there is a problem because the current code
for highlights doesn't account for the fresnel law (it does for metallic
surfaces), so depending on the angle of incidence the resulting
highlights will be some deal brighter than the fresnel-style
reflections. Reducing the highlight brightness isn't a perfect solution
for this problem (because the brightness still doesn't properly vary
with the angle of incidence), but it's better than nothing.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
