|
 |
A lot of artists has made so-called rayographs, but Man Ray coined the term and
is perhaps most famous for making such images. The traditional process involves
lighting some objects on top of a sheet of photographic paper, then developing
the paper in the normal way. It's possible to mimic this process in POV-Ray by
using a light-source with negative strength and a glowing surface below
invisible objects. The light-source should theoretically have a strength of
-2.0, but a little more seems to be better. The plane below the objects should
have a finish with ambient and diffuse of 1.0, giving a glow. The objects on
the surface should have the no_image keyword to hide the object from view, but
keeping the shadow it casts. The negative light will eat away the glow from the
surface, but where the shadows are, the glow will show.
Following is the code and then some references to rayographs on the web.
Enjoy
H
--
// Persistence of Vision Ray Tracer Scene Description File
// File: rayograph.pov
// Vers: 3.6
// Desc: mimics rayographs in POV-Ray
// Date: 2008.07.13
// Auth: Helge Hansen
//
// Note: a square image format will show +/- 1.0 in x- and z-directions
#version 3.6;
global_settings { assumed_gamma 1.8 }
camera {
location <0, 3, 0> // position above plane
direction 1.5*z
right x*image_width/image_height
look_at <0, 0, 0>
}
light_source {
<1, 1, 1> // position
color rgb <1, 1, 1> * (-2.5) // ! negative "colour", must be lower than -2.0
area_light // area light gives more interesting shadows
<0.75, 0, 0> <0, 0, 0.75> // light size
5,5
adaptive 1
jitter
//circular // for round light
}
#local Background = texture {
pigment { color rgb <1,1,1> }
finish { ambient 1 diffuse 1 } // glowing
}
#local Object = texture {
pigment { color rgb <0,0,0> }
}
plane { y, 0 texture { Background } }
// objects:
union {
cylinder { <-0.4, 0, -0.4>, <-0.4, 0.2, -0.4>, 0.1 }
cylinder { <-0.4, 0, 0.4>, <-0.4, 0.2, 0.4>, 0.1 }
cylinder { < 0.4, 0, -0.4>, < 0.4, 0.2, -0.4>, 0.1 }
cylinder { < 0.4, 0, 0.4>, < 0.4, 0.2, 0.4>, 0.1 }
no_image // ! hides the objects but keeps the shadows
texture { Object }
}
--
On the web:
http://en.wikipedia.org/wiki/Man_Ray
http://en.wikipedia.org/wiki/Rayographs
http://www.manraytrust.com/
http://museum.icp.org/museum/exhibitions/man_ray/mr_bio.html
http://cs.nga.gov.au/IMAGES/LRG/88112.JPG
http://www.nga.gov/exhibitions/2006/dada/images/artwork/202-677-m.jpg
(or search for images in Google: man ray rayograph)
Post a reply to this message
Attachments:
Download 'rayograph1.jpg' (26 KB)
Preview of image 'rayograph1.jpg'
|
|
|
|
Chambers <ben### [at] pacificwebguy com> wrote:
> These are pretty cool!
>
> I imagine you could get some funky abstract images by playing with the
> colors a bit ;)
Now with funky colours!
(How terrible)
All have three lights.
1) Yellow, cyan and magenta lights
2) Red, green and blue lights
3) Lights as 2), transmit on the box pigment is 0.5
4) Lights as 2), filter on the box pigment is 0.5, and they have different
colours
3) and 4) are four short boxes with one short box on top
Don't try this at home, it will ruin your good taste.
But thanks for the comments.
H
Post a reply to this message
Attachments:
Download 'rayograph-colors.jpg' (106 KB)
Preview of image 'rayograph-colors.jpg'
|
|
